Add right-click user switching tutorial bubble.

chrome/browser/ui/cocoa/profiles/profile_chooser_controller.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import <Cocoa/Cocoa.h>
 #import <Carbon/Carbon.h>  // kVK_Return.
 
 #import "chrome/browser/ui/cocoa/profiles/profile_chooser_controller.h"
 
 #include "base/mac/bundle_locations.h"
@@ skipping 860 matching lines @@
 - (BOOL)canBecomeKeyView {
   return NO;
 }
 
 @end
 
 @interface ProfileChooserController ()
 // Builds the profile chooser view.
 - (NSView*)buildProfileChooserView;
 
+- (NSView*)buildTutorialViewIfNeededForItem:(const AvatarMenu::Item&)item;
+
 // Builds a tutorial card with a title label using |titleMessage|, a content
 // label using |contentMessage|, a link using |linkMessage|, and a button using
 // |buttonMessage|. If |stackButton| is YES, places the button above the link.
 // Otherwise places both on the same row with the link left aligned and button
 // right aligned. On click, the link would execute |linkAction|, and the button
 // would execute |buttonAction|. It sets |tutorialMode_| to the given |mode|.
 - (NSView*)tutorialViewWithMode:(profiles::TutorialMode)mode
                    titleMessage:(NSString*)titleMessage
                  contentMessage:(NSString*)contentMessage
                     linkMessage:(NSString*)linkMessage
                   buttonMessage:(NSString*)buttonMessage
                     stackButton:(BOOL)stackButton
                  hasCloseButton:(BOOL)hasCloseButton
                      linkAction:(SEL)linkAction
                    buttonAction:(SEL)buttonAction;
 
+// Returns YES if the Welcome/Upgrade tutorial bubble should be shown to the
+// user, NO otherwise.
+- (BOOL)shouldShowWelcomeUpgradeTutorial;
+
+// Returns YES if the tutorial informing the user about right-click user
+// switching should be shown, NO otherwise.
+- (BOOL)shouldShowRightClickTutorialView;
+
 // Builds a tutorial card to introduce an upgrade user to the new avatar menu if
 // needed. |tutorial_shown| indicates if the tutorial has already been shown in
 // the previous active view. |avatar_item| refers to the current profile.
-- (NSView*)buildWelcomeUpgradeTutorialViewIfNeeded;
+- (NSView*)buildWelcomeUpgradeTutorialView:(const AvatarMenu::Item&)item;
+
+// Builds a tutorial card to inform the user about right-click user switching if
+// needed.
+- (NSView*)buildRightClickTutorialView;
 
 // Builds a tutorial card to have the user confirm the last Chrome signin,
 // Chrome sync will be delayed until the user either dismisses the tutorial, or
 // configures sync through the "Settings" link.
 - (NSView*)buildSigninConfirmationView;
 
 // Builds a tutorial card to show the last signin error.
 - (NSView*)buildSigninErrorView;
 
 // Creates the main profile card for the profile |item| at the top of
@@ skipping 211 matching lines @@
 }
 
 - (IBAction)dismissTutorial:(id)sender {
   // Never shows the upgrade tutorial again if manually closed.
   if (tutorialMode_ == profiles::TUTORIAL_MODE_WELCOME_UPGRADE) {
     browser_->profile()->GetPrefs()->SetInteger(
         prefs::kProfileAvatarTutorialShown,
         signin_ui_util::kUpgradeWelcomeTutorialShowMax + 1);
   }
 
+  if(tutorialMode_ == profiles::TUTORIAL_MODE_RIGHT_CLICK_SWITCHING) {
+    PrefService* localState = g_browser_process->local_state();
+    localState->SetBoolean(
+        prefs::kProfileAvatarRightClickTutorialDismissed, true);
+  }
+
   tutorialMode_ = profiles::TUTORIAL_MODE_NONE;
   [self initMenuContentsWithView:profiles::BUBBLE_VIEW_MODE_PROFILE_CHOOSER];
 }
 
 - (void)windowWillClose:(NSNotification*)notification {
   if (tutorialMode_ == profiles::TUTORIAL_MODE_CONFIRM_SIGNIN) {
     LoginUIServiceFactory::GetForProfile(browser_->profile())->
         SyncConfirmationUIClosed(false);
   }
 
@@ skipping 121 matching lines @@
       [[NSView alloc] initWithFrame:NSZeroRect]);
 
   NSView* tutorialView = nil;
   NSView* currentProfileView = nil;
   base::scoped_nsobject<NSMutableArray> otherProfiles(
       [[NSMutableArray alloc] init]);
   // Local and guest profiles cannot lock their profile.
   bool displayLock = false;
   bool isFastProfileChooser =
       viewMode_ == profiles::BUBBLE_VIEW_MODE_FAST_PROFILE_CHOOSER;
+  if (isFastProfileChooser) {
+    // The user is using right-click switching, no need to tell them about it.
+    PrefService* localState = g_browser_process->local_state();
+    localState->SetBoolean(
+        prefs::kProfileAvatarRightClickTutorialDismissed, true);
+  }
 
   // Loop over the profiles in reverse, so that they are sorted by their
   // y-coordinate, and separate them into active and "other" profiles.
   for (int i = avatarMenu_->GetNumberOfItems() - 1; i >= 0; --i) {
     const AvatarMenu::Item& item = avatarMenu_->GetItemAt(i);
     if (item.active) {
       if (viewMode_ == profiles::BUBBLE_VIEW_MODE_PROFILE_CHOOSER) {
-        switch (tutorialMode_) {
-          case profiles::TUTORIAL_MODE_NONE:
-          case profiles::TUTORIAL_MODE_WELCOME_UPGRADE:
-            tutorialView =
-                [self buildWelcomeUpgradeTutorialViewIfNeeded];
-            break;
-          case profiles::TUTORIAL_MODE_CONFIRM_SIGNIN:
-            tutorialView = [self buildSigninConfirmationView];
-            break;
-          case profiles::TUTORIAL_MODE_SHOW_ERROR:
-            tutorialView = [self buildSigninErrorView];
-        }
+        tutorialView = [self buildTutorialViewIfNeededForItem:item];
       }
       currentProfileView = [self createCurrentProfileView:item];
       displayLock = item.signed_in &&
           profiles::IsLockAvailable(browser_->profile());
     } else {
       [otherProfiles addObject:[self createOtherProfileView:i]];
     }
   }
   if (!currentProfileView)  // Guest windows don't have an active profile.
     currentProfileView = [self createGuestProfileView];
@@ skipping 116 matching lines @@
                        titleMessage:titleMessage
                      contentMessage:contentMessage
                         linkMessage:linkMessage
                       buttonMessage:nil
                         stackButton:NO
                      hasCloseButton:YES
                          linkAction:@selector(showLearnMorePage:)
                        buttonAction:nil];
 }
 
-- (NSView*)buildWelcomeUpgradeTutorialViewIfNeeded {
+- (BOOL)shouldShowWelcomeUpgradeTutorial {
   Profile* profile = browser_->profile();
-  const AvatarMenu::Item& avatarItem =
-      avatarMenu_->GetItemAt(avatarMenu_->GetActiveProfileIndex());
 
   const int showCount = profile->GetPrefs()->GetInteger(
       prefs::kProfileAvatarTutorialShown);
   // Do not show the tutorial if user has dismissed it.
   if (showCount > signin_ui_util::kUpgradeWelcomeTutorialShowMax)
-    return nil;
+    return NO;
 
-  if (tutorialMode_ != profiles::TUTORIAL_MODE_WELCOME_UPGRADE) {
-    if (showCount == signin_ui_util::kUpgradeWelcomeTutorialShowMax)
-      return nil;
-    profile->GetPrefs()->SetInteger(
-        prefs::kProfileAvatarTutorialShown, showCount + 1);
-  }
+  return tutorialMode_ == profiles::TUTORIAL_MODE_WELCOME_UPGRADE ||

[groby-ooo-7-16, 2015/05/07 01:59:01]

That's returning a bool, not BOOL.  Since you never compare the return value to
YES/NO, I'd suggest just using bool as return type.

[anthonyvd, 2015/05/12 16:09:11]

Thanks! Done.

+         showCount != signin_ui_util::kUpgradeWelcomeTutorialShowMax;
+}
 
+- (BOOL)shouldShowRightClickTutorialView {
+  PrefService* localState = g_browser_process->local_state();
+  const bool dismissed = localState->GetBoolean(
+      prefs::kProfileAvatarRightClickTutorialDismissed);
+
+  // Don't show the tutorial if it's already been dismissed or if right-clicking
+  // wouldn't show any targets.
+  return !dismissed && profiles::HasProfileSwitchTargets(browser_->profile());
+}
+
+- (NSView*)buildWelcomeUpgradeTutorialView:(const AvatarMenu::Item&)item {
   ProfileMetrics::LogProfileNewAvatarMenuUpgrade(
       ProfileMetrics::PROFILE_AVATAR_MENU_UPGRADE_VIEW);
 
   NSString* titleMessage = l10n_util::GetNSString(
       IDS_PROFILES_WELCOME_UPGRADE_TUTORIAL_TITLE);
   NSString* contentMessage = l10n_util::GetNSString(
       IDS_PROFILES_WELCOME_UPGRADE_TUTORIAL_CONTENT_TEXT);
   // For local profiles, the "Not you" link doesn't make sense.
-  NSString* linkMessage = avatarItem.signed_in ?
+  NSString* linkMessage = item.signed_in ?
       ElideMessage(
-          l10n_util::GetStringFUTF16(IDS_PROFILES_NOT_YOU, avatarItem.name),
+          l10n_util::GetStringFUTF16(IDS_PROFILES_NOT_YOU, item.name),
           kFixedMenuWidth - 2 * kHorizontalSpacing) :
       nil;
   NSString* buttonMessage = l10n_util::GetNSString(
       IDS_PROFILES_TUTORIAL_WHATS_NEW_BUTTON);
   return [self tutorialViewWithMode:profiles::TUTORIAL_MODE_WELCOME_UPGRADE
                        titleMessage:titleMessage
                      contentMessage:contentMessage
                         linkMessage:linkMessage
                       buttonMessage:buttonMessage
                         stackButton:YES
                      hasCloseButton:YES
                          linkAction:@selector(showSwitchUserView:)
                        buttonAction:@selector(seeWhatsNew:)];
 }
 
+- (NSView*)buildRightClickTutorialView {
+  NSString* titleMessage = l10n_util::GetNSString(
+      IDS_PROFILES_RIGHT_CLICK_TUTORIAL_TITLE);
+  NSString* contentMessage = l10n_util::GetNSString(
+      IDS_PROFILES_RIGHT_CLICK_TUTORIAL_CONTENT_TEXT);
+  NSString* buttonMessage = l10n_util::GetNSString(
+      IDS_PROFILES_TUTORIAL_OK_BUTTON);
+
+  return
+      [self tutorialViewWithMode:profiles::TUTORIAL_MODE_RIGHT_CLICK_SWITCHING
+                             titleMessage:titleMessage
+                           contentMessage:contentMessage
+                              linkMessage:nil
+                            buttonMessage:buttonMessage
+                              stackButton:NO
+                           hasCloseButton:NO
+                               linkAction:nil
+                             buttonAction:@selector(dismissTutorial:)];
+}
+
+- (NSView*)buildTutorialViewIfNeededForItem:(const AvatarMenu::Item&)item {
+  if (tutorialMode_ == profiles::TUTORIAL_MODE_CONFIRM_SIGNIN)
+    return [self buildSigninConfirmationView];
+
+  if (tutorialMode_ == profiles::TUTORIAL_MODE_SHOW_ERROR)
+    return [self buildSigninErrorView];
+
+  if ([self shouldShowWelcomeUpgradeTutorial]) {

[groby-ooo-7-16, 2015/05/07 01:59:01]

If I read this correctly, this code only updates the counter if we're not
already in welcomeUpgradeTutorial mode, but it always builds the view.

I'm not quite clear how you could end up in that situation - could you
elaborate?

[anthonyvd, 2015/05/12 16:09:11]

I moved this code as-is from line 1439 of the previous version but my
understanding is that building the tutorial view sets tutorialMode_ to
profiles::TUTORIAL_MODE_WELCOME_UPGRADE. Other code can rebuild the menu with
the current tutorial mode without user interaction (for example to refresh it)
and that shouldn't affect the "shown" counter so it's only incremented when we
actually take the decision to go into that mode.

+    if (tutorialMode_ != profiles::TUTORIAL_MODE_WELCOME_UPGRADE) {
+      Profile* profile = browser_->profile();
+      const int showCount = profile->GetPrefs()->GetInteger(
+          prefs::kProfileAvatarTutorialShown);
+      profile->GetPrefs()->SetInteger(
+          prefs::kProfileAvatarTutorialShown, showCount + 1);
+    }
+
+    return [self buildWelcomeUpgradeTutorialView:item];
+  }
+
+  if ([self shouldShowRightClickTutorialView])
+    return [self buildRightClickTutorialView];
+
+  return nil;
+}
+
 - (NSView*)tutorialViewWithMode:(profiles::TutorialMode)mode
                    titleMessage:(NSString*)titleMessage
                  contentMessage:(NSString*)contentMessage
                     linkMessage:(NSString*)linkMessage
                   buttonMessage:(NSString*)buttonMessage
                     stackButton:(BOOL)stackButton
                  hasCloseButton:(BOOL)hasCloseButton
                      linkAction:(SEL)linkAction
                    buttonAction:(SEL)buttonAction {
   tutorialMode_ = mode;
@@ skipping 833 matching lines @@
 }
 
 - (bool)shouldShowGoIncognito {
   bool incognitoAvailable =
       IncognitoModePrefs::GetAvailability(browser_->profile()->GetPrefs()) !=
           IncognitoModePrefs::DISABLED;
   return incognitoAvailable && !browser_->profile()->IsGuestSession();
 }
 
 @end