Autofill OSX: Add PermanentErrorMessage box and label.

chrome/browser/ui/cocoa/autofill/card_unmask_prompt_view_bridge.mm

 // Copyright (c) 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "base/bind.h"
 #include "base/message_loop/message_loop.h"
 #include "base/strings/sys_string_conversions.h"
 #include "chrome/browser/ui/autofill/autofill_dialog_models.h"
 #include "chrome/browser/ui/autofill/autofill_dialog_types.h"
 #include "chrome/browser/ui/autofill/card_unmask_prompt_controller.h"
+#include "chrome/browser/ui/chrome_style.h"
 #import "chrome/browser/ui/cocoa/autofill/autofill_tooltip_controller.h"
 #include "chrome/browser/ui/cocoa/autofill/card_unmask_prompt_view_bridge.h"
 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_button.h"
-#include "chrome/browser/ui/chrome_style.h"
 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_control_utils.h"
 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_custom_sheet.h"
 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_custom_window.h"
 #import "chrome/browser/ui/cocoa/key_equivalent_constants.h"
+#import "chrome/browser/ui/cocoa/l10n_util.h"
 #include "grit/generated_resources.h"
 #include "grit/theme_resources.h"
 #include "skia/ext/skia_utils_mac.h"
 #include "ui/base/cocoa/window_size_constants.h"
 #include "ui/base/l10n/l10n_util.h"
 
 namespace {
 
 const CGFloat kButtonGap = 6.0f;
 const CGFloat kDialogContentMinWidth = 210.0f;
 const CGFloat kCvcInputWidth = 64.0f;
+const SkColor kPermanentErrorTextColor = SK_ColorWHITE;
+const SkColor kPermanentErrorBackgroundColor = SkColorSetRGB(0xd3, 0x2f, 0x2f);
 const ui::ResourceBundle::FontStyle kProgressFontStyle =
     chrome_style::kTitleFontStyle;
 const ui::ResourceBundle::FontStyle kErrorFontStyle =
     chrome_style::kTextFontStyle;
 
 }  // namespace
 
 namespace autofill {
 
 // static
@@ skipping 41 matching lines @@
     [view_controller_ setProgressOverlayText:
                           l10n_util::GetStringUTF16(
                               IDS_AUTOFILL_CARD_UNMASK_VERIFICATION_SUCCESS)];
 
     base::MessageLoop::current()->PostDelayedTask(
         FROM_HERE, base::Bind(&CardUnmaskPromptViewBridge::PerformClose,
                               weak_ptr_factory_.GetWeakPtr()),
         base::TimeDelta::FromSeconds(1));
   } else {
     [view_controller_ setProgressOverlayText:base::string16()];
-    // TODO(bondd): Views version never hides |errorLabel_|. When Views decides
-    // when to hide it then do the same thing here.
-    [view_controller_ setRetriableErrorMessage:error_message];
+
+    if (allow_retry) {
+      // TODO(bondd): Views version never hides |errorLabel_|. When Views
+      // decides when to hide it then do the same thing here.
+      [view_controller_ setRetriableErrorMessage:error_message];
+    } else {
+      [view_controller_ setPermanentErrorMessage:error_message];
+    }
   }
 }
 
 void CardUnmaskPromptViewBridge::OnConstrainedWindowClosed(
     ConstrainedWindowMac* window) {
   if (controller_)
     controller_->OnUnmaskDialogClosed();
   base::MessageLoop::current()->DeleteSoon(FROM_HERE, this);
 }
 
 CardUnmaskPromptController* CardUnmaskPromptViewBridge::GetController() {
   return controller_;
 }
 
 void CardUnmaskPromptViewBridge::PerformClose() {
   constrained_window_->CloseWebContentsModalDialog();
 }
 
 }  // autofill
 
 #pragma mark CardUnmaskPromptViewCocoa
 
 @implementation CardUnmaskPromptViewCocoa {
+  base::scoped_nsobject<NSBox> permanentErrorBox_;
   base::scoped_nsobject<NSView> inputRowView_;
   base::scoped_nsobject<NSView> storageView_;
 
   base::scoped_nsobject<NSTextField> titleLabel_;
+  base::scoped_nsobject<NSTextField> permanentErrorLabel_;
   base::scoped_nsobject<NSTextField> instructionsLabel_;
   base::scoped_nsobject<NSTextField> cvcInput_;
   base::scoped_nsobject<NSPopUpButton> monthPopup_;
   base::scoped_nsobject<NSPopUpButton> yearPopup_;
   base::scoped_nsobject<NSButton> cancelButton_;
   base::scoped_nsobject<NSButton> verifyButton_;
   base::scoped_nsobject<NSButton> storageCheckbox_;
   base::scoped_nsobject<AutofillTooltipController> storageTooltip_;
   base::scoped_nsobject<NSTextField> errorLabel_;
   base::scoped_nsobject<NSTextField> progressOverlayLabel_;
 
   int monthPopupDefaultIndex_;
   int yearPopupDefaultIndex_;
 
   // Owns |self|.
   autofill::CardUnmaskPromptViewBridge* bridge_;
 }
 
 + (NSPopUpButton*)buildDatePopupWithModel:(ui::ComboboxModel&)model {
   NSPopUpButton* popup =
       [[NSPopUpButton alloc] initWithFrame:NSZeroRect pullsDown:NO];
 
   for (int i = 0; i < model.GetItemCount(); ++i) {
     [popup addItemWithTitle:base::SysUTF16ToNSString(model.GetItemAt(i))];
   }
   [popup sizeToFit];
   return popup;
 }
 
-// Sets |textField|'s frame size to minimum dimensions needed to display its
-// text without exceeding |width|. Text will wrap onto multiple lines if
-// necessary. Frame width may end up being less than |width| if the text fits
-// in a smaller area.
-+ (void)sizeTextField:(NSTextField*)textField toFitWidth:(CGFloat)width {
-  NSSize frameSize =
-      [[textField cell] cellSizeForBounds:NSMakeRect(0, 0, width, CGFLOAT_MAX)];
-  [textField setFrameSize:frameSize];
-}
-
 // Set |view|'s frame to the minimum dimensions required to contain all of its
 // subviews.
 + (void)sizeToFitView:(NSView*)view {
   NSRect frame = NSZeroRect;
   for (NSView* child in [view subviews]) {
     frame = NSUnionRect(frame, [child frame]);
   }
   [view setFrame:frame];
 }
 
@@ skipping 31 matching lines @@
 
 - (void)setRetriableErrorMessage:(const base::string16&)text {
   NSAttributedString* attributedString =
       constrained_window::GetAttributedLabelString(
           SysUTF16ToNSString(text), kErrorFontStyle, NSNaturalTextAlignment,
           NSLineBreakByWordWrapping);
   [errorLabel_ setAttributedStringValue:attributedString];
   [self performLayoutAndDisplay:YES];
 }
 
+- (void)setPermanentErrorMessage:(const base::string16&)text {
+  if (!text.empty()) {
+    if (!permanentErrorBox_) {
+      permanentErrorBox_.reset([[NSBox alloc] initWithFrame:NSZeroRect]);
+      [permanentErrorBox_ setBoxType:NSBoxCustom];
+      [permanentErrorBox_ setBorderType:NSNoBorder];
+      [permanentErrorBox_ setTitlePosition:NSNoTitle];
+      [permanentErrorBox_ setFillColor:gfx::SkColorToCalibratedNSColor(
+                                           kPermanentErrorBackgroundColor)];
+
+      permanentErrorLabel_.reset([constrained_window::CreateLabel() retain]);
+      [permanentErrorLabel_ setAutoresizingMask:NSViewWidthSizable];
+      [permanentErrorLabel_ setTextColor:gfx::SkColorToCalibratedNSColor(
+                                             kPermanentErrorTextColor)];
+
+      [permanentErrorBox_ addSubview:permanentErrorLabel_];
+      [[self view] addSubview:permanentErrorBox_];
+    }
+
+    NSAttributedString* attributedString =
+        constrained_window::GetAttributedLabelString(
+            SysUTF16ToNSString(text), kErrorFontStyle, NSNaturalTextAlignment,
+            NSLineBreakByWordWrapping);
+    [permanentErrorLabel_ setAttributedStringValue:attributedString];
+  }
+
+  [permanentErrorBox_ setHidden:text.empty()];
+  [self setRetriableErrorMessage:base::string16()];
+}
+
 - (void)updateVerifyButtonEnabled {
   autofill::CardUnmaskPromptController* controller = bridge_->GetController();
   DCHECK(controller);
 
   BOOL enable =
       ![inputRowView_ isHidden] &&
       controller->InputCvcIsValid(
           base::SysNSStringToUTF16([cvcInput_ stringValue])) &&
       (!monthPopup_ ||
        [monthPopup_ indexOfSelectedItem] != monthPopupDefaultIndex_) &&
@@ skipping 54 matching lines @@
                      IDS_AUTOFILL_CARD_UNMASK_PROMPT_STORAGE_TOOLTIP))];
   [view addSubview:[storageTooltip_ view]];
   [[storageTooltip_ view] setFrameOrigin:
       NSMakePoint(NSMaxX([storageCheckbox_ frame]) + kButtonGap, 0)];
 
   [CardUnmaskPromptViewCocoa sizeToFitView:view];
   [CardUnmaskPromptViewCocoa verticallyCenterSubviewsInView:view];
   return view;
 }
 
-// TODO(bondd): Add an ASCII diagram of the layout.
+// +------------------------------------------------+
+// | titleLabel_        (Single line.)              |
+// |------------------------------------------------|
+// | permanentErrorBox_ (Multiline, may be hidden.) |
+// |------------------------------------------------|
+// | instructionsLabel_ (Multiline.)                |
+// |------------------------------------------------|
+// | monthPopup_ yearPopup_ cvcInput_ cvcImage      |
+// |     (All enclosed in inputRowView_. Month and  |
+// |         year may be hidden.)                   |
+// |------------------------------------------------|
+// | errorLabel_ (Multiline. Always takes up space  |
+// |                 for one line even if empty.)   |
+// |------------------------------------------------|
+// |                              [Cancel] [Verify] |
+// |------------------------------------------------|
+// | storageCheckbox_ storageTooltip_               |
+// |     (Both enclosed in storageView_.)           |
+// +------------------------------------------------+
 - (void)performLayoutAndDisplay:(BOOL)display {
   // Calculate dialog content width.
   CGFloat contentWidth =
       std::max(NSWidth([titleLabel_ frame]), NSWidth([inputRowView_ frame]));
   contentWidth = std::max(contentWidth, NSWidth([storageView_ frame]));
   contentWidth = std::max(contentWidth, kDialogContentMinWidth);
 
   [storageView_
       setFrameOrigin:NSMakePoint(0, chrome_style::kClientBottomPadding)];
 
   [verifyButton_ setFrameOrigin:
       NSMakePoint(contentWidth - NSWidth([verifyButton_ frame]),
                   NSMaxY([storageView_ frame]) + chrome_style::kRowPadding)];
 
   [cancelButton_
       setFrameOrigin:NSMakePoint(NSMinX([verifyButton_ frame]) - kButtonGap -
                                      NSWidth([cancelButton_ frame]),
                                  NSMinY([verifyButton_ frame]))];
 
-  [errorLabel_ setFrameOrigin:NSMakePoint(0, NSMaxY([cancelButton_ frame]) +
-                                                 chrome_style::kRowPadding)];
-  [CardUnmaskPromptViewCocoa sizeTextField:errorLabel_ toFitWidth:contentWidth];
+  [errorLabel_ setFrame:NSMakeRect(0, NSMaxY([cancelButton_ frame]) +
+                                          chrome_style::kRowPadding,
+                                   contentWidth, 0)];
+  cocoa_l10n_util::WrapOrSizeToFit(errorLabel_);
 
   [inputRowView_ setFrameOrigin:NSMakePoint(0, NSMaxY([errorLabel_ frame]) +
                                                    chrome_style::kRowPadding)];
 
-  [instructionsLabel_
-      setFrameOrigin:NSMakePoint(0, NSMaxY([inputRowView_ frame]) +
-                                        chrome_style::kRowPadding)];
-  [CardUnmaskPromptViewCocoa sizeTextField:instructionsLabel_
-                                toFitWidth:contentWidth];
+  [instructionsLabel_ setFrame:NSMakeRect(0, NSMaxY([inputRowView_ frame]) +
+                                                 chrome_style::kRowPadding,
+                                          contentWidth, 0)];
+  cocoa_l10n_util::WrapOrSizeToFit(instructionsLabel_);
 
-  [titleLabel_
-      setFrameOrigin:NSMakePoint(0, NSMaxY([instructionsLabel_ frame]) +
-                                        chrome_style::kRowPadding)];
+  // Layout permanent error box.
+  CGFloat minY = NSMaxY([instructionsLabel_ frame]) + chrome_style::kRowPadding;
+  if (permanentErrorBox_ && ![permanentErrorBox_ isHidden]) {
+    [permanentErrorBox_ setFrame:NSMakeRect(0, minY, contentWidth, 0)];
+    cocoa_l10n_util::WrapOrSizeToFit(permanentErrorLabel_);
+    [permanentErrorBox_ sizeToFit];
+    minY = NSMaxY([permanentErrorBox_ frame]) + chrome_style::kRowPadding;
+  }
+
+  [titleLabel_ setFrameOrigin:NSMakePoint(0, minY)];
 
   // Center progressOverlayLabel_ vertically within inputRowView_ frame.
   CGFloat progressHeight = ui::ResourceBundle::GetSharedInstance()
                                .GetFont(kProgressFontStyle)
                                .GetHeight();
   [progressOverlayLabel_
       setFrame:NSMakeRect(0, ceil(NSMidY([inputRowView_ frame]) -
                                   progressHeight / 2.0),
                           contentWidth, progressHeight)];
 
@@ skipping 140 matching lines @@
 
   // Layout inputRowView_.
   [CardUnmaskPromptViewCocoa sizeToFitView:inputRowView_];
   [CardUnmaskPromptViewCocoa verticallyCenterSubviewsInView:inputRowView_];
 
   [self setView:mainView];
   [self performLayoutAndDisplay:NO];
 }
 
 @end