Build javascript unit tests with gn.

chrome/test/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chrome_build.gni")
 import("//build/config/crypto.gni")
 import("//build/config/features.gni")
 import("//build/config/ui.gni")
 import("//build/module_args/v8.gni")
 import("//testing/test.gni")
@@ skipping 487 matching lines @@
       ]
     }
     if (!is_chromeos) {
       sources -= [
         "../browser/sync/test/integration/wifi_credentials_helper.cc",
         "../browser/sync/test/integration/wifi_credentials_helper.h",
       ]
     }
   }
 
-  template("js2webui") {
+  template("js2gtest") {
+    assert(defined(invoker.test_type) &&
+           (invoker.test_type == "webui" || invoker.test_type == "unit"))
     action_name = target_name + "_action"
     source_set_name = target_name
 
     action_foreach(action_name) {
       testonly = true
       visibility = [ ":$source_set_name" ]
       script = "//tools/gypv8sh.py"
 
       sources = invoker.sources
 
       d8_path =
           get_label_info("//v8:d8($host_toolchain)", "root_out_dir") + "/d8"
       if (is_win) {
         d8_path += ".exe"
       }
 
       input_js = [
         "//chrome/third_party/mock4js/mock4js.js",
         "//chrome/test/data/webui/test_api.js",
         "//chrome/test/base/js2gtest.js",
       ]
       inputs = [ d8_path ] + input_js
 
       outputs = [
         "$target_gen_dir/{{source_name_part}}-gen.cc",
-        "$root_out_dir/test_data/chrome/{{source_root_relative_dir}}/{{source_file_part}}",
+        "$root_out_dir/test_data/{{source_root_relative_dir}}/{{source_file_part}}",
       ]
 
       args = [
         # Need "./" for script to find binary (cur dir is not on path).
         "./" + rebase_path(d8_path, root_build_dir),
       ]
-      args += rebase_path(input_js, root_build_dir) + [ "webui" ]
+      args += rebase_path(input_js, root_build_dir) + [ invoker.test_type ]
       if (v8_use_external_startup_data) {
         args += [ "--external=y" ]
       } else {
         args += [ "--external=n" ]
       }
       args += [
         "{{source}}",
         "{{source_root_relative_dir}}/{{source_file_part}}",
       ]
       args += rebase_path(outputs, root_build_dir)
 
       deps = [
         "//v8:d8($host_toolchain)",
       ]
     }
 
+    if (defined(invoker.extra_js_files)) {
+      copy_target_name = target_name + "_copy"
+      copy(copy_target_name) {
+        visibility = [ ":$source_set_name" ]
+        sources = invoker.extra_js_files
+        outputs = [
+          "$root_out_dir/test_data/{{source_root_relative_dir}}/{{source_file_part}}",
+        ]
+      }
+    }
     source_set(source_set_name) {
       testonly = true
       if (defined(invoker.visibility)) {
         visibility = invoker.visibility
       }
       sources = get_target_outputs(":$action_name")
-      defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
+      if (defined(invoker.defines)) {
+        defines = invoker.defines
+      }
       deps = [
         ":$action_name",
 
         # The generator implicitly makes includes from these targets.
         "//testing/gmock",
         "//testing/gtest",
         "//url",
       ]
       if (defined(invoker.deps)) {
         deps += invoker.deps
       }
+      if (defined(invoker.extra_js_files)) {
+        data_deps = [ ":$copy_target_name" ]
+      }
     }
   }
 
-  js2webui("browser_tests_js_webui") {
+  js2gtest("browser_tests_js_webui") {
+    test_type = "webui"
     sources = rebase_path(
             chrome_tests_gypi_values.chrome_browser_tests_webui_js_sources,
             ".",
             "//chrome")
     if (is_chrome_branded) {
       # crbug.com/230471
       sources -= [ "data/webui/accessibility_audit_browsertest.js" ]
     }
     if (!is_chromeos) {
       sources -= [ "data/webui/certificate_viewer_dialog_test.js" ]
     }
     if (!enable_app_list) {
       sources -= [ "../browser/ui/webui/app_list/start_page_browsertest.js" ]
     }
     if (!enable_supervised_users) {
       sources -=
           [ "../browser/ui/webui/downloads_ui_supervised_browsertest.js" ]
     }
     deps = [
       "//chrome/browser/ui",
       "//skia",
     ]
+    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
   }
 
   test("browser_tests") {
     sources = [
       "base/browser_tests_main.cc",
     ]
     sources +=
         rebase_path(chrome_tests_gypi_values.chrome_browser_tests_sources,
                     ".",
                     "//chrome")
@@ skipping 577 matching lines @@
         "//third_party/widevine/cdm:widevinecdmadapter",
       ]
     }
   }
 
   unit_gypi_values = exec_script("//build/gypi_to_gn.py",
                                  [ rebase_path("../chrome_tests_unit.gypi") ],
                                  "scope",
                                  [ "../chrome_tests_unit.gypi" ])
 
+  js2gtest("unit_tests_js") {
+    test_type = "unit"
+    sources = rebase_path(unit_gypi_values.chrome_unit_tests_gtestjs_sources,
+                          ".",
+                          "//chrome")
+    extra_js_files = rebase_path(unit_gypi_values.chrome_unit_tests_js_sources,
+                                 ".",
+                                 "//chrome")
+    if (is_chromeos) {
+      sources += rebase_path(
+              unit_gypi_values.chrome_unit_tests_chromeos_gtestjs_sources,
+              ".",
+              "//chrome")
+      extra_js_files +=
+          rebase_path(unit_gypi_values.chrome_unit_tests_chromeos_js_sources,
+                      ".",
+                      "//chrome")
+    }
+  }
+
   test("unit_tests") {
     sources =
         rebase_path(unit_gypi_values.chrome_unit_tests_sources, ".", "//chrome")
 
     defines = []
 
     deps = [
       # NOTE: New depndencies should generally be added in the OS!="ios"
       # dependencies block below, rather than here.
       # Unit tests should only depend on:
@@ skipping 34 matching lines @@
       "//ui/resources",
     ]
     data_deps = []
 
     # TODO(GYP) Windows stuff
     # ['incremental_chrome_dll==1', {
     #   'UseLibraryDependencyInputs': "true",
 
     if (!is_ios) {
       deps += [
+        ":unit_tests_js",
         "//components/audio_modem:audio_modem_test_support",
         "//components/autofill/content/browser:test_support",
         "//components/metrics/proto",
         "//components/data_reduction_proxy/core/browser:test_support",
         "//components/webdata_services:test_support",
         "//components/strings",
         "//device/bluetooth:mocks",
         "//content/app/resources",
         "//gpu:test_support",
         "//media:test_support",
@@ skipping 504 matching lines @@
       }
 
       if (cld_version == 0 || cld_version == 2) {
         # Use whatever CLD2 data access mode that the
         # application embedder is using.
         deps += [ "//third_party/cld_2:cld2_platform_impl" ]
       }
     }
   }
 }