PrintPreview: [MAC] Set the system default page size in NSPrintInfo PMPageFormat.

printing/printing_context_mac.mm

 // Copyright (c) 2011 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "printing/printing_context_mac.h"
 
 #import <ApplicationServices/ApplicationServices.h>
 #import <AppKit/AppKit.h>
 
 #include "base/logging.h"
@@ skipping 125 matching lines @@
       return OnError();
 
     if (!SetDuplexModeInPrintSettings(
             static_cast<DuplexMode>(duplex_mode))) {
       return OnError();
     }
 
     if (!SetOutputColor(color))
       return OnError();
   }
+  if (!SetPaperName())
+    return OnError();
 
   if (!SetOrientationIsLandscape(landscape))
     return OnError();
 
   [print_info_.get() updateFromPMPrintSettings];
 
   InitPrintSettingsFromPrintInfo(ranges);
   return OK;
 }
 
@@ skipping 34 matching lines @@
 
   PMPrinter new_printer = PMPrinterCreateFromPrinterID(new_printer_id.get());
   if (new_printer == NULL)
     return false;
 
   OSStatus status = PMSessionSetCurrentPMPrinter(print_session, new_printer);
   PMRelease(new_printer);
   return status == noErr;
 }
 
+bool PrintingContextMac::SetPaperName() {

[csilv, 2011/11/01 17:34:14]

'SetPaperName' seems like an odd name for this method.  Perhaps
'SetPaperFormat', 'ConfigPaperFormat', or something similar would be a better
choice?

[kmadhusu, 2011/11/01 20:00:41]

SetPaperName => UpdatePageFormatWithPaperInfo

[csilv, 2011/11/01 20:11:59]

Fantastic, thanks.

On 2011/11/01 20:00:41, kmadhusu wrote:

+  PMPrintSession print_session =
+      static_cast<PMPrintSession>([print_info_.get() PMPrintSession]);
+
+  PMPageFormat default_page_format =
+      static_cast<PMPageFormat>([print_info_.get() PMPageFormat]);
+
+  PMPaper default_paper;
+  if (PMGetPageFormatPaper(default_page_format, &default_paper) != noErr)
+    return false;
+
+  double default_page_width, default_page_height;
+  if (PMPaperGetWidth(default_paper, &default_page_width) != noErr)
+    return false;
+
+  if (PMPaperGetHeight(default_paper, &default_page_height) != noErr)
+    return false;
+
+  PMPrinter current_printer = NULL;
+  if (PMSessionGetCurrentPrinter(print_session, &current_printer) != noErr)
+    return false;
+
+  if (current_printer == nil)
+    return false;
+
+  CFArrayRef paper_list = NULL;
+  if (PMPrinterGetPaperList(current_printer, &paper_list) != noErr)
+    return false;
+
+  int num_papers = CFArrayGetCount(paper_list);
+  PMPaper best_matching_paper = kPMNoData;
+  for (int i = 0; i < num_papers; ++i) {
+    PMPaper paper = (PMPaper) [(NSArray* ) paper_list objectAtIndex: i];

[csilv, 2011/11/01 17:34:14]

This can be simplified by using NSArray fast enumeration.  Replace lines 231-233
with:

  for (PMPaper paper in (NSArray*)paper_list) {

[kmadhusu, 2011/11/01 20:00:41]

As we discussed, I am ignoring this comment.

+    double paper_width, paper_height;
+    PMPaperGetWidth(paper, &paper_width);
+    PMPaperGetHeight(paper, &paper_height);
+    if (default_page_width == paper_width &&
+        default_page_height == paper_height) {
+      best_matching_paper = paper;
+      break;
+    }
+    // Trying to find the best matching paper.
+    if (fabs(default_page_width - paper_width) < 2 &&
+        fabs(default_page_height - paper_height) < 2) {
+      best_matching_paper = paper;
+    }
+  }
+
+  if (best_matching_paper == kPMNoData) {
+    PMPaper paper = kPMNoData;
+    // Create a custom paper for the specified default page size.
+    PMPaperMargins default_margins;
+    if (PMPaperGetMargins(default_paper, &default_margins) != noErr)
+      return false;
+
+    const PMPaperMargins margins =
+        {default_margins.top, default_margins.left, default_margins.bottom,
+         default_margins.right};
+    std::string paper_id_str("Custom paper ID");
+    std::string paper_name_str("Custom paper");
+    CFStringRef paper_id = base::SysUTF8ToCFStringRef(paper_id_str);
+    CFStringRef paper_name = base::SysUTF8ToCFStringRef(paper_name_str);

[csilv, 2011/11/01 17:34:14]

paper_id and paper_name will leak memory because SysUTF8ToCFStringRef returns a
new object. Instead, replace 260-263 with:

  CFStringRef paper_id = CFSTR("Custom paper ID");
  CFStringRef paper_name = CFSTR("Custom paper");

[kmadhusu, 2011/11/01 20:00:41]

Done.

+#if (MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5)
+    if (PMPaperCreateCustom != NULL) {
+      if (PMPaperCreateCustom(current_printer, paper_id, paper_name,
+              default_page_width, default_page_height,
+              &margins, &paper) != noErr) {
+        return false;
+      }
+    }
+#else
+    if (paper == kPMNoData) {
+      if (PMPaperCreate(current_printer, paper_id, paper_name,

[kmadhusu, 2011/11/01 20:00:41]

This code will run on machines whose version is MAC_OS_X_VERSION_10_5 or less.
Do we have any try bot or machines similar to this configuration?

[csilv, 2011/11/01 20:11:59]

Oh, thanks for asking about this.  You can remove this section entirely. 
MacChrome has always required 10.5 or later.

+              default_page_width, default_page_height,
+              &margins, &paper) != noErr) {
+        return false;
+      }
+    }
+#endif
+    [print_info_.get() updateFromPMPageFormat];
+    PMRelease(paper);
+  } else {
+    PMPageFormat chosen_page_format = NULL;
+    if (PMCreatePageFormat((PMPageFormat*) &chosen_page_format) != noErr)
+      return false;
+
+    // Create page format from that paper.
+    if (PMCreatePageFormatWithPMPaper(&chosen_page_format,
+            best_matching_paper) != noErr) {
+      PMRelease(chosen_page_format);
+      return false;
+    }
+    // Copy over the original format with the new page format.
+    if (PMCopyPageFormat(chosen_page_format, default_page_format) != noErr) {
+      PMRelease(chosen_page_format);
+      return false;
+    }
+    [print_info_.get() updateFromPMPageFormat];
+    PMRelease(chosen_page_format);
+  }
+  return true;
+}
+
 bool PrintingContextMac::SetCopiesInPrintSettings(int copies) {
   if (copies < 1)
     return false;
 
   PMPrintSettings pmPrintSettings =
       static_cast<PMPrintSettings>([print_info_.get() PMPrintSettings]);
   return PMSetCopies(pmPrintSettings, copies, false) == noErr;
 }
 
 bool PrintingContextMac::SetCollateInPrintSettings(bool collate) {
   PMPrintSettings pmPrintSettings =
       static_cast<PMPrintSettings>([print_info_.get() PMPrintSettings]);
   return PMSetCollate(pmPrintSettings, collate) == noErr;
 }
 
 bool PrintingContextMac::SetOrientationIsLandscape(bool landscape) {
   PMPageFormat page_format =
       static_cast<PMPageFormat>([print_info_.get() PMPageFormat]);
 
   PMOrientation orientation = landscape ? kPMLandscape : kPMPortrait;
 
   if (PMSetOrientation(page_format, orientation, false) != noErr)
     return false;
 
+  PMPrintSession print_session =
+      static_cast<PMPrintSession>([print_info_.get() PMPrintSession]);
+
+  PMSessionValidatePageFormat(print_session, page_format, kPMDontWantBoolean);
+
   [print_info_.get() updateFromPMPageFormat];
   return true;
 }
 
 bool PrintingContextMac::SetDuplexModeInPrintSettings(DuplexMode mode) {
   PMDuplexMode duplexSetting;
   switch (mode) {
     case LONG_EDGE:
       duplexSetting = kPMDuplexNoTumble;
       break;
@@ skipping 143 matching lines @@
 void PrintingContextMac::ReleaseContext() {
   print_info_.reset();
   context_ = NULL;
 }
 
 gfx::NativeDrawingContext PrintingContextMac::context() const {
   return context_;
 }
 
 }  // namespace printing