[MacViews] Implement size constraints for app windows.

chrome/browser/ui/views/apps/app_window_native_widget_mac.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/browser/ui/views/apps/app_window_native_widget_mac.h"
 
 #import <Cocoa/Cocoa.h>
 
+#include "base/mac/mac_util.h"
+#include "base/mac/sdk_forward_declarations.h"
+#import "chrome/browser/ui/cocoa/apps/nswindow_util.h"
 #import "chrome/browser/ui/views/apps/native_widget_mac_frameless_nswindow.h"
 #import "ui/base/cocoa/window_size_constants.h"
+#include "ui/views/widget/widget_delegate.h"
 
 AppWindowNativeWidgetMac::AppWindowNativeWidgetMac(views::Widget* widget)
     : NativeWidgetMac(widget) {
 }
 
 AppWindowNativeWidgetMac::~AppWindowNativeWidgetMac() {
 }
 
+void AppWindowNativeWidgetMac::OnSizeConstraintsChanged() {
+  NativeWidgetMac::OnSizeConstraintsChanged();
+
+  gfx::Size minimum_size = delegate()->GetMinimumSize();

[tapted, 2015/03/20 12:12:53]

I think to be consistent with aura widgets, this can all move into
BridgedNativeWidget::SizeConstraintsChanged()

(e.g. consider that when Mac goes to Aura,
DesktopNativeWidgetAura::OnSizeConstraintsChanged will call
desktop_window_tree_host_->SizeConstraintsChanged();. On Windows, that then
calls HWNDMessageHandler::SCC, on Mac it will probably call
BridgedNativeWidget::SCC

[jackhou1, 2015/03/25 23:32:23]

Done.

+  gfx::Size maximum_size = delegate()->GetMaximumSize();
+  bool is_resizable = delegate()->AsWidget()->widget_delegate()->CanResize();
+  bool shows_resize_controls =
+      is_resizable && (minimum_size.IsEmpty() || minimum_size != maximum_size);
+  bool shows_fullscreen_controls =
+      is_resizable && delegate()->AsWidget()->widget_delegate()->CanMaximize();
+
+  NSWindow* window = GetNativeWindow();
+  SetResizableStyleMask(window, shows_resize_controls);
+  if (base::mac::IsOSSnowLeopard())
+    [window setShowsResizeIndicator:shows_resize_controls];
+
+  // Set the window to participate in Lion Fullscreen mode. Setting this flag
+  // has no effect on Snow Leopard or earlier. UI controls for fullscreen are
+  // only shown for apps that have unbounded size.
+  if (base::mac::IsOSLionOrLater())
+    SetFullScreenCollectionBehavior(window, shows_fullscreen_controls);
+
+  [[window standardWindowButton:NSWindowZoomButton]
+      setEnabled:shows_fullscreen_controls];

[tapted, 2015/03/20 12:12:53]

I wonder if this is all complicated enough to try to share it with
native_app_window_cocoa...

e.g.

ui/gfx/mac/nswindow_util.h

ApplySizeConstraints(NSWindow*, gfx::Size min_size, gfx::Size max_size,
can_resize, can_fullscreen).

[jackhou1, 2015/03/25 23:32:23]

Done.

+}
+
 NSWindow* AppWindowNativeWidgetMac::CreateNSWindow(
     const views::Widget::InitParams& params) {
   // If the window has a standard frame, use the same NSWindow as
   // NativeWidgetMac.
   if (!params.remove_standard_frame)
     return NativeWidgetMac::CreateNSWindow(params);
 
   // NSTexturedBackgroundWindowMask is needed to implement draggable window
   // regions.
   NSUInteger style_mask = NSTexturedBackgroundWindowMask | NSTitledWindowMask |
                           NSClosableWindowMask | NSMiniaturizableWindowMask |
                           NSResizableWindowMask;
   return [[[NativeWidgetMacFramelessNSWindow alloc]
       initWithContentRect:ui::kWindowSizeDeterminedLater
                 styleMask:style_mask
                   backing:NSBackingStoreBuffered
                     defer:YES] autorelease];
 }