Add use_apk_split parameter to java_apk.gypi / android_apk (gn)

build/config/android/rules.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//base/android/linker/config.gni")
 import("//build/config/android/config.gni")
 import("//build/config/android/internal_rules.gni")
 import("//tools/grit/grit_rule.gni")
 import("//tools/relocation_packer/config.gni")
 
@@ skipping 1186 matching lines @@
   if (defined(invoker.testonly)) {
     testonly = invoker.testonly
   }
 
   assert(defined(invoker.final_apk_path) || defined(invoker.apk_name))
   assert(defined(invoker.android_manifest))
   gen_dir = "$target_gen_dir/$target_name"
   base_path = "$gen_dir/$target_name"
   _build_config = "$target_gen_dir/$target_name.build_config"
   resources_zip_path = "$base_path.resources.zip"
-  all_resources_zip_path = "$base_path.resources.all.zip"
+  _all_resources_zip_path = "$base_path.resources.all.zip"
   jar_path = "$base_path.jar"
   final_dex_path = "$gen_dir/classes.dex"
   _template_name = target_name
   _final_apk_path = ""
   if (defined(invoker.final_apk_path)) {
     _final_apk_path = invoker.final_apk_path
   } else if (defined(invoker.apk_name)) {
     _final_apk_path = "$root_build_dir/apks/" + invoker.apk_name + ".apk"
   }
   _dist_jar_path_list =
       process_file_template(
           [ _final_apk_path ],
           "$root_build_dir/test.lib.java/{{source_name_part}}.jar")
   _dist_jar_path = _dist_jar_path_list[0]
 
   _native_libs = []
 
+  _version_code = "1"
+  if (defined(invoker.version_code)) {
+    _version_code = invoker.version_code
+  }
+
+  _version_name = "Developer Build"
+  if (defined(invoker.version_name)) {
+    _version_name = invoker.version_name
+  }
   _keystore_path = android_default_keystore_path
   _keystore_name = android_default_keystore_name
   _keystore_password = android_default_keystore_password
 
   if (defined(invoker.keystore_path)) {
     _keystore_path = invoker.keystore_path
     _keystore_name = invoker.keystore_name
     _keystore_password = invoker.keystore_password
   }
 
@@ skipping 45 matching lines @@
     }
 
     _native_lib_version_name = ""
     if (defined(invoker.native_lib_version_name)) {
       _native_lib_version_name = invoker.native_lib_version_name
     }
   }
 
   _android_manifest = invoker.android_manifest
   _rebased_build_config = rebase_path(_build_config, root_build_dir)
+  _create_abi_split =
+      defined(invoker.create_abi_split) && invoker.create_abi_split
+
+  # Assert to avoid error:
+  #     You set the variable "create_abi_split" here and it was unused before it
+  #     went out of scope.

[cjhopman, 2015/05/16 01:31:10]

I'd just do:

# Mark _create_abi_split as used
assert(_create_abi_split || true)

[agrieve, 2015/05/16 02:21:40]

It's not obvious to my why that would be better.

[cjhopman, 2015/05/16 02:29:07]

I think such a short comment is more typical when marking a variable used in
this way, and I guess I sort of assume that people reading it understand that an
unused variable is an error in gn (without needing the full text of that error).
I don't feel strongly about it though.

[agrieve, 2015/05/17 02:06:10]

Fair enough! :)

+  assert(_create_abi_split || !_create_abi_split)
 
   write_build_config("${_template_name}__build_config") {
     type = "android_apk"
     dex_path = final_dex_path
     resources_zip = resources_zip_path
     build_config = _build_config
     android_manifest = _android_manifest
 
     if (defined(invoker.deps)) {
       deps = invoker.deps
     }
 
     if (defined(invoker.apk_under_test)) {
       apk_under_test = invoker.apk_under_test
     }
 
     native_libs = _native_libs
   }
 
   final_deps = []
 
   final_deps += [ ":${_template_name}__process_resources" ]
   process_resources("${_template_name}__process_resources") {
     srcjar_path = "${target_gen_dir}/${target_name}.srcjar"
     r_text_path = "${target_gen_dir}/${target_name}_R.txt"
     android_manifest = _android_manifest
     resource_dirs = [ "//build/android/ant/empty/res" ]
     zip_path = resources_zip_path
+    all_resources_zip_path = _all_resources_zip_path
     generate_constant_ids = true
     build_config = _build_config
 
     if (defined(invoker.include_all_resources)) {
       include_all_resources = invoker.include_all_resources
     }
   }
   _srcjar_deps += [ ":${_template_name}__process_resources" ]
 
   if (_native_libs != []) {
@@ skipping 136 matching lines @@
         inputs += [ android_gdbserver ]
         args += [ "--libraries=$rebased_gdbserver" ]
       }
     }
   }
 
   final_deps += [ ":${_template_name}__create" ]
   create_apk("${_template_name}__create") {
     apk_path = _final_apk_path
     android_manifest = _android_manifest
-    resources_zip = all_resources_zip_path
+    resources_zip = _all_resources_zip_path
     dex_path = final_dex_path
     load_library_from_apk = _load_library_from_apk
 
-    version_code = "1"
-    if (defined(invoker.version_code)) {
-      version_code = invoker.version_code
-    }
-
-    version_name = "Developer Build"
-    if (defined(invoker.version_name)) {
-      version_name = invoker.version_name
-    }
+    version_code = _version_code
+    version_name = _version_name
 
     keystore_name = _keystore_name
     keystore_path = _keystore_path
     keystore_password = _keystore_password
 
     deps = []
     if (defined(invoker.asset_location)) {
       asset_location = invoker.asset_location
 
       # We don't know the exact dependencies that create the assets in
       # |asset_location|; we depend on all caller deps until a better solution
       # is figured out (http://crbug.com/433330).
       if (defined(invoker.deps)) {
         deps += invoker.deps
       }
     }
 
-    if (_native_libs != []) {
+    if (_native_libs != [] && !_create_abi_split) {
       native_libs_dir = _native_libs_dir
       deps += [ ":${_template_name}__prepare_native" ]
     }
   }
 
+  if (_native_libs != [] && _create_abi_split) {
+    _manifest_rule = "${_template_name}__split_manifest_abi_${android_app_abi}"
+    generate_split_manifest(_manifest_rule) {
+      main_manifest = _android_manifest
+      out_manifest =
+          "$gen_dir/split-manifests/${android_app_abi}/AndroidManifest.xml"
+      split_name = "abi_${android_app_abi}"
+    }
+
+    _apk_rule = "${_template_name}__split_apk_abi_${android_app_abi}"
+    final_deps += [ ":$_apk_rule" ]
+    create_apk(_apk_rule) {
+      _split_paths = process_file_template(
+              [ _final_apk_path ],
+              "{{source_dir}}/{{source_name_part}}-abi-${android_app_abi}.apk")
+      apk_path = _split_paths[0]
+      base_path = "$gen_dir/$_apk_rule"
+
+      manifest_outputs = get_target_outputs(":${_manifest_rule}")
+      android_manifest = manifest_outputs[1]
+      load_library_from_apk = _load_library_from_apk
+
+      version_code = _version_code
+      version_name = _version_name
+
+      keystore_name = _keystore_name
+      keystore_path = _keystore_path
+      keystore_password = _keystore_password
+
+      native_libs_dir = _native_libs_dir
+      deps = [
+        ":${_template_name}__prepare_native",
+      ]
+    }
+  }
+
   group(target_name) {
     deps = final_deps
     if (defined(invoker.datadeps)) {
       datadeps = invoker.datadeps
     }
   }
 }
 
 # Declare an Android gtest apk
 #
@@ skipping 293 matching lines @@
 template("uiautomator_test") {
   set_sources_assignment_filter([])
   if (defined(invoker.testonly)) {
     testonly = invoker.testonly
   }
   assert(target_name != "")
   assert(invoker.deps != [] || true)
   group(target_name) {
   }
 }