Autofill OSX: Add "Verifying card" / "Your card is verified" status overlay.

chrome/browser/ui/cocoa/autofill/card_unmask_prompt_view_bridge.mm

 // Copyright (c) 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
+#include "base/bind.h"
+#include "base/message_loop/message_loop.h"
 #include "base/strings/sys_string_conversions.h"
 #include "chrome/browser/ui/autofill/autofill_dialog_models.h"
 #include "chrome/browser/ui/autofill/card_unmask_prompt_controller.h"
 #include "chrome/browser/ui/cocoa/autofill/card_unmask_prompt_view_bridge.h"
 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_button.h"
 #include "chrome/browser/ui/chrome_style.h"
 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_control_utils.h"
 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_custom_sheet.h"
 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_custom_window.h"
 #import "chrome/browser/ui/cocoa/key_equivalent_constants.h"
@@ skipping 37 matching lines @@
 
 CardUnmaskPromptViewBridge::~CardUnmaskPromptViewBridge() {
 }
 
 void CardUnmaskPromptViewBridge::ControllerGone() {
   controller_ = nullptr;
   PerformClose();
 }
 
 void CardUnmaskPromptViewBridge::DisableAndWaitForVerification() {
-  [view_controller_ setInputsEnabled:false];
+  [view_controller_ setInputRowHidden:YES];
   [view_controller_ updateVerifyButtonEnabled];
+
+  [view_controller_ setProgressOverlayText:
+                        l10n_util::GetStringUTF16(
+                            IDS_AUTOFILL_CARD_UNMASK_VERIFICATION_IN_PROGRESS)];
+  [view_controller_ setProgressOverlayHidden:NO];
 }
 
 void CardUnmaskPromptViewBridge::GotVerificationResult(
     const base::string16& error_message,
     bool allow_retry) {
-  [view_controller_ setInputsEnabled:true];
-  [view_controller_ updateVerifyButtonEnabled];
+  if (error_message.empty()) {
+    [view_controller_ setProgressOverlayText:
+                          l10n_util::GetStringUTF16(
+                              IDS_AUTOFILL_CARD_UNMASK_VERIFICATION_SUCCESS)];
+
+    base::MessageLoop::current()->PostDelayedTask(
+        FROM_HERE, base::Bind(&CardUnmaskPromptViewBridge::PerformClose,
+                              base::Unretained(this)),
+        base::TimeDelta::FromSeconds(1));

[bondd, 2015/03/18 02:48:37]

This call to PostDelayedTask is copied from the Views implementation.

+  } else {
+    [view_controller_ setInputRowHidden:NO];
+    [view_controller_ setProgressOverlayHidden:YES];
+    [view_controller_ updateVerifyButtonEnabled];
+  }
 }
 
 void CardUnmaskPromptViewBridge::OnConstrainedWindowClosed(
     ConstrainedWindowMac* window) {
   constrained_window_.reset();
   if (controller_)
     controller_->OnUnmaskDialogClosed();
 }
 
 CardUnmaskPromptController* CardUnmaskPromptViewBridge::GetController() {
   return controller_;
 }
 
 void CardUnmaskPromptViewBridge::PerformClose() {
   constrained_window_->CloseWebContentsModalDialog();
 }
 
 }  // autofill
 
 #pragma mark CardUnmaskPromptViewCocoa
 
 @implementation CardUnmaskPromptViewCocoa {
   base::scoped_nsobject<NSTextField> cvcInput_;
   base::scoped_nsobject<NSPopUpButton> monthPopup_;
   base::scoped_nsobject<NSPopUpButton> yearPopup_;
   base::scoped_nsobject<NSButton> verifyButton_;
+  base::scoped_nsobject<NSView> inputRow_;
+  base::scoped_nsobject<NSView> progressOverlay_;

[groby-ooo-7-16, 2015/03/18 07:10:05]

Why a separate view and not just a text field?

[bondd, 2015/03/18 22:01:40]

Done.

+  base::scoped_nsobject<NSTextField> progressOverlayText_;
 
   int monthPopupDefaultIndex_;
   int yearPopupDefaultIndex_;
 
   // Owns |self|.
   autofill::CardUnmaskPromptViewBridge* bridge_;
 }
 
 + (NSPopUpButton*)buildDatePopupWithModel:(ui::ComboboxModel&)model {
   NSPopUpButton* popup =
@@ skipping 27 matching lines @@
 
 - (id)initWithBridge:(autofill::CardUnmaskPromptViewBridge*)bridge {
   DCHECK(bridge);
 
   if ((self = [super initWithNibName:nil bundle:nil]))
     bridge_ = bridge;
 
   return self;
 }
 
-- (void)setInputsEnabled:(BOOL)enabled {
-  [cvcInput_ setEnabled:enabled];
-  [monthPopup_ setEnabled:enabled];
-  [yearPopup_ setEnabled:enabled];
+- (void)setInputRowHidden:(BOOL)hidden {
+  [inputRow_ setHidden:hidden];
+}
+
+- (void)setProgressOverlayHidden:(BOOL)hidden {
+  [progressOverlay_ setHidden:hidden];
+}
+
+- (void)setProgressOverlayText:(const base::string16&)text {
+  NSAttributedString* attributedString =
+      constrained_window::GetAttributedLabelString(
+          SysUTF16ToNSString(text), chrome_style::kTitleFontStyle,
+          NSCenterTextAlignment, NSLineBreakByWordWrapping);
+  [progressOverlayText_ setAttributedStringValue:attributedString];
+
+  [progressOverlayText_ sizeToFit];
+  [progressOverlayText_
+      setFrameSize:NSMakeSize(NSWidth([progressOverlay_ frame]),
+                              NSHeight([progressOverlayText_ frame]))];
+  [CardUnmaskPromptViewCocoa verticallyCenterSubviewsInView:progressOverlay_];
 }
 
 - (void)updateVerifyButtonEnabled {
   autofill::CardUnmaskPromptController* controller = bridge_->GetController();
   DCHECK(controller);
 
   BOOL enable =
-      [cvcInput_ isEnabled] &&
+      ![inputRow_ isHidden] &&
       controller->InputCvcIsValid(
           base::SysNSStringToUTF16([cvcInput_ stringValue])) &&
       (!monthPopup_ ||
        [monthPopup_ indexOfSelectedItem] != monthPopupDefaultIndex_) &&
       (!yearPopup_ ||
        [yearPopup_ indexOfSelectedItem] != yearPopupDefaultIndex_);
 
   [verifyButton_ setEnabled:enable];
 }
 
@@ skipping 13 matching lines @@
 
 - (void)onExpirationDateChanged:(id)sender {
   [self updateVerifyButtonEnabled];
 }
 
 // Called when text in CVC input field changes.
 - (void)controlTextDidChange:(NSNotification*)notification {
   [self updateVerifyButtonEnabled];
 }
 
+- (void)createProgressOverlay {
+  progressOverlay_.reset([[NSView alloc] initWithFrame:NSZeroRect]);
+  progressOverlayText_.reset([constrained_window::CreateLabel() retain]);
+  [progressOverlay_ addSubview:progressOverlayText_];
+  [progressOverlay_ setHidden:YES];
+}
+
 - (void)loadView {
   autofill::CardUnmaskPromptController* controller = bridge_->GetController();
   DCHECK(controller);
 
   base::scoped_nsobject<NSBox> mainView(
       [[NSBox alloc] initWithFrame:NSZeroRect]);
   [mainView setBoxType:NSBoxCustom];
   [mainView setBorderType:NSNoBorder];
   [mainView setTitlePosition:NSNoTitle];
   [mainView
       setContentViewMargins:NSMakeSize(chrome_style::kHorizontalPadding, 0)];
 
-  base::scoped_nsobject<NSView> inputRowView(
-      [[NSView alloc] initWithFrame:NSZeroRect]);
-  [mainView addSubview:inputRowView];
+  inputRow_.reset([[NSView alloc] initWithFrame:NSZeroRect]);
+  [mainView addSubview:inputRow_];
 
   // Title label.
   NSTextField* title = constrained_window::CreateLabel();
   NSAttributedString* titleString =
       constrained_window::GetAttributedLabelString(
           SysUTF16ToNSString(controller->GetWindowTitle()),
           chrome_style::kTitleFontStyle, NSNaturalTextAlignment,
           NSLineBreakByWordWrapping);
   [title setAttributedStringValue:titleString];
   [title sizeToFit];
@@ skipping 33 matching lines @@
     [expirationView addSubview:yearPopup_];
 
     // Layout month and year within expirationView.
     [yearPopup_
         setFrameOrigin:NSMakePoint(NSMaxX([monthPopup_ frame]) + kButtonGap,
                                    0)];
     NSRect expirationFrame =
         NSUnionRect([monthPopup_ frame], [yearPopup_ frame]);
     expirationFrame.size.width += kButtonGap;
     [expirationView setFrame:expirationFrame];
-    [inputRowView addSubview:expirationView];
+    [inputRow_ addSubview:expirationView];
   }
 
   // CVC text input.
   cvcInput_.reset([[NSTextField alloc] initWithFrame:NSZeroRect]);
   [[cvcInput_ cell]
       setPlaceholderString:l10n_util::GetNSString(
                                IDS_AUTOFILL_DIALOG_PLACEHOLDER_CVC)];
   [[cvcInput_ cell] setScrollable:YES];
   [cvcInput_ setDelegate:self];
   [cvcInput_ sizeToFit];
   [cvcInput_ setFrame:NSMakeRect(NSMaxX([expirationView frame]), 0,
                                  kCvcInputWidth, NSHeight([cvcInput_ frame]))];
-  [inputRowView addSubview:cvcInput_];
+  [inputRow_ addSubview:cvcInput_];
 
   // CVC image.
   ui::ResourceBundle& rb = ui::ResourceBundle::GetSharedInstance();
   NSImage* cvcImage =
       rb.GetNativeImageNamed(controller->GetCvcImageRid()).ToNSImage();
   base::scoped_nsobject<NSImageView> cvcImageView(
       [[NSImageView alloc] initWithFrame:NSZeroRect]);
   [cvcImageView setImage:cvcImage];
   [cvcImageView setFrameSize:[cvcImage size]];
   [cvcImageView
       setFrameOrigin:NSMakePoint(NSMaxX([cvcInput_ frame]) + kButtonGap, 0)];
-  [inputRowView addSubview:cvcImageView];
+  [inputRow_ addSubview:cvcImageView];
 
   // Cancel button.
   base::scoped_nsobject<NSButton> cancelButton(
       [[ConstrainedWindowButton alloc] initWithFrame:NSZeroRect]);
   [cancelButton setTitle:l10n_util::GetNSStringWithFixup(IDS_CANCEL)];
   [cancelButton setKeyEquivalent:kKeyEquivalentEscape];
   [cancelButton setTarget:self];
   [cancelButton setAction:@selector(onCancel:)];
   [cancelButton sizeToFit];
   [mainView addSubview:cancelButton];
 
   // Verify button.
   verifyButton_.reset(
       [[ConstrainedWindowButton alloc] initWithFrame:NSZeroRect]);
   // TODO(bondd): use l10n string.
   [verifyButton_ setTitle:@"Verify"];
   [verifyButton_ setKeyEquivalent:kKeyEquivalentReturn];
   [verifyButton_ setTarget:self];
   [verifyButton_ setAction:@selector(onVerify:)];
   [verifyButton_ sizeToFit];
   [self updateVerifyButtonEnabled];
   [mainView addSubview:verifyButton_];
 
-  // Layout inputRowView.
-  [CardUnmaskPromptViewCocoa sizeToFitView:inputRowView];
-  [CardUnmaskPromptViewCocoa verticallyCenterSubviewsInView:inputRowView];
+  // Layout inputRow_.
+  [CardUnmaskPromptViewCocoa sizeToFitView:inputRow_];
+  [CardUnmaskPromptViewCocoa verticallyCenterSubviewsInView:inputRow_];
 
   // Calculate dialog content width.
   CGFloat contentWidth =
-      std::max(NSWidth([title frame]), NSWidth([inputRowView frame]));
+      std::max(NSWidth([title frame]), NSWidth([inputRow_ frame]));
   contentWidth = std::max(contentWidth, kDialogContentMinWidth);
 
   // Layout mainView contents, starting at the bottom and moving up.
 
   // Verify and Cancel buttons.
   [verifyButton_
       setFrameOrigin:NSMakePoint(contentWidth - NSWidth([verifyButton_ frame]),
                                  chrome_style::kClientBottomPadding)];
 
   [cancelButton
       setFrameOrigin:NSMakePoint(NSMinX([verifyButton_ frame]) - kButtonGap -
                                      NSWidth([cancelButton frame]),
                                  NSMinY([verifyButton_ frame]))];
 
   // Input row.
-  [inputRowView setFrameOrigin:NSMakePoint(0, NSMaxY([cancelButton frame]) +
-                                                  chrome_style::kRowPadding)];
+  [inputRow_ setFrameOrigin:NSMakePoint(0, NSMaxY([cancelButton frame]) +
+                                               chrome_style::kRowPadding)];
 
   // Instruction label.
-  [instructions setFrameOrigin:NSMakePoint(0, NSMaxY([inputRowView frame]) +
+  [instructions setFrameOrigin:NSMakePoint(0, NSMaxY([inputRow_ frame]) +
                                                   chrome_style::kRowPadding)];
   NSSize instructionsSize = [[instructions cell]
       cellSizeForBounds:NSMakeRect(0, 0, contentWidth, CGFLOAT_MAX)];
   [instructions setFrameSize:instructionsSize];
 
   // Title label.
   [title setFrameOrigin:NSMakePoint(0, NSMaxY([instructions frame]) +
                                            chrome_style::kRowPadding)];
 
   // Dialog size.
   [mainView
       setFrameSize:NSMakeSize(
                        contentWidth + [mainView contentViewMargins].width * 2.0,
                        NSMaxY([title frame]) + chrome_style::kTitleTopPadding)];
 
+  // Add progress overlay.
+  [self createProgressOverlay];

[groby-ooo-7-16, 2015/03/18 07:10:05]

In case it becomes a single view, doing this inline might be a good idea.

[bondd, 2015/03/18 22:01:40]

Done. I also did an alternate implementation where progressOverlayText_ init is
done in setProgressOverlayText once there is a text string to set. Avoids
getting font height from NSLayoutManager, but the calculations for the
progressOverlayText_ frame dimensions are a bit more complicated, and get done
every time the text is changed. I don't think either way has a clear advantage.

+  [progressOverlay_
+      setFrame:NSMakeRect(0, NSMinY([inputRow_ frame]), contentWidth,
+                          NSHeight([inputRow_ frame]))];
+  [mainView addSubview:progressOverlay_];
+
   [self setView:mainView];
 }
 
 @end