nacl_helper_bootstrap: Reserve correct address space size for ARM, none for x86-64

chrome/nacl/nacl_helper_bootstrap_linux.x

 /* Copyright (c) 2011 The Chromium Authors. All rights reserved.
  * Use of this source code is governed by a BSD-style license that can be
  * found in the LICENSE file.
  *
  * This is a custom linker script used to build nacl_helper_bootstrap.
  * It has a very special layout.  This script will only work with input
  * that is kept extremely minimal.  If there are unexpected input sections
  * not named here, the result will not be correct.
  *
  * We need to use a standalone loader program rather than just using a
@@ skipping 15 matching lines @@
 ENTRY(_start)
 
 /*
  * This is the address where the program text starts.
  * We set this as low as we think we can get away with.
  * The common settings for sysctl vm.mmap_min_addr range from 4k to 64k.
  */
 TEXT_START = 0x10000;
 
 /*
- * This is the top of the range we are trying to reserve, which is 1G
- * for x86-32 and ARM.  For an x86-64 zero-based sandbox, this really
- * needs to be 36G.
+ * The symbol RESERVE_TOP is the top of the range we are trying to reserve.
+ * This is set via --defsym on the linker command line, because the correct
+ * value differs for each machine.  It's not defined at all if we do not
+ * actually need any space reserved for this configuration.
  */
-RESERVE_TOP = 1 << 30;
 
 /*
  * We specify the program headers we want explicitly, to get the layout
  * exactly right and to give the "reserve" segment p_flags of zero, so
  * that it gets mapped as PROT_NONE.
  */
 PHDRS {
   text PT_LOAD FILEHDR PHDRS;
   data PT_LOAD;
   reserve PT_LOAD FLAGS(0);
@@ skipping 51 matching lines @@
    * p_memsz we want, which reserves the address space.  But the linker
    * gives it a p_filesz of zero.  We have to edit the phdr after link
    * time to give it a p_filesz matching its p_memsz.  That way, the
    * kernel doesn't think we are preallocating a huge amount of memory.
    * It just maps it from the file, i.e. way off the end of the file,
    * which is perfect for reserving the address space.
    */
   . = ALIGN(CONSTANT(COMMONPAGESIZE));
   RESERVE_START = .;
   .reserve : {
-    . = RESERVE_TOP - RESERVE_START;
+    . += DEFINED(RESERVE_TOP) ? (RESERVE_TOP - RESERVE_START) : 0;
   } :reserve
 
   /*
    * This must be placed above the reserved address space, so it won't
    * be clobbered by NaCl.  We want this to be visible at its fixed address
    * in the memory image so the debugger can make sense of things.
    */
   .r_debug : {
     *(.r_debug)
   } :r_debug
 
   /*
    * These are empty input sections the linker generates.
    * If we don't discard them, they pollute the flags in the output segment.
    */
   /DISCARD/ : {
     *(.iplt)
     *(.rel*)
     *(.igot.plt)
   }
 }