Remove -Wno-unused-private-field clang warning suppression.

third_party/cld_2/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/features.gni")
 
 gypi_values = exec_script("//build/gypi_to_gn.py",
                           [ rebase_path("cld_2.gyp") ],
                           "scope",
                           [ "cld_2.gyp" ])
@@ skipping 62 matching lines @@
 
 source_set("cld2_platform_impl") {
   deps = []
   if (cld2_platform_support == "static") {
     deps += [ ":cld2_static" ]
   } else if (cld2_platform_support == "dynamic") {
     deps += [ ":cld2_dynamic" ]
   }
 }
 
+config("cld2_warnings") {
+  if (is_clang) {
+    cflags = [
+      # cld_2 has unused private fields.
+      "-Wno-unused-private-field",
+    ]
+  }
+}
+
 static_library("cld2_static") {
   sources = gypi_values.cld2_core_impl_sources
   include_dirs = [
     "src/internal",
     "src/public",
   ]
 
   deps = [
     ":cld_2",
     ":cld2_data",
   ]
   configs -= [ "//build/config/compiler:chromium_code" ]
-  configs += [ "//build/config/compiler:no_chromium_code" ]
+  configs += [
+    "//build/config/compiler:no_chromium_code",
+    ":cld2_warnings",

[brettw, 2015/07/09 18:03:07]

This should go first.

[Nico, 2015/07/09 18:18:46]

No, it needs be be after no_chromium_code so that the -Wno flag is after the
(effective) -Wall in no_chromium_code (that's why there's a config for this).

+  ]
 }
 
 config("cld2_dynamic_mode_config") {
   defines = [ "CLD2_DYNAMIC_MODE" ]
 }
 
 static_library("cld2_dynamic") {
   sources = gypi_values.cld2_core_sources + gypi_values.cld2_core_impl_sources +
             gypi_values.cld2_dynamic_data_loader_sources
   include_dirs = [
     "src/internal",
     "src/public",
   ]
 
   configs -= [ "//build/config/compiler:chromium_code" ]
   configs += [
     ":cld2_dynamic_mode_config",
     "//build/config/compiler:no_chromium_code",
+    ":cld2_warnings",

[brettw, 2015/07/09 18:03:07]

Ditto

[Nico, 2015/07/09 18:18:46]

Ditto.

   ]
 }
 
 # Does not build on Windows.
 if (!is_win) {
   executable("cld_2_dynamic_data_tool") {
     sources = [
       "src/internal/cld2_dynamic_data_extractor.cc",
       "src/internal/cld2_dynamic_data_extractor.h",
       "src/internal/cld2_dynamic_data_tool.cc",
     ]
 
     include_dirs = [
       "src/internal",
       "src/public",
     ]
 
     deps = [
       ":cld2_data",
       ":cld2_dynamic",
     ]
 
     configs -= [ "//build/config/compiler:chromium_code" ]
     configs += [
       ":cld2_dynamic_mode_config",
       "//build/config/compiler:no_chromium_code",
     ]
   }
 }