[MacViews] Enable dragging a window by its caption/draggable areas.

ui/views/cocoa/bridged_native_widget.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/views/cocoa/bridged_native_widget.h"
 
 #import <objc/runtime.h>
 
 #include "base/logging.h"
+#import "base/mac/foundation_util.h"
 #include "base/mac/mac_util.h"
 #import "base/mac/sdk_forward_declarations.h"
 #include "base/thread_task_runner_handle.h"
+#include "ui/base/hit_test.h"
 #include "ui/base/ime/input_method.h"
 #include "ui/base/ime/input_method_factory.h"
 #include "ui/base/ui_base_switches_util.h"
 #include "ui/gfx/display.h"
 #include "ui/gfx/geometry/dip_util.h"
 #import "ui/gfx/mac/coordinate_conversion.h"
 #import "ui/gfx/mac/nswindow_frame_controls.h"
 #include "ui/gfx/screen.h"
 #import "ui/views/cocoa/cocoa_mouse_capture.h"
 #import "ui/views/cocoa/bridged_content_view.h"
@@ skipping 46 matching lines @@
 gfx::Size GetClientSizeForWindowSize(NSWindow* window,
                                      const gfx::Size& window_size) {
   NSRect frame_rect =
       NSMakeRect(0, 0, window_size.width(), window_size.height());
   // Note gfx::Size will prevent dimensions going negative. They are allowed to
   // be zero at this point, because Widget::GetMinimumSize() may later increase
   // the size.
   return gfx::Size([window contentRectForFrameRect:frame_rect].size);
 }
 
+BOOL WindowWantsMouseDownReposted(NSEvent* ns_event) {
+  id delegate = [[ns_event window] delegate];
+  return
+      [delegate
+          respondsToSelector:@selector(shouldRepostPendingLeftMouseDown:)] &&
+      [delegate shouldRepostPendingLeftMouseDown:[ns_event locationInWindow]];
+}
+
+// Check if a mouse-down event should drag the window. If so, repost the event
+// twice. It doesn't seem to work the first time it's reposted.
+NSEvent* DoubleRepostEventIfHandledByWindow(NSEvent* ns_event) {
+  // Which repost we're expecting to receive.
+  static int expected_repost_count = 0;
+  // The event number of the reposted event. This let's us track whether an
+  // event is actually a repost since user-generated events have increasing
+  // event numbers.
+  static NSInteger reposted_event_number = -1;
+
+  CGEventRef cg_event = [ns_event CGEvent];
+  NSInteger event_number = [ns_event eventNumber];
+
+  // The logic here is a bit convoluted because we want to mitigate race
+  // conditions if somehow a different mousedown occurs between reposts.
+  // Specifically, we want to avoid:
+  // - BridgedNativeWidget's draggability getting out of sync (e.g. it's
+  //   draggable outside of a repost cycle),
+  // - any repost loop.
+  if (reposted_event_number == event_number) {
+    // This is a reposted event.
+    if (expected_repost_count == 1) {
+      // There has been no intermediate mouse-down, repost the event again.
+      expected_repost_count = 2;
+      CGEventPost(kCGSessionEventTap, cg_event);
+    } else if (expected_repost_count == 2) {
+      expected_repost_count = 0;
+      // This is the final repost, call through to make the window
+      // non-draggable.
+      WindowWantsMouseDownReposted(ns_event);
+    }

[tapted, 2015/05/22 04:03:12]

else { NOTREACHED(); }? (i.e. we should never see that event number again.
Although perhaps `reposted_event_number = -1` at the same time we set the repost
count to 0 would be more robust to hypothetical wraparaound

[jackhou1, 2015/05/25 04:50:19]

In the if (expected_repost_count > 0) block below, we set expected_repost_count
= 0; but reposted_event_number is unchanged. In that case, we want to do nothing
and just return nil. Made that more explicit.

+    return nil;  // Ignore the event.
+  } else {

[tapted, 2015/05/22 04:03:12]

nit: no else after return

[jackhou1, 2015/05/25 04:50:19]

Done.

+    // This is a new event.
+    if (expected_repost_count > 0) {
+      // We were expecting a repost, but since this is a new mouse-down, cancel
+      // reposting and allow event to continue as usual.
+      expected_repost_count = 0;
+      // Call through so that the window is made non-draggable again.
+      WindowWantsMouseDownReposted(ns_event);
+      return ns_event;
+    } else {

[tapted, 2015/05/22 04:03:12]

no else after return

[jackhou1, 2015/05/25 04:50:19]

Done.

+      // We're not in the middle of reposting, process this new event.
+      if (WindowWantsMouseDownReposted(ns_event)) {
+        expected_repost_count = 1;
+        reposted_event_number = [ns_event eventNumber];
+        CGEventPost(kCGSessionEventTap, cg_event);
+        return nil;
+      }
+      return ns_event;
+    }
+  }
+}
+
+// Support window caption/draggable regions.
+// In AppKit, non-client regions are set by overriding
+// -[NSView mouseDownCanMoveWindow]. NSApplication caches this area as views are
+// installed and performs window moving when mouse-downs land in the area.
+// In Views, non-client regions are determined via hit-tests when the event
+// occurs.
+// To bridge the two models, we monitor mouse-downs with
+// +[NSEvent addLocalMonitorForEventsMatchingMask:handler:]. This receives
+// events after window dragging is handled, so for mouse-downs that land on a
+// draggable point, we cancel the event and repost it at the CGSessionEventTap
+// level so that window dragging will be handled again.
+void SetupDragEventMonitor() {
+  static id g_event_monitor = nil;

[tapted, 2015/05/22 04:03:12]

nit: no `g_` for local statics. I'd maybe just call it monitor.

[jackhou1, 2015/05/25 04:50:19]

Done.

+  if (g_event_monitor)
+    return;
+
+  NSEvent* (^monitor_callback)(NSEvent* ns_event);

[tapted, 2015/05/22 04:03:12]

nit: move this into the function call (just to hide the block type syntax). See
e.g. event_monitor_mac.mm

[jackhou1, 2015/05/25 04:50:19]

Done.

+  monitor_callback = ^NSEvent*(NSEvent* ns_event) {
+    return DoubleRepostEventIfHandledByWindow(ns_event);
+  };
+
+  g_event_monitor =
+      [NSEvent addLocalMonitorForEventsMatchingMask:NSLeftMouseDownMask
+                                            handler:monitor_callback];
+}
+
 }  // namespace
 
 namespace views {
 
 // static
 gfx::Size BridgedNativeWidget::GetWindowSizeForClientSize(
     NSWindow* window,
     const gfx::Size& content_size) {
   NSRect content_rect =
       NSMakeRect(0, 0, content_size.width(), content_size.height());
   NSRect frame_rect = [window frameRectForContentRect:content_rect];
   return gfx::Size(NSWidth(frame_rect), NSHeight(frame_rect));
 }
 
 BridgedNativeWidget::BridgedNativeWidget(NativeWidgetMac* parent)
     : native_widget_mac_(parent),
       focus_manager_(nullptr),
       widget_type_(Widget::InitParams::TYPE_WINDOW),  // Updated in Init().
       parent_(nullptr),
       target_fullscreen_state_(false),
       in_fullscreen_transition_(false),
       window_visible_(false),
       wants_to_be_visible_(false) {
+  SetupDragEventMonitor();
   DCHECK(parent);
   window_delegate_.reset(
       [[ViewsNSWindowDelegate alloc] initWithBridgedNativeWidget:this]);
 }
 
 BridgedNativeWidget::~BridgedNativeWidget() {
   RemoveOrDestroyChildren();
   DCHECK(child_windows_.empty());
   SetFocusManager(NULL);
   SetRootView(NULL);
@@ skipping 403 matching lines @@
     if (is_key) {
       widget->OnNativeFocus();
       widget->GetFocusManager()->RestoreFocusedView();
     } else {
       widget->OnNativeBlur();
       widget->GetFocusManager()->StoreFocusedView(true);
     }
   }
 }
 
+bool BridgedNativeWidget::ShouldRepostPendingLeftMouseDown(
+    NSPoint location_in_window) {
+  if (!bridged_view_)
+    return false;
+
+  if ([bridged_view_ mouseDownCanMoveWindow]) {
+    // This is a re-post, the movement has already started, so we can make the
+    // window non-draggable again.
+    SetDraggable(false);
+    return false;
+  }
+
+  gfx::Point point(location_in_window.x,
+                   NSHeight([window_ frame]) - location_in_window.y);
+  bool should_move_window =
+      native_widget_mac()->GetWidget()->GetNonClientComponent(point) ==
+      HTCAPTION;
+
+  if (!should_move_window)
+    return false;
+
+  // Make the window draggable, then return true to repost the event.
+  SetDraggable(true);
+  return true;
+}
+
 void BridgedNativeWidget::OnSizeConstraintsChanged() {
   NSWindow* window = ns_window();
   Widget* widget = native_widget_mac()->GetWidget();
   gfx::Size min_size = widget->GetMinimumSize();
   gfx::Size max_size = widget->GetMaximumSize();
   bool is_resizable = widget->widget_delegate()->CanResize();
   bool shows_resize_controls =
       is_resizable && (min_size.IsEmpty() || min_size != max_size);
   bool shows_fullscreen_controls =
       is_resizable && widget->widget_delegate()->CanMaximize();
@@ skipping 313 matching lines @@
   NSMutableDictionary* properties = objc_getAssociatedObject(
       window_, &kWindowPropertiesKey);
   if (!properties) {
     properties = [NSMutableDictionary dictionary];
     objc_setAssociatedObject(window_, &kWindowPropertiesKey,
                              properties, OBJC_ASSOCIATION_RETAIN);
   }
   return properties;
 }
 
+void BridgedNativeWidget::SetDraggable(bool draggable) {
+  [bridged_view_ setMouseDownCanMoveWindow:draggable];
+  // AppKit will not update it's cache of mouseDownCanMoveWindow unless

[tapted, 2015/05/22 04:03:12]

nit: it's -> its

[jackhou1, 2015/05/25 04:50:19]

Done.

+  // something changes.
+  base::scoped_nsobject<NSView> temp_view(
+      [[NSView alloc] initWithFrame:[bridged_view_ bounds]]);
+  [bridged_view_ addSubview:temp_view];
+  [temp_view removeFromSuperview];
+}
+
 }  // namespace views