Adding VideoCaptureDevice for Mac.

media/video/capture/mac/video_capture_device_mac_qtkit.mm

+// Copyright (c) 2011 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "media/video/capture/mac/video_capture_device_mac_qtkit.h"
+
+#import <QTKit/QTKit.h>
+
+#include "base/logging.h"
+
+@implementation VideoCaptureDeviceMacQTKit
+
+- (id)init {
+  return [super init];
+}
+
+- (void)dealloc {
+  [captureSession_ release];
+  [captureDecompressedOutput_ release];
+  [captureDeviceInput_ release];
+  [super dealloc];
+}
+
+#pragma mark Class methods
+
++ (NSArray *)deviceNames {
+  return [QTCaptureDevice inputDevicesWithMediaType:QTMediaTypeVideo];
+}
+
+#pragma mark Public methods
+
+- (void)setFrameReceiver:(media::VideoCaptureDeviceMac *)frameReceiver {
+  frameReceiver_ = frameReceiver;
+}
+
+- (BOOL)setCaptureDevice:(NSString *)deviceId {
+  if (deviceId) {
+    // Set the capture device.
+    if (captureDeviceInput_) {
+      DLOG(ERROR) << "Video capture device already set.";
+      return NO;
+    }
+
+    NSArray *captureDevices =
+        [QTCaptureDevice inputDevicesWithMediaType:QTMediaTypeVideo];
+    NSArray *captureDevicesNames =
+        [captureDevices valueForKey:@"uniqueID"];
+    NSUInteger index = [captureDevicesNames indexOfObject:deviceId];
+    if (index == NSNotFound) {
+      DLOG(ERROR) << "Video capture device not found.";
+      return NO;
+    }
+    QTCaptureDevice *device = [captureDevices objectAtIndex:index];
+    NSError *error = nil;
+    if (![device open:&error]) {
+      DLOG(ERROR) << "Could not open video capture device.";
+      return NO;
+    }
+    captureDeviceInput_ = [[QTCaptureDeviceInput alloc] initWithDevice:device];
+    captureSession_ = [[QTCaptureSession alloc] init];
+    captureDecompressedOutput_ =
+        [[QTCaptureDecompressedVideoOutput alloc] init];
+    [captureDecompressedOutput_ setDelegate:self];
+    return YES;
+  } else {
+    // Remove the previously set capture device.
+    if (!captureDeviceInput_) {
+      return YES;
+    }
+    if ([[captureSession_ inputs] count] > 0) {
+      // The device is still running.
+      [self stopCapture];
+    }
+    [captureDecompressedOutput_ release];
+    captureDecompressedOutput_ = nil;
+    [captureSession_ release];
+    captureSession_ = nil;
+    [captureDeviceInput_ release];
+    captureDeviceInput_ = nil;
+    return YES;
+  }
+}
+
+- (BOOL)setCaptureCapabilities:(int)height:(int)width:(int)frameRate {
+  if (!captureDeviceInput_) {
+    DLOG(ERROR) << "No video capture device set.";
+    return NO;
+  }
+
+  frameWidth_ = width;
+  frameHeight_ = height;
+  frameRate_ = frameRate;
+
+  // Set up desired output properties.
+  NSDictionary *captureDictionary =
+      [NSDictionary dictionaryWithObjectsAndKeys:
+          [NSNumber numberWithDouble:frameWidth_],
+          (id)kCVPixelBufferWidthKey,
+          [NSNumber numberWithDouble:frameHeight_],
+          (id)kCVPixelBufferHeightKey,
+          [NSNumber numberWithUnsignedInt:kCVPixelFormatType_32BGRA],
+          (id)kCVPixelBufferPixelFormatTypeKey,
+          nil];
+  [captureDecompressedOutput_ setPixelBufferAttributes:captureDictionary];
+
+  // Connect the output with the session.
+  NSError *error;
+  if (![captureSession_ addOutput:captureDecompressedOutput_ error:&error]) {
+    DLOG(ERROR) << "Could not connect video capture output.";
+    return NO;
+  }
+  return YES;
+}
+
+- (BOOL)startCapture {
+  if ([[captureSession_ outputs] count] == 0) {
+    // Capture properties not set.
+    DLOG(ERROR) << "Video capture device not initialized.";
+    return NO;
+  }
+  if ([[captureSession_ inputs] count] == 0) {
+    NSError *error;
+    if (![captureSession_ addInput:captureDeviceInput_ error:&error]) {
+      DLOG(ERROR) << "Could not connect video capture device.";
+      return NO;
+    }
+    [captureSession_ startRunning];
+  }
+  return YES;
+}
+
+- (void)stopCapture {
+  if ([[captureSession_ inputs] count] > 0) {
+    [captureSession_ removeInput:captureDeviceInput_];
+    [captureSession_ stopRunning];
+  }
+}
+
+// |captureOutput| is called by the capture device to deliver a new frame.
+- (void)captureOutput:(QTCaptureOutput *)captureOutput
+  didOutputVideoFrame:(CVImageBufferRef)videoFrame
+     withSampleBuffer:(QTSampleBuffer *)sampleBuffer
+       fromConnection:(QTCaptureConnection *)connection {
+
+  if(!frameReceiver_) {
+    return;
+  }
+
+  // Lock the frame and calculate frame size.
+  const int LOCK_FLAGS = 0;
+  if (CVPixelBufferLockBaseAddress(videoFrame, LOCK_FLAGS)
+      == kCVReturnSuccess) {
+    void *baseAddress = CVPixelBufferGetBaseAddress(videoFrame);
+    size_t bytesPerRow = CVPixelBufferGetBytesPerRow(videoFrame);
+    int frameHeight = CVPixelBufferGetHeight(videoFrame);
+    int frameSize = bytesPerRow * frameHeight;
+    media::VideoCaptureDevice::Capability captureCapability;
+    captureCapability.width = frameWidth_;
+    captureCapability.height = frameHeight_;
+    captureCapability.frame_rate = frameRate_;
+    captureCapability.color = media::VideoCaptureDevice::kARGB;
+
+    // Deliver the captured video frame.
+    frameReceiver_->IncomingFrame(baseAddress, frameSize, captureCapability);
+
+    CVPixelBufferUnlockBaseAddress(videoFrame, LOCK_FLAGS);
+  }
+}
+
+@end