Enable proguard for apks

build/config/android/rules.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//base/android/linker/config.gni")
 import("//build/config/android/config.gni")
 import("//build/config/android/internal_rules.gni")
 import("//third_party/android_platform/config.gni")
 import("//tools/grit/grit_rule.gni")
 
@@ skipping 1452 matching lines @@
 
   _rebased_build_config = rebase_path(_build_config, root_build_dir)
   _create_abi_split =
       defined(invoker.create_abi_split) && invoker.create_abi_split
   _create_density_splits =
       defined(invoker.create_density_splits) && invoker.create_density_splits
 
   # Help GN understand that _create_abi_split is not unused (bug in GN).
   assert(_create_abi_split || true)
 
+  _proguard_enabled = false
+  if (defined(invoker.proguard_enabled) && invoker.proguard_enabled) {
+    _proguard_enabled = true
+    _proguard_jar_path = "$base_path.proguard.jar"
+  }
+
   build_config_target = "${_template_name}__build_config"
   write_build_config(build_config_target) {
     type = "android_apk"
     dex_path = final_dex_path
     resources_zip = resources_zip_path
     build_config = _build_config
     android_manifest = _android_manifest
 
     deps = _chromium_linker_dep + _android_manifest_deps
     if (defined(invoker.deps)) {
       deps += invoker.deps
     }
 
     if (defined(invoker.apk_under_test)) {
       apk_under_test = invoker.apk_under_test
     }
 
+    if (_proguard_enabled) {
+      proguard_enabled = true
+      proguard_info = "$_proguard_jar_path.info"
+    }
+
     native_libs = _native_libs
   }
 
   final_deps = []
 
+  _generated_proguard_config = "$base_path.resources.proguard.txt"
   process_resources_target = "${_template_name}__process_resources"
   final_deps += [ ":$process_resources_target" ]
   process_resources(process_resources_target) {
     srcjar_path = "${target_gen_dir}/${target_name}.srcjar"
     r_text_path = "${target_gen_dir}/${target_name}_R.txt"
     android_manifest = _android_manifest
     resource_dirs = [ "//build/android/ant/empty/res" ]
     zip_path = resources_zip_path
     all_resources_zip_path = _all_resources_zip_path
     generate_constant_ids = true
+    proguard_file = _generated_proguard_config
 
     if (defined(invoker.include_all_resources)) {
       include_all_resources = invoker.include_all_resources
     }
 
     build_config = _build_config
     deps = _android_manifest_deps + [ ":$build_config_target" ]
     if (defined(invoker.deps)) {
       deps += invoker.deps
     }
@@ skipping 88 matching lines @@
       inputs += [ jar_path ]
       _rebased_jar_path = rebase_path([ jar_path ], root_build_dir)
       args += [ "--inputs=$_rebased_jar_path" ]
       deps = [
         ":$build_config_target",  # Generates the build config file.
         ":$java_target",  # Generates the jar file.
       ]
     }
   }
 
+  if (defined(invoker.proguard_enabled) && invoker.proguard_enabled) {
+    _proguard_configs = [ _generated_proguard_config ]
+    if (defined(invoker.proguard_configs)) {
+      _proguard_configs += invoker.proguard_configs
+    }
+    proguard_target = "${_template_name}__proguard"
+    proguard(proguard_target) {
+      deps = [
+        ":$build_config_target",
+        ":$process_resources_target",
+        ":$java_target",
+      ]
+      inputs = [
+                 _build_config,
+                 jar_path,
+               ] + _proguard_configs
+
+      output_jar_path = _proguard_jar_path
+      rebased_proguard_configs = rebase_path(_proguard_configs, root_build_dir)
+      args = [
+        "--proguard-configs=$rebased_proguard_configs",
+        "--tested-apk-info=@FileArg($_rebased_build_config:proguard:tested_apk_info)",
+        "--input-paths=@FileArg($_rebased_build_config:proguard:input_paths)",
+      ]
+    }
+    dex_jar_path = _proguard_jar_path
+    dex_deps = [ ":$proguard_target" ]
+  } else {
+    dex_jar_path = jar_path
+    dex_deps = [ ":$java_target" ]
+  }
+
   final_deps += [ ":$final_dex_target_name" ]
   dex("$final_dex_target_name") {
-    deps = [
-      ":$build_config_target",
-      ":$java_target",
-    ]
+    deps = dex_deps + [ ":$build_config_target" ]
     sources = [
-      jar_path,
+      dex_jar_path,
     ]
     inputs = [
       _build_config,
     ]
     output = final_dex_path
     dex_arg_key = "${_rebased_build_config}:final_dex:dependency_dex_files"
     args = [ "--inputs=@FileArg($dex_arg_key)" ]
   }
 
   if (_native_libs != []) {
@@ skipping 243 matching lines @@
     }
     if (defined(invoker.apk_name)) {
       apk_name = invoker.apk_name
     }
     if (defined(invoker.final_apk_path)) {
       final_apk_path = invoker.final_apk_path
     }
     if (defined(invoker.native_libs)) {
       native_libs = invoker.native_libs
     }
+    if (defined(invoker.proguard_enabled)) {
+      proguard_enabled = invoker.proguard_enabled
+    }
     if (defined(invoker.apk_under_test)) {
       apk_under_test = invoker.apk_under_test
     }
     if (defined(invoker.DEPRECATED_java_in_dir)) {
       DEPRECATED_java_in_dir = invoker.DEPRECATED_java_in_dir
     }
   }
 }
 
 # Declare an Android gtest apk
@@ skipping 317 matching lines @@
 template("uiautomator_test") {
   set_sources_assignment_filter([])
   if (defined(invoker.testonly)) {
     testonly = invoker.testonly
   }
   assert(target_name != "")
   assert(invoker.deps != [] || true)
   group(target_name) {
   }
 }