Gets packaging of html_viewer for android working

mojo/services/html_viewer/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//testing/test.gni")
 import("//third_party/mojo/src/mojo/public/mojo.gni")
 import("//third_party/mojo/src/mojo/public/mojo_application.gni")
 
 action("generate_blink_resource_map") {
   script = "//mojo/services/html_viewer/generate_blink_resource_map.py"
@@ skipping 92 matching lines @@
   ]
 
   public_deps = [
     "//third_party/WebKit/public:blink",
     "//third_party/mojo/src/mojo/public/cpp/bindings",
     "//third_party/mojo_services/src/view_manager/public/cpp",
     ":generate_blink_resource_map",
   ]
 }
 
-mojo_native_application("html_viewer") {
-  sources = [
-    "html_viewer.cc",
-  ]
-  deps = [
-    ":lib",
-  ]
+if (is_android) {
+  import("//build/config/android/rules.gni")
+
+  java_library_path = "$target_out_dir/java_library.dex.jar"
+
+  mojo_android_application("html_viewer") {
+    input_so = "$root_out_dir/lib.stripped/libhtml_viewer_lib.so"
+    input_dex_jar = java_library_path
+  }
+
+  shared_library("html_viewer_lib") {
+    sources = [
+      "android/android_hooks.cc",
+      "html_viewer.cc",
+    ]
+
+    deps = [
+      ":html_viewer_jni_headers",
+      ":lib",
+      "//base",
+      "//ui/gfx:gfx_jni_headers",
+    ]
+  }
+
+  generate_jni("html_viewer_jni_headers") {
+    sources = [
+      "android/java/org/chromium/html_viewer/Main.java",
+    ]
+    jni_package = "mojo/services/html_viewer"
+  }
+
+  android_library("html_viewer_java_classes") {
+    java_files = [ "android/java/org/chromium/html_viewer/Main.java" ]
+
+    deps = [
+      "//base:base_java",
+    ]
+  }
+
+  android_standalone_library("java_library") {
+    dex_path = java_library_path
+
+    deps = [
+      ":html_viewer_java_classes",
+
+      # TODO(sky): this is WAY more than we need. We really only need
+      # DeviceDisplayInfo. Refactor to make this clearer.
+      "//ui/android:ui_java",
+    ]
+  }
+} else {
+  mojo_native_application("html_viewer") {
+    sources = [
+      "html_viewer.cc",
+    ]
+    deps = [
+      ":lib",
+    ]
+  }
 }
 
 test("tests") {
   output_name = "html_viewer_unittests"
   sources = [
     "ax_provider_impl_unittest.cc",
   ]
   deps = [
     ":lib",
     "//base/test:run_all_unittests",
   ]
 }