Adding untrusted crash dump / stack trace tests.

tests/inbrowser_untrusted_crash_dump_test/nacl.scons

Index: tests/inbrowser_untrusted_crash_dump_test/nacl.scons
diff --git a/tests/inbrowser_untrusted_crash_dump_test/nacl.scons b/tests/inbrowser_untrusted_crash_dump_test/nacl.scons
new file mode 100644
index 0000000000000000000000000000000000000000..4ddc7bba6861385673c7653c85298f2af16a403d
--- /dev/null
+++ b/tests/inbrowser_untrusted_crash_dump_test/nacl.scons
@@ -0,0 +1,66 @@
+# -*- python -*-
+# Copyright (c) 2012 The Native Client Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+Import('env')
+
+# Exception handling support is not implemented everywhere yet.
+is_broken = (not (env.Bit('host_windows') or env.Bit('host_mac')) or
+             not env.Bit('build_x86_32'))
+
+# Don't build on anything other than x86-32 for now.
+if not env.Bit('build_x86_32'):
+  Return()
+
+env.Append(CCFLAGS=['-O0', '-fno-omit-frame-pointer', '-g'])
+env.Append(CPPDEFINES=['IN_BROWER=1'])
+
+untrusted_crash_dump_lib = env.ComponentLibrary(
+    'inbrowser_untrusted_crash_dump_lib',
+    '${MAIN_DIR}/tests/untrusted_crash_dump/untrusted_crash_dump_lib.c',
+    EXTRA_LIBS=['srpc', 'platform', 'gio', 'imc', 'imc_syscalls',
+                '${PTHREAD_LIBS}', '${NON_PPAPI_BROWSER_LIBS}'],
+    COMPONENT_STATIC=not env.Bit('nacl_glibc'))
+
+untrusted_crash_dump_test = env.ComponentProgram(
+    'inbrowser_untrusted_crash_dump_test',
+    [env.ComponentObject(
+         'untrusted_crash_dump',
+         '${MAIN_DIR}/tests/untrusted_crash_dump/untrusted_crash_dump.c'),
+     env.ComponentObject(
+         'untrusted_crash_dump_test',
+         '${MAIN_DIR}/tests/untrusted_crash_dump/untrusted_crash_dump_test.c')],
+    EXTRA_LIBS=['untrusted_crash_dump_lib',
+                'srpc', 'platform', 'gio', 'imc', 'imc_syscalls',
+                '${PTHREAD_LIBS}', '${NON_PPAPI_BROWSER_LIBS}'])
+
+# Make sure .so is in place for decoding.
+if env.Bit('nacl_glibc'):
+  env.Depends(untrusted_crash_dump_test,
+              '$STAGING_DIR/libuntrusted_crash_dump_lib.so')
+
+if env.Bit('nacl_glibc'):
+  golden = 'untrusted_crash_dump_test_glibc.golden'
+else:
+  golden = 'untrusted_crash_dump_test_newlib.golden'
+golden = '$MAIN_DIR/tests/untrusted_crash_dump/' + golden
+
+env['ENV']['NACL_UNTRUSTED_EXCEPTION_HANDLING'] = '1'
+node = env.PPAPIBrowserTester(
+    'inbrowser_untrusted_crash_dump_test.out',
+    url='untrusted_crash_dump.html',
+    nmfs=['inbrowser_untrusted_crash_dump_test.nmf'],
+    nacl_exe_stdout={
+        'file': ('${TARGET_ROOT}/test_results/'
+                 'inbrowser_untrusted_crash_dump_test.stdout'),
+        'golden': golden,
+        'decode_crash_dump': True,
+    },
+    files=[untrusted_crash_dump_test,
+           env.File('untrusted_crash_dump.html')])
+env.AddNodeToTestSuite(
+    node, ['chrome_browser_tests', 'exception_tests'],
+       'run_inbrowser_untrusted_crash_dump_test',
+       is_broken=env.PPAPIBrowserTesterIsBroken() or
+                 env.Bit('running_on_valgrind') or is_broken)