Revert 112305 - Pull the phone library directly. Delete old version.

third_party/libphonenumber/cpp/CMakeLists.txt

Index: third_party/libphonenumber/cpp/CMakeLists.txt
diff --git a/third_party/libphonenumber/cpp/CMakeLists.txt b/third_party/libphonenumber/cpp/CMakeLists.txt
new file mode 100644
index 0000000000000000000000000000000000000000..888c7c5dddaa6c04da82bbdfb9c2dead3e8c0302
--- /dev/null
+++ b/third_party/libphonenumber/cpp/CMakeLists.txt
@@ -0,0 +1,329 @@
+# Copyright (C) 2011 Google Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+# Author: Philippe Liard
+
+cmake_minimum_required (VERSION 2.8)
+
+project (libphonenumber)
+
+# Helper functions dealing with finding libraries and programs this library
+# depends on.
+
+function (print_error DESCRIPTION FILE)
+  message (FATAL_ERROR
+    "Can't find ${DESCRIPTION}: can't locate ${FILE}. Please read the README.")
+endfunction ()
+
+# Find a library. If it has not been found, stop CMake with a fatal error
+# message.
+function (find_required_library NAME HEADER LIBRARY DESCRIPTION)
+  # Check the header.
+  find_path (${NAME}_INCLUDE_DIR ${HEADER})
+  set (INCLUDE_DIR ${${NAME}_INCLUDE_DIR})
+
+  if (${INCLUDE_DIR} STREQUAL "${INCLUDE_DIR}-NOTFOUND")
+    print_error (${DESCRIPTION} ${HEADER})
+  endif ()
+  include_directories (${INCLUDE_DIR})
+  # Check the binary.
+  find_library (${NAME}_LIB ${LIBRARY})
+  set (LIB ${NAME}_LIB)
+
+  if (${LIB} STREQUAL "${LIB}-NOTFOUND")
+    print_error (${DESCRIPTION} ${LIBRARY})
+  endif ()
+endfunction (find_required_library)
+
+# Check the library version (if pkg-config available).
+find_package (PkgConfig)
+function (check_library_version VARNAME LIBRARY_WITH_VERSION)
+  if (PKG_CONFIG_FOUND)
+    pkg_check_modules (${VARNAME} REQUIRED ${LIBRARY_WITH_VERSION})
+  endif ()
+endfunction ()
+
+# Find a program. If it has not been found, stop CMake with a fatal error
+# message.
+function (find_required_program NAME FILENAME DESCRIPTION)
+  find_program (${NAME}_BIN NAMES ${FILENAME})
+
+  if (${NAME}_BIN STREQUAL "${${NAME}_BIN}-NOTFOUND")
+    print_error (${DESCRIPTION} ${FILENAME})
+  endif ()
+endfunction (find_required_program)
+
+# Options that can be passed to CMake using 'cmake -DKEY=VALUE'.
+option ("USE_LITE_METADATA" "Use lite metadata" "OFF")
+option ("USE_RE2" "Use RE2 instead of ICU" "OFF")
+
+# Find all the required libraries and programs.
+find_package (Boost 1.40.0 COMPONENTS thread)
+if (NOT Boost_FOUND)
+  print_error ("Boost Thread" "Boost")
+endif ()
+include_directories (${Boost_INCLUDE_DIRS})
+
+find_required_library (GTEST gtest/gtest.h gtest "Google Test framework")
+
+if (${USE_RE2} STREQUAL "ON")
+  find_required_library (RE2 re2/re2.h re2 "Google RE2")
+endif ()
+
+find_required_library (PROTOBUF google/protobuf/message_lite.h protobuf
+                       "Google Protocol Buffers")
+check_library_version (PC_PROTOBUF protobuf>=2.4)
+
+find_required_library (ICU_UC unicode/uchar.h icuuc "ICU")
+check_library_version (PC_ICU_UC icu-uc>=4.4)
+
+set (ICU_INCLUDE_DIR ${ICU_UC_INCLUDE_DIR})
+set (ICU_LIB ${ICU_UC_LIB})
+# If ICU regexp engine is used, use icui18n as well.
+if (${USE_RE2} STREQUAL "OFF")
+  find_required_library (ICU_I18N unicode/regex.h icui18n "ICU")
+  check_library_version (PC_ICU_I18N icu-i18n>=4.4)
+  list (APPEND ICU_INCLUDE_DIR ${ICU_I18N_INCLUDE_DIR})
+  list (APPEND ICU_LIB ${ICU_I18N_LIB})
+endif ()
+
+find_required_program (PROTOC protoc
+                       "Google Protocol Buffers compiler (protoc)")
+
+find_required_program (JAVA java
+                       "Java Runtime Environment")
+
+if (APPLE)
+  FIND_LIBRARY (COREFOUNDATION_LIB CoreFoundation)
+  FIND_LIBRARY (FOUNDATION_LIB Foundation)
+endif ()
+
+INCLUDE (CheckIncludeFileCXX)
+CHECK_INCLUDE_FILE_CXX ("tr1/unordered_map" HAVE_CXX_TR1_UNORDERED_MAP)
+
+if (HAVE_CXX_TR1_UNORDERED_MAP)
+  add_definitions ("-DUSE_TR1_UNORDERED_MAP")
+else ()
+  CHECK_INCLUDE_FILE_CXX (hash_map HAVE_CXX_HASH_MAP)
+  if (HAVE_CXX_HASH_MAP)
+    add_definitions ("-DUSE_HASH_MAP")
+  else ()
+    print_error ("C++ map class" "tr1/unordered_map or hash_map")
+  endif ()
+endif ()
+
+# Add protoc (Protocol Buffers compiler) target.
+set (RESOURCES_DIR "${CMAKE_SOURCE_DIR}/../resources")
+
+set (
+  PROTOBUF_SOURCES "${RESOURCES_DIR}/phonemetadata.proto"
+                   "${RESOURCES_DIR}/phonenumber.proto"
+)
+
+set (
+  PROTOBUF_OUTPUT "${CMAKE_SOURCE_DIR}/src/phonemetadata.pb.cc"
+                  "${CMAKE_SOURCE_DIR}/src/phonemetadata.pb.h"
+                  "${CMAKE_SOURCE_DIR}/src/phonenumber.pb.cc"
+                  "${CMAKE_SOURCE_DIR}/src/phonenumber.pb.h"
+)
+
+add_custom_command (
+  COMMAND ${PROTOC_BIN} --cpp_out=${CMAKE_SOURCE_DIR}/src
+    --proto_path=${RESOURCES_DIR} ${PROTOBUF_SOURCES}
+
+  OUTPUT ${PROTOBUF_OUTPUT}
+  DEPENDS ${PROTOBUF_SOURCES}
+)
+
+add_custom_target (
+  generate-sources
+
+  DEPENDS ${PROTOBUF_OUTPUT}
+  COMMENT "Generating Protocol Buffers code"
+)
+
+set (
+  SOURCES
+  "src/base/string_piece.cc"
+  "src/default_logger.cc"
+  "src/logger.cc"
+  "src/metadata.h"          # Generated by build tools.
+  "src/phonemetadata.pb.cc" # Generated by Protocol Buffers.
+  "src/phonenumber.cc"
+  "src/phonenumber.pb.cc"   # Generated by Protocol Buffers.
+  "src/phonenumberutil.cc"
+  "src/regexp_cache.cc"
+  "src/stringutil.cc"
+  "src/utf/rune.c"
+  "src/utf/unicodetext.cc"
+  "src/utf/unilib.cc"
+)
+
+# Add regexp engine sources. ICU is used by default.
+if (${USE_RE2} STREQUAL "ON")
+  list (APPEND SOURCES "src/regexp_adapter_re2.cc")
+else ()
+  list (APPEND SOURCES "src/regexp_adapter_icu.cc")
+endif ()
+
+# Library sources excluding the metadata files, since special metadata is used
+# for unit-testing.
+set (TESTING_LIBRARY_SOURCES ${SOURCES})
+
+# Add metadata code generation targets.
+
+# This function is invoked to create metadata, test metadata and lite metadata
+# code generation targets.
+function (add_metadata_gen_target TARGET_NAME
+                                  XML_FILE
+                                  METADATA_TYPE)
+  set (METADATA_SOURCE_DIR "${CMAKE_SOURCE_DIR}/src")
+  set (GEN_OUTPUT "${METADATA_SOURCE_DIR}/${METADATA_TYPE}.cc"
+                  "${METADATA_SOURCE_DIR}/metadata.h")
+  set (JAR_PATH "${CMAKE_SOURCE_DIR}/../tools/java/cpp-build/target")
+  set (JAR_PATH "${JAR_PATH}/cpp-build-1.0-SNAPSHOT-jar-with-dependencies.jar")
+
+  add_custom_command (
+    COMMAND ${JAVA_BIN} -jar
+      ${JAR_PATH} BuildMetadataCppFromXml ${XML_FILE} ${CMAKE_SOURCE_DIR}/src
+      ${METADATA_TYPE}
+
+    OUTPUT ${GEN_OUTPUT}
+    DEPENDS ${XML_FILE}
+  )
+  add_custom_target (
+    ${TARGET_NAME}
+    DEPENDS ${GEN_OUTPUT}
+    COMMENT "Generating Metadata code"
+  )
+endfunction (add_metadata_gen_target)
+
+if (${USE_LITE_METADATA} STREQUAL "ON")
+  # Add the lite metadata generation target.
+  set (METADATA_TARGET "generate-lite-metadata")
+  add_metadata_gen_target (
+    ${METADATA_TARGET}
+    "${RESOURCES_DIR}/PhoneNumberMetaData.xml"
+    "lite_metadata"
+  )
+  list (APPEND SOURCES "src/lite_metadata.cc")
+else ()
+  # Add the metadata generation target.
+  set (METADATA_TARGET "generate-metadata")
+  add_metadata_gen_target (
+    ${METADATA_TARGET}
+    "${RESOURCES_DIR}/PhoneNumberMetaData.xml"
+    "metadata"
+  )
+  list (APPEND SOURCES "src/metadata.cc")
+endif ()
+
+# Add the test metadata generation target.
+set (TEST_METADATA_TARGET "generate-test-metadata")
+add_metadata_gen_target (
+  ${TEST_METADATA_TARGET}
+  "${RESOURCES_DIR}/PhoneNumberMetaDataForTesting.xml"
+  "test_metadata"
+)
+list (APPEND TESTING_LIBRARY_SOURCES "src/test_metadata.cc")
+add_definitions ("-Wall -Werror")
+
+include_directories ("src")
+
+# Build a static library (without -fPIC).
+add_library (phonenumber STATIC ${SOURCES})
+add_dependencies (phonenumber generate-sources ${METADATA_TARGET})
+
+# Build a shared library (with -fPIC).
+set (BUILD_SHARED_LIB true)
+
+if (${USE_RE2} STREQUAL "ON")
+  # RE2 is not always available as a shared library (e.g: package provided by
+  # Ubuntu) therefore disable the shared library build in this case.
+  if (${RE2_LIB} MATCHES ".*\\.a")
+    message (WARNING
+      "RE2 not available as a shared library, shared library build disabled")
+    set (BUILD_SHARED_LIB false)
+  endif ()
+endif ()
+
+if (BUILD_SHARED_LIB)
+  add_library (phonenumber-shared SHARED ${SOURCES})
+  add_dependencies (phonenumber-shared generate-sources ${METADATA_TARGET})
+  set_target_properties (phonenumber-shared
+                         PROPERTIES OUTPUT_NAME "phonenumber")
+  set_target_properties (phonenumber-shared PROPERTIES PREFIX "lib")
+endif ()
+
+set (LIBRARY_DEPS ${PROTOBUF_LIB} ${ICU_LIB} ${Boost_LIBRARIES})
+
+if (${USE_RE2} STREQUAL "ON")
+  list (APPEND LIBRARY_DEPS ${RE2_LIB})
+endif ()
+
+if (APPLE)
+  list (APPEND LIBRARY_DEPS ${COREFOUNDATION_LIB} ${FOUNDATION_LIB})
+endif ()
+
+target_link_libraries (phonenumber ${LIBRARY_DEPS})
+
+if (BUILD_SHARED_LIB)
+  target_link_libraries (phonenumber-shared ${LIBRARY_DEPS})
+endif ()
+
+# Build a specific library for testing purposes.
+add_library (phonenumber_testing STATIC ${TESTING_LIBRARY_SOURCES})
+target_link_libraries (phonenumber_testing ${LIBRARY_DEPS})
+add_dependencies (phonenumber_testing generate-sources ${TEST_METADATA_TARGET})
+
+set (TEST_SOURCES
+  "src/logger_test.cc"
+  "src/phonenumberutil_test.cc"
+  "src/regexp_adapter_test.cc"
+  "src/regexp_cache_test.cc"
+  "src/run_tests.cc"
+  "src/stringutil_test.cc"
+  "src/utf/unicodetext_test.cc"
+)
+
+# Build the testing binary.
+add_executable (libphonenumber_test ${TEST_SOURCES})
+target_link_libraries (
+  libphonenumber_test
+  phonenumber_testing ${GTEST_LIB} pthread
+)
+
+# Install rules.
+install (FILES
+  "src/logger.h"
+  "src/phonenumber.pb.h"
+  "src/phonenumberutil.h"
+  DESTINATION include/phonenumbers/
+)
+
+install (FILES
+  "src/base/basictypes.h"
+  "src/base/memory/scoped_ptr.h"
+  "src/base/singleton.h"
+  DESTINATION include/phonenumbers/base/
+)
+install (FILES src/base/synchronization/lock.h
+         DESTINATION include/phonenumbers/base/synchronization)
+
+install (TARGETS phonenumber LIBRARY DESTINATION lib/ ARCHIVE DESTINATION lib/)
+
+if (BUILD_SHARED_LIB)
+  install (TARGETS phonenumber-shared LIBRARY DESTINATION lib/ ARCHIVE
+           DESTINATION lib/)
+endif ()