Switch to Cocoa APIs for fullscreen.

chrome/browser/fullscreen_mac.mm

 // Copyright (c) 2011 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/fullscreen.h"
 
-#import <Carbon/Carbon.h>
 #import <Cocoa/Cocoa.h>
 
-#import "base/logging.h"
+// Replicate specific 10.7 SDK declarations for building with prior SDKs.
+#if !defined(MAC_OS_X_VERSION_10_7) || \
+    MAC_OS_X_VERSION_MAX_ALLOWED < MAC_OS_X_VERSION_10_7
 
-@interface FullScreenMonitor : NSObject {
- @private
-  BOOL fullScreen_;
-  EventHandlerRef eventHandler_;
-}
+enum {
+  NSApplicationPresentationFullScreen = 1 << 10
+};
 
-@property (nonatomic, getter=isFullScreen) BOOL fullScreen;
-
-@end
-
-static OSStatus handleAppEvent(EventHandlerCallRef myHandler,
-                               EventRef event,
-                               void* userData) {
-  DCHECK(userData);
-
-  FullScreenMonitor* fullScreenMonitor =
-      reinterpret_cast<FullScreenMonitor*>(userData);
-
-  UInt32 mode = 0;
-  OSStatus status = GetEventParameter(event,
-                                      kEventParamSystemUIMode,
-                                      typeUInt32,
-                                      NULL,
-                                      sizeof(UInt32),
-                                      NULL,
-                                      &mode);
-  if (status != noErr)
-    return status;
-  BOOL isFullScreenMode = mode == kUIModeAllHidden;
-  [fullScreenMonitor setFullScreen:isFullScreenMode];
-  return noErr;
-}
-
-@implementation FullScreenMonitor
-
-@synthesize fullScreen = fullScreen_;
-
-- (id)init {
-  if ((self = [super init])) {
-    // Check if the user is in presentation mode initially.
-    SystemUIMode currentMode;
-    GetSystemUIMode(&currentMode, NULL);
-    fullScreen_ = currentMode == kUIModeAllHidden;
-
-    // Register a Carbon event to receive the notification about the login
-    // session's UI mode change.
-    EventTypeSpec events[] =
-      {{ kEventClassApplication, kEventAppSystemUIModeChanged }};
-    OSStatus status = InstallApplicationEventHandler(

[Nico, 2013/01/23 21:35:21]

Did this inform us about fullscreen changes from other processes too? (Say,
npapi flash fullscreen)

[Avi (use Gerrit), 2013/01/23 21:48:21]

Yes, and that's the point.

Cocoa has on NSApp both -presentationOptions and
-currentSystemPresentationOptions. The former is the local setting for when this
app is in front, the latter is the global system setting, depending on what the
app that is currently in control has set.

Carbon only has GetSystemUIMode, which gets the local setting for the app. The
only way in Carbon to get the global system setting was to observe and track the
kEventAppSystemUIModeChanged event which was broadcast when the global system
setting changed. That's why we had this class in the first place.

-        NewEventHandlerUPP(handleAppEvent),
-        GetEventTypeCount(events),
-        events,
-        self,
-        &eventHandler_);
-    if (status) {
-      [self release];
-      self = nil;
-    }
-  }
-  return self;
-}
-
-- (void)dealloc {
-  if (eventHandler_)
-    RemoveEventHandler(eventHandler_);
-  [super dealloc];
-}
-
-@end
-
-static FullScreenMonitor* g_fullScreenMonitor = nil;
-
-void InitFullScreenMonitor() {
-  if (!g_fullScreenMonitor)
-    g_fullScreenMonitor = [[FullScreenMonitor alloc] init];
-}
-
-void StopFullScreenMonitor() {
-  [g_fullScreenMonitor release];
-  g_fullScreenMonitor = nil;
-}
+#endif  // MAC_OS_X_VERSION_10_7
 
 bool IsFullScreenMode() {
-  // Check if the main display has been captured (game in particular).
+  // Check if the main display has been captured (by games in particular).
   if (CGDisplayIsCaptured(CGMainDisplayID()))
     return true;
 
-  return [g_fullScreenMonitor isFullScreen];
+  NSApplicationPresentationOptions options =
+      [NSApp currentSystemPresentationOptions];
+
+  // If both dock and menu bar are hidden, that is the equivalent of the Carbon
+  // SystemUIMode (or Info.plist's LSUIPresentationMode) kUIModeAllHidden.
+  if (((options & NSApplicationPresentationHideDock) ||
+       (options & NSApplicationPresentationAutoHideDock)) &&
+      ((options & NSApplicationPresentationHideMenuBar) ||
+       (options & NSApplicationPresentationAutoHideMenuBar))) {

[Nico, 2013/01/23 21:52:08]

nit: This would be a tad more readable as

bool dock_hidden = (options & NSApplicationPresentationHideDock) ||
    (options & NSApplicationPresentationAutoHideDock);

bool menu_hidden = (options & NSApplicationPresentationHideMenuBar) ||
    (options & NSApplicationPresentationAutoHideMenuBar);

if (dock_hidden && menu_hidden) …

[Avi (use Gerrit), 2013/01/23 21:55:07]

agreed.

+    return true;
+  }
+
+  if (options & NSApplicationPresentationFullScreen)
+    return true;
+
+  return false;
 }