Merge device/vibration/android/BUILD.gn to vibration/BUILD.gn.

device/vibration/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/features.gni")
 import("//third_party/mojo/src/mojo/public/tools/bindings/mojom.gni")
 
+if (is_android) {
+  import("//build/config/android/config.gni")
+  import("//build/config/android/rules.gni")  # For generate_jni().
+}
+
 component("vibration") {
   output_name = "device_vibration"
 
   sources = [
+    "android/vibration_jni_registrar.cc",

[timvolodine, 2015/05/14 12:16:36]

looks like this is only needed for android?

[scheib, 2015/05/14 16:43:00]

As in GYP, platform files are implicitly filtered:
See set_sources_assignment_filter
https://chromium.googlesource.com/chromium/src/+/master/tools/gn/docs/referen...
https://code.google.com/p/chromium/codesearch#chromium/src/build/config/BUILD...

[scheib, 2015/05/14 16:48:16]

Actually, since the if (is_android) block below is already modifying sources,
I've moved the android sources there too.

+    "android/vibration_jni_registrar.h",
     "vibration_export.h",
     "vibration_manager_impl.h",
     "vibration_manager_impl_android.cc",
     "vibration_manager_impl_android.h",
-    "vibration_manager_impl_default.cc",
   ]
 
   defines = [ "DEVICE_VIBRATION_IMPLEMENTATION" ]
 
   deps = [
     ":mojo_bindings",
     "//base",
     "//base/third_party/dynamic_annotations",
     "//mojo/environment:chromium",
     "//third_party/mojo/src/mojo/public/cpp/bindings",
     "//third_party/mojo/src/mojo/edk/system",
   ]
 
   if (is_android) {
-    sources -= [ "vibration_manager_impl_default.cc" ]
-    deps += [
-      "//device/vibration/android",
-      "//device/vibration/android:vibration_jni_headers",
-    ]
-    allow_circular_includes_from = [ "//device/vibration/android" ]
+    deps += [ ":vibration_jni_headers" ]
+  } else {
+    sources += [ "vibration_manager_impl_default.cc" ]

[timvolodine, 2015/05/14 12:16:36]

nit: no need for else if you use sources -= [
"vibration_manager_impl_default.cc" ], but I don't feel strongly about it ;)

[scheib, 2015/05/14 16:43:00]

GN style guide: List sources only once:
https://chromium.googlesource.com/chromium/src/+/master/tools/gn/docs/style_g...

   }
 }
 
 mojom("mojo_bindings") {
   sources = [
     "vibration_manager.mojom",
   ]
 }
+
+if (is_android) {
+  generate_jni("vibration_jni_headers") {
+    sources = [
+      "android/java/src/org/chromium/device/vibration/VibrationProvider.java",
+    ]
+    jni_package = "vibration"
+  }
+}