compositor_unittests target is unimplmented on Mac

ui/gfx/compositor/test_compositor_host_mac.mm

+// Copyright (c) 2011 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "ui/gfx/compositor/test_compositor_host.h"
+
+#import <AppKit/NSApplication.h>
+#import <AppKit/NSOpenGL.h>
+#import <AppKit/NSView.h>
+#import <AppKit/NSWindow.h>
+#import <Foundation/NSAutoreleasePool.h>
+
+#include "base/compiler_specific.h"
+#include "ui/gfx/compositor/compositor.h"
+#include "ui/gfx/rect.h"
+
+// AcceleratedTestView provides an NSView class that delegates drawing to a
+// ui::Compositor delegate, setting up the NSOpenGLContext as required.
+@interface AcceleratedTestView : NSView {
+  scoped_refptr<ui::Compositor> compositor_;
+}
+// Designated initializer.
+-(id)init;
+-(void)setCompositor:(scoped_refptr<ui::Compositor>)compositor;
+@end
+
+@implementation AcceleratedTestView
+-(id)init {
+  // The frame will be resized when reparented into the window's view hierarchy.
+  self = [super initWithFrame:NSZeroRect];
+  return self;
+}
+
+-(void)setCompositor:(scoped_refptr<ui::Compositor>)compositor {
+  compositor_ = compositor;
+}
+
+- (void)drawRect:(NSRect)rect {
+  DCHECK(compositor_) << "Drawing with no compositor set.";
+
+  NSOpenGLContext* context = [NSOpenGLContext currentContext];

[Nico, 2011/11/16 19:11:13]

Won't that just return nil? Where are you setting up a GL context?

[dhollowa, 2011/11/16 19:59:18]

The current context gets set by the compositing machinery.  The test "host"
coordinates the drawing code, which draws using the compositor, then when the
compositor has done its thing it alerts the "host" that drawing should happen. 
This code gets triggered and the gl context is properly set.

On 2011/11/16 19:11:13, Nico wrote:

+  [context setView:self];
+  compositor_->Draw(false);
+}
+@end
+
+namespace ui {
+
+// Tests that use Objective-C memory semantics need to have a top-level
+// NSAutoreleasePool set up and initialized prior to execution and drained upon
+// exit.  The tests will leak otherwise.
+class FoundationHost {

[Nico, 2011/11/16 19:11:13]

Can you use testing/platform_test.h instead?

[dhollowa, 2011/11/16 19:59:18]

Not in this case, no.  The tests need to run cross-platform, so a parallel
"host" hierarchy was needed.

On 2011/11/16 19:11:13, Nico wrote:

+ protected:
+  FoundationHost() {
+    pool_ = [[NSAutoreleasePool alloc] init];
+  }
+  virtual ~FoundationHost() {
+    [pool_ drain];
+  }
+
+ private:
+  NSAutoreleasePool* pool_;
+  DISALLOW_COPY_AND_ASSIGN(FoundationHost);
+};
+
+// Tests that use the AppKit framework need to have the NSApplication
+// initialized prior to doing anything with display objects such as windows,
+// views, or controls.
+class AppKitHost : public FoundationHost {
+ protected:
+  AppKitHost() {
+    [NSApplication sharedApplication];

[Nico, 2011/11/16 19:11:13]

base relies on NSApp implementing some custom protocol – should you be using
CrApplication here?

Also, most of our test suites create NSApp during test suite main(), not in the
individual tests – if gfx_tests doesn't do that, maybe add it there instead?

[dhollowa, 2011/11/16 19:59:18]

No, CrApplication's main benefit is in diverting events.  There is no need for
that functionality in these tests which are largely visual, and non-interactive.
I followed the principle of narrowest scope with this.  Since these are
currently the only tests that need AppKit stuff I've kept them contained here. 
I prefer this.  I'll keep an eye on this though and promote up to the gfx_tests
level if we need them elsewhere.  That is, if you agree.

[Nico, 2011/11/16 20:04:22]

message_loop_mac still DCHECKs that NSApp
conformsToProtocol:@protocol(CrAppProtocol). Maybe the tests don't use message
loops?

[dhollowa, 2011/11/16 20:25:24]

Correct.  No message loops here, though that may change.  If/when it does I'll
bring in CrApplication.  Thanks for pointing that out.

+  }
+  virtual ~AppKitHost() {
+  }
+ private:
+  DISALLOW_COPY_AND_ASSIGN(AppKitHost);
+};
+
+// TestCompositorHostMac provides a window surface and a coordinated compositor
+// for use in the compositor unit tests.
+class TestCompositorHostMac : public TestCompositorHost,
+                              public CompositorDelegate,
+                              public AppKitHost {
+ public:
+  TestCompositorHostMac(const gfx::Rect& bounds);
+  virtual ~TestCompositorHostMac();
+
+ private:
+  // TestCompositorHost:
+  virtual void Show() OVERRIDE;
+  virtual ui::Compositor* GetCompositor() OVERRIDE;
+
+  // CompositorDelegate:
+  virtual void ScheduleDraw() OVERRIDE;
+
+  gfx::Rect bounds_;
+  scoped_refptr<ui::Compositor> compositor_;
+
+  // Owned.  Released when window is closed.
+  NSWindow* window_;
+
+  DISALLOW_COPY_AND_ASSIGN(TestCompositorHostMac);
+};
+
+TestCompositorHostMac::TestCompositorHostMac(const gfx::Rect& bounds)
+    : bounds_(bounds), window_(nil) {
+}
+
+TestCompositorHostMac::~TestCompositorHostMac() {
+  [window_ orderOut:nil];
+  [window_ close];
+}
+
+void TestCompositorHostMac::Show() {
+  DCHECK(!window_);
+  window_ = [[NSWindow alloc]
+                initWithContentRect:NSMakeRect(bounds_.x(),
+                                               bounds_.y(),
+                                               bounds_.width(),
+                                               bounds_.height())
+                          styleMask:NSBorderlessWindowMask
+                            backing:NSBackingStoreBuffered
+                              defer:NO];
+  AcceleratedTestView* view = [[[AcceleratedTestView alloc] init] autorelease];
+  compositor_ = ui::Compositor::Create(this, view, bounds_.size());
+  [view setCompositor:compositor_];
+  [window_ setContentView:view];
+  [window_ orderFront:nil];
+}
+
+ui::Compositor* TestCompositorHostMac::GetCompositor() {
+  return compositor_;
+}
+
+void TestCompositorHostMac::ScheduleDraw() {
+  if (!compositor_)
+    return;
+
+  // Force display now.
+  [window_ display];
+}
+
+// static
+TestCompositorHost* TestCompositorHost::Create(const gfx::Rect& bounds) {
+  return new TestCompositorHostMac(bounds);
+}
+
+}  // namespace ui