content: Remove 16 exit time destructors and 15 static initializers.

content/browser/accessibility/browser_accessibility_cocoa.mm

 // Copyright (c) 2011 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include <execinfo.h>
 
 #import "content/browser/accessibility/browser_accessibility_cocoa.h"
 
 #include <map>
 
@@ skipping 30 matching lines @@
 struct MapEntry {
   WebAccessibility::Role webKitValue;
   NSString* nativeValue;
 };
 
 struct AttributeToMethodNameEntry {
   NSString* attribute;
   NSString* methodName;
 };
 
 static const MapEntry roles[] = {

[Mark Mentovai, 2011/11/07 22:34:15]

While poking through here, I noticed…

This is both static and in an anonymous namespace. Remove the |static|.

   { WebAccessibility::ROLE_ALERT, NSAccessibilityGroupRole },
   { WebAccessibility::ROLE_ALERT_DIALOG, NSAccessibilityGroupRole },
   { WebAccessibility::ROLE_ANNOTATION, NSAccessibilityUnknownRole },
   { WebAccessibility::ROLE_APPLICATION, NSAccessibilityGroupRole },
   { WebAccessibility::ROLE_ARTICLE, NSAccessibilityGroupRole },
   { WebAccessibility::ROLE_BROWSER, NSAccessibilityBrowserRole },
   { WebAccessibility::ROLE_BUSY_INDICATOR, NSAccessibilityBusyIndicatorRole },
   { WebAccessibility::ROLE_BUTTON, NSAccessibilityButtonRole },
   { WebAccessibility::ROLE_CELL, @"AXCell" },
   { WebAccessibility::ROLE_CHECKBOX, NSAccessibilityCheckBoxRole },
@@ skipping 149 matching lines @@
   { @"AXVisited", @"visited" },
 };
 
 // GetState checks the bitmask used in webaccessibility.h to check
 // if the given state was set on the accessibility object.
 bool GetState(BrowserAccessibility* accessibility, int state) {
   return ((accessibility->state() >> state) & 1);
 }
 
 // A mapping of webkit roles to native roles.
-std::map<WebAccessibility::Role, NSString*> webAccessibilityToNativeRole;
+NSString* NativeRoleFromWebAccessibilityRole(
+    const WebAccessibility::Role& role) {
+  CR_DEFINE_STATIC_LOCAL(std::map<WebAccessibility::Role, NSString*>,
+                         webAccessibilityToNativeRole, ());

[Mark Mentovai, 2011/11/07 22:34:15]

This would properly be named web_accessibility_to_native_role, because you’re in
a mixed Objective-C++ files and you’re outside of an @interface,
@implementation, @protocol, etc. See
http://google-styleguide.googlecode.com/svn/trunk/objcguide.xml?showone=Objec...
.

[Nico, 2011/11/07 23:29:21]

Done.

+  if (webAccessibilityToNativeRole.empty()) {

[Mark Mentovai, 2011/11/07 22:34:15]

I don’t like this pattern, because it treats “empty” as the
“initialized” sentinel, but the compiler already provides a sentinel for static
initialization. It’s less fragile to track something in one location and for the
meaning to be correct. Even though we have thread-safe statics off and I’m
assuming we don’t need thread safety here, “!empty” may not always equal
“initialized.”

I prefer something like this, and the compiled machine code will likely even be
a tiny bit more optimal:

std::map<WebAccessibility::Role, NSString*>* WebAccessibilityToNativeRoleMap() {
  std::map<WebAccessibility::Role, NSString*>* map = new std::map…;
  // Now you can even move the data in-line into this function.
  // initialize and return map;
}

NSString* NativeRoleFromWebAccessibilityRole(
    const WebAccessibility::Role& role) {
  static std::map<WebAccessibility::Role, NSString*>* map =
      WebAccessibilityToNativeRoleMap();
  // map().find, etc.
}

[Nico, 2011/11/07 23:29:21]

Done-ish

+    for (size_t i = 0; i < arraysize(roles); ++i) {
+      webAccessibilityToNativeRole[roles[i].webKitValue] = roles[i].nativeValue;
+    }
+  }
+
+  std::map<WebAccessibility::Role, NSString*>::iterator it =
+      webAccessibilityToNativeRole.find(role);
+  if (it != webAccessibilityToNativeRole.end())
+    return it->second;
+  else
+    return NSAccessibilityUnknownRole;
+}
+
 // A mapping of webkit roles to native subroles.
-std::map<WebAccessibility::Role, NSString*> webAccessibilityToNativeSubrole;
+NSString* NativeSubroleFromWebAccessibilityRole(
+    const WebAccessibility::Role& role) {
+  CR_DEFINE_STATIC_LOCAL(std::map<WebAccessibility::Role, NSString*>,
+                         webAccessibilityToNativeSubrole, ());

[Mark Mentovai, 2011/11/07 22:34:15]

Same.

[Nico, 2011/11/07 23:29:21]

Done.

+  if (webAccessibilityToNativeSubrole.empty()) {

[Mark Mentovai, 2011/11/07 22:34:15]

And same.

[Nico, 2011/11/07 23:29:21]

Done.

+    for (size_t i = 0; i < arraysize(subroles); ++i) {
+      webAccessibilityToNativeSubrole[subroles[i].webKitValue] =
+          subroles[i].nativeValue;
+    }
+  }
+
+  std::map<WebAccessibility::Role, NSString*>::iterator it =
+      webAccessibilityToNativeSubrole.find(role);
+  if (it != webAccessibilityToNativeSubrole.end())
+    return it->second;
+  else
+    return nil;
+}
+
 // A mapping from an accessibility attribute to its method name.
 NSDictionary* attributeToMethodNameMap = nil;
 
 } // namespace
 
 @implementation BrowserAccessibilityCocoa
 
 + (void)initialize {
-  const size_t numRoles = sizeof(roles) / sizeof(roles[0]);
-  for (size_t i = 0; i < numRoles; ++i) {
-    webAccessibilityToNativeRole[roles[i].webKitValue] = roles[i].nativeValue;
-  }
-
-  const size_t numSubroles = sizeof(subroles) / sizeof(subroles[0]);
-  for (size_t i = 0; i < numSubroles; ++i) {
-    webAccessibilityToNativeSubrole[subroles[i].webKitValue] =
-        subroles[i].nativeValue;
-  }
-
   NSMutableDictionary* dict = [[NSMutableDictionary alloc] init];
   const size_t numAttributes = sizeof(attributeToMethodNameContainer) /
                                sizeof(attributeToMethodNameContainer[0]);
   for (size_t i = 0; i < numAttributes; ++i) {
     [dict setObject:attributeToMethodNameContainer[i].methodName
              forKey:attributeToMethodNameContainer[i].attribute];
   }
   attributeToMethodNameMap = dict;
   dict = nil;
 }
@@ skipping 190 matching lines @@
   return [NSNumber numberWithBool:
       GetState(browserAccessibility_, WebAccessibility::STATE_REQUIRED)];
 }
 
 // Returns a string indicating the role of this object.
 - (NSString*)role {
   WebAccessibility::Role browserAccessibilityRole =
       static_cast<WebAccessibility::Role>( browserAccessibility_->role());
 
   // Roles that we only determine at runtime.
-  std::map<WebAccessibility::Role, NSString*>::iterator it =
-      webAccessibilityToNativeRole.find(browserAccessibilityRole);
-
-  if (it != webAccessibilityToNativeRole.end())
-    return it->second;
-  else
-    return NSAccessibilityUnknownRole;
+  return NativeRoleFromWebAccessibilityRole(browserAccessibilityRole);
 }
 
 // Returns a string indicating the role description of this object.
 - (NSString*)roleDescription {
   NSString* role = [self role];
 
   content::ContentClient* content_client = content::GetContentClient();
 
   // The following descriptions are specific to webkit.
   if ([role isEqualToString:@"AXWebArea"]) {
@@ skipping 66 matching lines @@
 
   if (browserAccessibilityRole == WebAccessibility::ROLE_LIST) {
     if ([htmlTag isEqualToString:@"ul"] ||
         [htmlTag isEqualToString:@"ol"]) {
       return @"AXContentList";
     } else if ([htmlTag isEqualToString:@"dl"]) {
       return @"AXDefinitionList";
     }
   }
 
-  std::map<WebAccessibility::Role, NSString*>::iterator it =
-      webAccessibilityToNativeSubrole.find(browserAccessibilityRole);
-  if (it != webAccessibilityToNativeSubrole.end())
-    return it->second;
-  else
-    return nil;
+  return NativeSubroleFromWebAccessibilityRole(browserAccessibilityRole);
 }
 
 // Returns all tabs in this subtree.
 - (NSArray*)tabs {
   NSMutableArray* tabSubtree = [[[NSMutableArray alloc] init] autorelease];
 
   if (browserAccessibility_->role() == WebAccessibility::ROLE_TAB)
     [tabSubtree addObject:self];
 
   for (uint i=0; i < [[self children] count]; ++i) {
@@ skipping 427 matching lines @@
     return [super hash];
   return browserAccessibility_->renderer_id();
 }
 
 - (BOOL)accessibilityShouldUseUniqueId {
   return YES;
 }
 
 @end