GN updates to build base on iOS

base/BUILD.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/ui.gni")
 import("//testing/test.gni")
 
 if (is_android) {
   import("//build/config/android/rules.gni")
 }
 
 config("base_implementation") {
   defines = [ "BASE_IMPLEMENTATION" ]
+
+  if (is_ios) {
+    # base uses routines deprecated in iOS 8
+    cflags = [ "-Wno-deprecated-declarations" ]

[Nico, 2015/06/11 15:37:59]

I don't see this in the gyp build files for base. How come?

[Chinmay, 2015/06/11 17:44:35]

The Sky builds set the target to 8.0 manually. Do you have suggestions on a more
elegant fix? Admittedly, this is a very hacky workaround.

+  }
 }
 
 if (is_win) {
   # This is in a separate config so the flags can be applied to dependents.
   # ldflags in GN aren't automatically inherited.
   config("base_win_linker_flags") {
     ldflags = [
       "/DELAYLOAD:cfgmgr32.dll",
       "/DELAYLOAD:powrprof.dll",
       "/DELAYLOAD:setupapi.dll",
     ]
   }
 }
 
 source_set("base_paths") {
   sources = [
     "base_paths.cc",
     "base_paths.h",
     "base_paths_android.cc",
     "base_paths_android.h",
     "base_paths_mac.h",
     "base_paths_mac.mm",
     "base_paths_posix.cc",
     "base_paths_posix.h",
     "base_paths_win.cc",
     "base_paths_win.h",
   ]
 
-  if (is_android || is_mac) {
+  if (is_android || is_mac || is_ios) {
     sources -= [ "base_paths_posix.cc" ]
   }
 
   if (is_nacl) {
     sources -= [
       "base_paths.cc",
       "base_paths_posix.cc",
     ]
   }
 
@@ skipping 704 matching lines @@
       "powrprof.lib",
       "setupapi.lib",
     ]
     all_dependent_configs = [ ":base_win_linker_flags" ]
   } else if (!is_nacl) {
     # Non-Windows.
     deps += [ "//third_party/libevent" ]
   }
 
   # Mac.
-  if (is_mac) {
+  if (is_mac || is_ios) {
+    # Common Desktop / iOS excludes
     sources -= [
       "native_library_posix.cc",
       "strings/sys_string_conversions_posix.cc",
       "threading/platform_thread_internal_posix.cc",
     ]
+
+    if (is_ios) {
+      sources -= [
+        "files/file_path_watcher_fsevents.cc",
+        "files/file_path_watcher_fsevents.h",
+      ]

[Nico, 2015/06/11 15:37:59]

I thought the gn way was to not add these in the first place if is_ios is true
instead of adding and then removing them.

+    }
   } else {
     # Non-Mac.
     sources -= [
       "files/file_path_watcher_fsevents.cc",
       "files/file_path_watcher_fsevents.h",
       "files/file_path_watcher_kqueue.cc",
       "files/file_path_watcher_kqueue.h",
     ]
   }
 
@@ skipping 24 matching lines @@
     ]
 
     if (!is_android) {
       sources -= [
         "linux_util.cc",
         "linux_util.h",
       ]
     }
   }
 
+  # iOS
+  if (is_ios) {
+    set_sources_assignment_filter([])

[eseidel, 2015/06/10 21:42:44]

This is slightly sad-panda.  Would be nice to know what files it's wrongly
filtering.

[Chinmay, 2015/06/10 21:45:27]

By default, all "mac" specific files will get filtered away. But most of them
serve fine for iOS. The filter is temporarily disabled to add a subset of the
mac specific file.

[Nico, 2015/06/11 15:37:59]

Since it's early for the ios gn build, it's probably better to get this right
instead of putting in some temporary workaround. I think in gyp all the _mac
files are used on ios by default, right? should gn just work the same?

[Chinmay, 2015/06/11 17:44:35]

In the GN system, "mac" files are not built by default on "ios" (and are
filtered away).  I am not sure what the GN way is regarding these rules. But a
majority (though not all) of the "mac" files are fine for use on iOS. I am not
sure what the elegant way to do this would be though. Since there are always
going to be exceptions for both Desktop Mac and iOS builds. All the existing GN
files treat the "is_mac" case as if it was "is_mac_desktop".

[sdefresne, 2015/06/11 17:54:32]

According to build/filename_rules.gypi, we do not build _mac.* files on iOS
either when using gyp and we use sources/ include rules to add those files we do
want to build, so I think it make sense to do the same thing with gn.

+
+    sources += [
+      "base_paths_mac.h",
+      "base_paths_mac.mm",
+      "files/file_util_mac.mm",
+      "mac/bundle_locations.h",
+      "mac/bundle_locations.mm",
+      "mac/foundation_util.h",
+      "mac/foundation_util.mm",
+      "mac/mach_logging.cc",
+      "mac/mach_logging.h",
+      "mac/scoped_mach_port.cc",
+      "mac/scoped_mach_port.h",
+      "mac/scoped_nsautorelease_pool.h",
+      "mac/scoped_nsautorelease_pool.mm",
+      "message_loop/message_pump_mac.h",
+      "message_loop/message_pump_mac.mm",
+      "strings/sys_string_conversions_mac.mm",
+      "threading/platform_thread_mac.mm",
+      "time/time_mac.cc",
+    ]
+
+    set_sources_assignment_filter(sources_assignment_filter)
+  }
+
   if (!use_glib) {
     sources -= [
       "message_loop/message_pump_glib.cc",
       "message_loop/message_pump_glib.h",
     ]
   }
 
   configs += [ "//build/config/compiler:wexit_time_destructors" ]
   if (is_android && !is_debug) {
     configs -= [ "//build/config/compiler:optimize" ]
@@ skipping 506 matching lines @@
     apk_deps = [
       ":base_java",
       ":base_java_unittest_support",
     ]
     isolate_file = "base_unittests.isolate"
   }
 
   if (is_ios) {
     sources -= [
       "process/memory_unittest.cc",
-      "process/memory_unittest_mac.h",
-      "process/memory_unittest_mac.mm",
       "process/process_unittest.cc",
       "process/process_util_unittest.cc",
     ]
 
     # Pull in specific Mac files for iOS (which have been filtered out by file
     # name rules).
     set_sources_assignment_filter([])
     sources += [
       "mac/bind_objc_block_unittest.mm",
       "mac/foundation_util_unittest.mm",
@@ skipping 156 matching lines @@
 
   # GYP: //base.gyp:base_java_unittest_support
   android_library("base_java_unittest_support") {
     deps = [
       ":base_java",
     ]
     java_files =
         [ "test/android/java/src/org/chromium/base/ContentUriTestUtils.java" ]
   }
 }