Add GN targets for libc++ and libc++abi.

third_party/libc++abi/BUILD.gn

+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+static_library("libc++abi") {
+  sources = [
+    "trunk/src/abort_message.cpp",
+    "trunk/src/cxa_aux_runtime.cpp",
+    "trunk/src/cxa_default_handlers.cpp",
+    "trunk/src/cxa_demangle.cpp",
+    "trunk/src/cxa_exception.cpp",
+    "trunk/src/cxa_exception_storage.cpp",
+    "trunk/src/cxa_guard.cpp",
+    "trunk/src/cxa_handlers.cpp",
+    "trunk/src/cxa_new_delete.cpp",
+    "trunk/src/cxa_personality.cpp",
+    "trunk/src/cxa_unexpected.cpp",
+    "trunk/src/cxa_vector.cpp",
+    "trunk/src/cxa_virtual.cpp",
+    "trunk/src/exception.cpp",
+    "trunk/src/private_typeinfo.cpp",
+    "trunk/src/stdexcept.cpp",
+    "trunk/src/typeinfo.cpp",
+  ]
+  include_dirs = [
+    "trunk/include",
+    "../libc++/trunk/include",
+  ]
+  cflags = [

[earthdok, 2015/05/25 15:48:19]

What happened to the exclusion lists?

      'cflags_cc!': [
        '-fno-exceptions',
        '-fno-rtti',
      ],
      'cflags!': [
        '-fvisibility=hidden',
      ],
      'ldflags!': [
        '-pthread',
      ],

[Sam McNally, 2015/05/26 00:55:49]

The cflags and cflags_cc are handled by removing configs.

I can't figure out a way to remove -pthread from ldflags. Configs and targets
can't remove flags set by other configs; targets can only remove entire configs.
-pthread is set by the //build/config/compiler config, which is probably one we
want to keep.

+    "-fstrict-aliasing",
+    "-nostdinc++",
+    "-std=c++11",
+  ]
+  configs -= [
+    "//build/config/gcc:no_exceptions",
+    "//build/config/compiler:no_rtti",
+    "//build/config/gcc:symbol_visibility_hidden",
+    "//build/config/compiler:chromium_code",
+  ]
+  configs += [
+    "//build/config/compiler:rtti",
+    "//build/config/compiler:no_chromium_code",
+  ]
+  ldflags = [ "-nodefaultlibs" ]
+  libs = [
+    "c",
+    "gcc_s",
+    "pthread",
+    "rt",
+  ]
+}