Fixing identifier for device returning a 0 identifierForVendor.

base/ios/device_util.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "base/ios/device_util.h"
 
 #include <CommonCrypto/CommonDigest.h>
 #import <UIKit/UIKit.h>
 
 #include <ifaddrs.h>
 #include <net/if_dl.h>
 #include <string.h>
 #include <sys/socket.h>
 #include <sys/sysctl.h>
 
 #include "base/ios/ios_util.h"
 #include "base/logging.h"
 #include "base/string_util.h"
 #include "base/stringprintf.h"
 #include "base/mac/scoped_cftyperef.h"
 #include "base/memory/scoped_ptr.h"
 #include "base/sys_string_conversions.h"
 
 namespace {
 
 // Client ID key in the user preferences.
-NSString* const kClientIdPreferenceKey = @"ChromiumClientID";
+NSString* const kLegacyClientIdPreferenceKey = @"ChromiumClientID";
+NSString* const kClientIdPreferenceKey = @"ChromeClientID";
 // Default salt for device ids.
 const char kDefaultSalt[] = "Salt";
+// Zero UUID returned on buggy iOS devices.
+NSString* const kZeroUUID = @"00000000-0000-0000-0000-000000000000";
+
+NSString* GenerateClientId() {
+  NSUserDefaults* defaults = [NSUserDefaults standardUserDefaults];
+
+  // Try to migrate from legacy client id.
+  NSString* client_id = [defaults stringForKey:kLegacyClientIdPreferenceKey];
+
+  // Some iOS6 devices return a buggy identifierForVendor:
+  // http://openradar.appspot.com/12377282. If this is the case, revert to
+  // generating a new one.
+  if (!client_id || [client_id isEqualToString:kZeroUUID]) {
+    if (base::ios::IsRunningOnIOS6OrLater()) {
+      client_id = [[[UIDevice currentDevice] identifierForVendor] UUIDString];
+      if ([client_id isEqualToString:kZeroUUID])
+        client_id = base::SysUTF8ToNSString(ios::device_util::GetRandomId());
+    } else {
+      client_id = base::SysUTF8ToNSString(ios::device_util::GetRandomId());
+    }
+  }
+  return client_id;
+}
 
 }  // namespace
 
 namespace ios {
 namespace device_util {
 
 std::string GetPlatform() {
   std::string platform;
   size_t size = 0;
   sysctlbyname("hw.machine", NULL, &size, NULL, 0);
@@ skipping 57 matching lines @@
   base::mac::ScopedCFTypeRef<CFStringRef> uuid_string(
       CFUUIDCreateString(kCFAllocatorDefault, uuid_object));
   return base::SysCFStringRefToUTF8(uuid_string);
 }
 
 std::string GetDeviceIdentifier(const char* salt) {
   NSUserDefaults* defaults = [NSUserDefaults standardUserDefaults];
   NSString* client_id = [defaults stringForKey:kClientIdPreferenceKey];
 
   if (!client_id) {
-    if (base::ios::IsRunningOnIOS6OrLater())
-      client_id = [[[UIDevice currentDevice] identifierForVendor] UUIDString];
-    else
-      client_id = base::SysUTF8ToNSString(GetRandomId());
+    client_id = GenerateClientId();
     [defaults setObject:client_id forKey:kClientIdPreferenceKey];
     [defaults synchronize];
   }
 
   NSData* hash_data = [[NSString stringWithFormat:@"%@%s", client_id,
       salt ? salt : kDefaultSalt] dataUsingEncoding:NSUTF8StringEncoding];
 
   unsigned char hash[CC_SHA256_DIGEST_LENGTH];
   CC_SHA256([hash_data bytes], [hash_data length], hash);
   CFUUIDBytes* uuid_bytes = reinterpret_cast<CFUUIDBytes*>(hash);
 
   base::mac::ScopedCFTypeRef<CFUUIDRef>
       uuid_object(CFUUIDCreateFromUUIDBytes(kCFAllocatorDefault, *uuid_bytes));
   base::mac::ScopedCFTypeRef<CFStringRef> device_id(
       CFUUIDCreateString(kCFAllocatorDefault, uuid_object));
   return base::SysCFStringRefToUTF8(device_id);
 }
 
 }  // namespace device_util
 }  // namespace ios