Media Router GYP/GN cleanup

chrome/browser/media/router/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 #
 import("//testing/test.gni")
 import("//third_party/mojo/src/mojo/public/tools/bindings/mojom.gni")
 
+gypi_values = exec_script("//build/gypi_to_gn.py",
+                          [ rebase_path("media_router.gypi") ],
+                          "scope",
+                          [ "media_router.gypi" ])
+
 source_set("router") {
   deps = [
-    ":router_core",
+    ":core",
     ":keyed_service_factories",
   ]
 }
 
-source_set("router_core") {
+# TODO(mfoltz): Fix problem that requires explicitly listing //skia
+source_set("core") {
+  defines = [ "ENABLE_MEDIA_ROUTER=1" ]

[brettw, 2015/05/11 21:53:37]

You add this define here, twice (incorrectly) in //chrome/common, in
//chrome/browser, in //chrome/browser/extensions, and in chrome/browser/ui. And
these are controlled by a global build flag.

This isn't a good state to be in, and it's also different than the GYP build.

While I would normally want this flag to be scoped non-globally, the fact that
the define controls some grit flags means you had top make it globa. And since
the build flag is global, I think the define should be as well (in
//build/config:feature_flags config). This will match the GYP build and you can
delete all of these custom defines in various targets.

[mark a. foltz, 2015/05/11 23:08:26]

Okay, done.

This current situation was done in response to
https://codereview.chromium.org/1069063002/diff/20001/build/config/BUILD.gn#n....
 Does the comment in build/config/BUILD.gn need to be updated?

   deps = [
     ":mojo_bindings",
     "//base",
+    "//extensions/browser",
     "//components/keyed_service/core",
     "//third_party/mojo/src/mojo/public/cpp/bindings",
+    "//skia",
     "//url",
   ]
-  sources = [
-    "create_session_request.cc",
-    "create_session_request.h",
-    "issue.cc",
-    "issue.h",
-    "issue_manager.cc",
-    "issue_manager.h",
-    "issues_observer.h",
-    "media_route.cc",
-    "media_route.h",
-    "media_route_id.h",
-    "media_router.h",
-    "media_router_impl.cc",
-    "media_router_impl.h",
-    "media_router_type_converters.cc",
-    "media_router_type_converters.h",
-    "media_routes_observer.cc",
-    "media_routes_observer.h",
-    "media_sink.cc",
-    "media_sink.h",
-    "media_sinks_observer.cc",
-    "media_sinks_observer.h",
-    "media_source.cc",
-    "media_source.h",
-    "media_source_helper.cc",
-    "media_source_helper.h",
-    "presentation_media_sinks_observer.cc",
-    "presentation_media_sinks_observer.h",
-    "route_id_manager.cc",
-    "route_id_manager.h",
-  ]
+  sources = rebase_path(gypi_values.media_router_core_sources,
+                        ".",
+                        "//chrome/browser/media/router")
 }
 
 source_set("keyed_service_factories") {
   deps = [
-    ":router_core",
+    ":core",
     "//components/keyed_service/content",
-  ]
-  sources = [
-    "media_router_impl_factory.cc",
-    "media_router_impl_factory.h",
-  ]
-}
-
-source_set("unit_tests") {
-  testonly = true
-  deps = [
-    ":router_core",
-    ":unit_tests_support",
-    "//base/test:test_support",
-    "//chrome/test:test_support",
-    "//testing/gmock",
-    "//testing/gtest",
+    "//extensions/browser",
     "//third_party/mojo/src/mojo/public/cpp/bindings",
   ]
-  sources = [
-    "media_route_unittest.cc",
-    "media_router_type_converters_unittest.cc",
-    "media_sink_unittest.cc",
-    "media_source_unittest.cc",
-    "presentation_media_sinks_observer_unittest.cc",
-    "route_id_manager_unittest.cc",
-  ]
-}
-
-source_set("unit_tests_support") {
-  testonly = true
-  deps = [
-    ":router_core",
-    "//testing/gmock",
-  ]
-  sources = [
-    "mock_media_router.cc",
-    "mock_media_router.h",
-    "mock_screen_availability_listener.cc",
-    "mock_screen_availability_listener.h",
-  ]
+  sources =
+      rebase_path(gypi_values.media_router_keyed_service_factories_sources,
+                  ".",
+                  "//chrome/browser/media/router")
 }
 
 mojom("mojo_bindings") {
   sources = [
     "media_router.mojom",
   ]
 }
 
-# Optional standalone test binary, for faster isolated builds.
-test("unit_tests_main") {
+# TODO(mfoltz): Fix problem that requires explicitly listing //skia
+source_set("unit_tests") {
+  testonly = true
   deps = [
-    ":unit_tests",
-    "//testing/gmock:gmock_main",
+    ":core",
+    ":mojo_bindings",
+    ":test_support",
+    "//base/test:test_support",
+    "//chrome/test:test_support",
+    "//skia",
+    "//testing/gmock",
+    "//testing/gtest",
+    "//third_party/mojo/src/mojo/public/cpp/bindings",
   ]
-  sources = [
-    ":unittest_files",
+  sources =
+      rebase_path(gypi_values.media_router_unit_tests_sources, ".", "//chrome")
+}
+
+# TODO(mfoltz): Fix browser tests, then link into //chrome/test:browser_tests
+source_set("browser_tests") {
+  testonly = true
+  deps = [
+    ":core",
+    ":test_support",
+    "//base",
+    "//base/test:test_support",
+    "//chrome/browser/ui",
+    "//chrome/common:constants",
+    "//content/test:test_support",
+    "//content/public/browser",
+    "//content/public/common",
+    "//net:test_support",
+    "//skia",
+    "//testing/gmock",
+    "//testing/gtest",
   ]
+  sources = rebase_path(gypi_values.media_router_ui_browser_tests_sources,
+                        ".",
+                        "//chrome/browser/media/router")
 }
+
+source_set("test_support") {
+  testonly = true
+  deps = [
+    ":core",
+    ":mojo_bindings",
+    "//chrome/test:test_support",
+    "//testing/gmock",
+  ]
+  sources = rebase_path(gypi_values.media_router_test_support_sources,
+                        ".",
+                        "//chrome/browser/media/router")
+}