Dismiss context menu when download bar is closed.

chrome/browser/ui/cocoa/download/download_item_button.mm

-// Copyright (c) 2012 The Chromium Authors. All rights reserved.
+// Copyright 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/download/download_item_button.h"
 
 #include "base/logging.h"
 #include "base/strings/sys_string_conversions.h"
 #import "chrome/browser/ui/cocoa/download/download_item_cell.h"
 #import "chrome/browser/ui/cocoa/download/download_item_controller.h"
 #import "chrome/browser/ui/cocoa/download/download_shelf_context_menu_controller.h"
 #import "chrome/browser/ui/cocoa/view_id_util.h"
 #import "ui/base/cocoa/nsview_additions.h"
 
 @implementation DownloadItemButton
 
 @synthesize download = downloadPath_;
 @synthesize controller = controller_;
 
 // Overridden from DraggableButton.
 - (void)beginDrag:(NSEvent*)event {
   if (!downloadPath_.empty()) {
     NSString* filename = base::SysUTF8ToNSString(downloadPath_.value());
     [self dragFile:filename fromRect:[self bounds] slideBack:YES event:event];
   }
 }
 
+- (void)showContextMenu {
+  base::scoped_nsobject<DownloadShelfContextMenuController> menuController(
+      [[DownloadShelfContextMenuController alloc]
+          initWithItemController:controller_
+                    withDelegate:self]);
+  showingContextMenu_ = YES;
+  [NSMenu popUpContextMenu:[menuController menu]
+                 withEvent:[NSApp currentEvent]
+                   forView:self];
+}
+
 // Override to show a context menu on mouse down if clicked over the context
 // menu area.
 - (void)mouseDown:(NSEvent*)event {
   DCHECK(controller_);
   // Override so that we can pop up a context menu on mouse down.
   NSCell* cell = [self cell];
   DCHECK([cell respondsToSelector:@selector(isMouseOverButtonPart)]);
   if ([reinterpret_cast<DownloadItemCell*>(cell) isMouseOverButtonPart]) {
     [self.draggableButton mouseDownImpl:event];
   } else {
-    base::scoped_nsobject<DownloadShelfContextMenuController> menuController(
-        [[DownloadShelfContextMenuController alloc]
-            initWithItemController:controller_
-                      withDelegate:self]);
-
     [cell setHighlighted:YES];
-    [NSMenu popUpContextMenu:[menuController menu]
-                   withEvent:[NSApp currentEvent]
-                     forView:self];
+    [self showContextMenu];
   }
 }
 
 // Override to retain the controller, in case a closure is pumped that deletes
 // the DownloadItemController while the menu is open <http://crbug.com/129826>.
 - (void)rightMouseDown:(NSEvent*)event {
   base::scoped_nsobject<DownloadItemController> ref([controller_ retain]);
   [super rightMouseDown:event];
 }
 
 - (void)menuDidClose:(NSMenu*)menu {
+  showingContextMenu_ = NO;
   [[self cell] setHighlighted:NO];
 }
 
 - (BOOL)shouldDelayWindowOrderingForEvent:(NSEvent*)event {
   return YES;
 }
 
 - (BOOL)isOpaque {
   // Make this control opaque so that sub-pixel anti-aliasing works when
   // CoreAnimation is enabled.
   return YES;
 }
 
 - (void)drawRect:(NSRect)rect {
   NSView* downloadShelfView = [self ancestorWithViewID:VIEW_ID_DOWNLOAD_SHELF];
   [self cr_drawUsingAncestor:downloadShelfView inRect:rect];
   [super drawRect:rect];
 }
 
 // ThemedWindowDrawing implementation.
 
 - (void)windowDidChangeTheme {
   [self setNeedsDisplay:YES];
 }
 
 - (void)windowDidChangeActive {
   [self setNeedsDisplay:YES];
 }
 
+- (BOOL)showingContextMenu
+{
+  return showingContextMenu_;
+}
+
+- (void)viewWillMoveToWindow:(NSWindow *)newWindow {

[asanka, 2015/05/08 17:12:47]

Shall we trigger the menu close logic on the download removal pathway described
above?

[shrike, 2015/05/08 17:52:04]

By "described above" do you mean your previous comment about watching for
download items marked as open, or somewhere "above" in the code? I think it
makes sense to incorporate the marked as open case - can you suggest a download
item, or class of items, that would produce this behavior (so that I can test)?

[asanka, 2015/05/12 01:27:33]

Sorry, I was referring to https://codereview.chromium.org/1125423002#msg9 .

+  // If the DownloadItemButton's context menu is still visible, synthesize an
+  // Escape key event to hide it (there is no API to explicitly dismiss a
+  // pop up menu).

[asanka, 2015/05/08 17:12:47]

What about NSMenu cancelTracking: ?

[shrike, 2015/05/08 17:52:04]

Indeed, but the problem is that popUpContextMenu: does not return the popup menu
(i.e. there is no way to get the popup menu in order to call cancelTracking: on
it).

[asanka, 2015/05/12 01:27:33]

Can we keep a reference to the DownloadShelfContextMenuController or the NSMenu
that we are passing into popUpContextMenu?

+  if (showingContextMenu_ && !newWindow) {
+    unichar escapeString[] = { 27, 0 };
+    NSString* escapeCharacterString =
+        [NSString stringWithCharacters:escapeString length:1];
+    NSEvent* escapeKeyEvent =
+        [NSEvent keyEventWithType:NSKeyDown
+                          location:NSZeroPoint
+                     modifierFlags:0
+                         timestamp:[[NSDate date] timeIntervalSinceNow]
+                      windowNumber:[[self window] windowNumber]
+                           context:NULL
+                        characters:escapeCharacterString
+       charactersIgnoringModifiers:escapeCharacterString
+                         isARepeat:NO
+                           keyCode:53];
+    [[NSApplication sharedApplication] postEvent:escapeKeyEvent atStart:YES];
+  }
+}
+
 @end