Applescript: return value from execute javascript command

chrome/browser/ui/cocoa/applescript/tab_applescript.mm

 // Copyright (c) 2011 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/applescript/tab_applescript.h"
 
 #include "base/file_path.h"
 #include "base/logging.h"
 #import "base/memory/scoped_nsobject.h"
 #include "base/sys_string_conversions.h"
 #include "base/utf_string_conversions.h"
 #include "chrome/browser/printing/print_view_manager.h"
 #include "chrome/browser/sessions/restore_tab_helper.h"
 #include "chrome/browser/sessions/session_id.h"
 #include "chrome/browser/ui/cocoa/applescript/error_applescript.h"
 #include "chrome/browser/ui/tab_contents/tab_contents_wrapper.h"
 #include "chrome/common/url_constants.h"
 #include "content/browser/download/save_package.h"
 #include "content/browser/renderer_host/render_view_host.h"
 #include "content/browser/tab_contents/navigation_controller.h"
 #include "content/browser/tab_contents/navigation_entry.h"
 #include "content/browser/tab_contents/tab_contents_delegate.h"
 #include "content/common/view_messages.h"
 #include "googleurl/src/gurl.h"
 
+@interface AnyResultValue : NSObject {
+ @private
+  scoped_nsobject<NSAppleEventDescriptor> descriptor;
+}
+- (id)initWithDescriptor:(NSAppleEventDescriptor*)desc;
+- (NSAppleEventDescriptor *)scriptingAnyDescriptor;
+@end
+
+@implementation AnyResultValue
+
+- (id)initWithDescriptor:(NSAppleEventDescriptor*)desc {
+  if (self = [super init]) {
+    descriptor.reset([desc retain]);
+  }
+  return self;
+}
+
+- (NSAppleEventDescriptor *) scriptingAnyDescriptor {

[Avi (use Gerrit), 2011/10/17 14:20:38]

nit: no space after )

[keishi, 2011/10/21 05:05:43]

Done.

+  return descriptor.get();
+}
+
+@end
+
+static NSAppleEventDescriptor* valueToDescriptor(Value* value) {
+  NSAppleEventDescriptor* descriptor = nil;
+  switch (value->GetType()) {
+    case Value::TYPE_NULL:
+      descriptor = [NSAppleEventDescriptor
+          descriptorWithTypeCode:cMissingValue];
+      break;
+    case Value::TYPE_BOOLEAN: {
+      bool bool_value;
+      value->GetAsBoolean(&bool_value);
+      descriptor = [NSAppleEventDescriptor descriptorWithBoolean:bool_value];
+      break;
+    }
+    case Value::TYPE_INTEGER: {
+      int int_value;
+      value->GetAsInteger(&int_value);
+      descriptor = [NSAppleEventDescriptor descriptorWithInt32:int_value];

[Avi (use Gerrit), 2011/10/17 14:20:38]

Why int32? Is this future proof for 64-bits?

[keishi, 2011/10/21 05:05:43]

JS integers are 32 bits.

+      break;
+    }
+    case Value::TYPE_DOUBLE: {
+      double double_value;
+      value->GetAsDouble(&double_value);
+      descriptor = [NSAppleEventDescriptor
+          descriptorWithDescriptorType:typeIEEE64BitFloatingPoint
+                                 bytes:&double_value
+                                length:sizeof(double_value)];
+      break;
+    }
+    case Value::TYPE_STRING: {
+      std::string string_value;
+      value->GetAsString(&string_value);
+      descriptor = [NSAppleEventDescriptor descriptorWithString:
+          base::SysUTF8ToNSString(string_value)];
+      break;
+    }
+    case Value::TYPE_BINARY:
+      NOTREACHED();
+      break;
+    case Value::TYPE_DICTIONARY: {
+      DictionaryValue* dictionary_value = static_cast<DictionaryValue*>(value);
+      descriptor = [NSAppleEventDescriptor recordDescriptor];
+      NSAppleEventDescriptor* userRecord = [NSAppleEventDescriptor
+          listDescriptor];
+      for (DictionaryValue::key_iterator iter(dictionary_value->begin_keys());
+           iter != dictionary_value->end_keys(); ++iter) {
+        Value* item;
+        if (dictionary_value->Get(*iter, &item)) {
+          [userRecord insertDescriptor:[NSAppleEventDescriptor
+              descriptorWithString:base::SysUTF8ToNSString(*iter)] atIndex:0];
+          [userRecord insertDescriptor:valueToDescriptor(item) atIndex:0];
+        }
+      }
+      [descriptor setDescriptor:userRecord forKeyword:keyASUserRecordFields];

[Avi (use Gerrit), 2011/10/17 14:20:38]

Can you find a link to put in here for keyASUserRecordFields? That's a bit
obscure and I had to search for a while.

[keishi, 2011/10/21 05:05:43]

I can't find the right documentation from Apple so I linked to this
http://google-toolbox-for-mac.googlecode.com/svn/tags/google-toolbox-for-mac-...

[Avi (use Gerrit), 2011/10/21 11:50:48]

A plaintext description?
http://www.mail-archive.com/cocoa-dev@lists.apple.com/msg40149.html

But yes, that's very underdocumented.

+      break;
+    }
+    case Value::TYPE_LIST: {
+      ListValue* list_value;
+      value->GetAsList(&list_value);
+      descriptor = [NSAppleEventDescriptor listDescriptor];
+      for (unsigned i = 0; i < list_value->GetSize(); ++i) {
+        Value* item;
+        list_value->Get(i, &item);
+        [descriptor insertDescriptor:valueToDescriptor(item) atIndex:0];

[Avi (use Gerrit), 2011/10/17 14:20:38]

Doesn't this reverse the order of the items in the list?

[keishi, 2011/10/21 05:05:43]

AppleScript lists are 1 based and specifying index 0 appends the object at the
end.
http://developer.apple.com/library/mac/documentation/Cocoa/Reference/Foundati...:

[Avi (use Gerrit), 2011/10/21 11:50:48]

Sigh. Been way too long since I've done this.

+      }
+      break;
+    }
+  }
+  return descriptor;
+}
+
 @interface TabAppleScript()
 @property (nonatomic, copy) NSString* tempURL;
 @end
 
 @implementation TabAppleScript
 
 @synthesize tempURL = tempURL_;
 
 - (id)init {
   if ((self = [super init])) {
@@ skipping 258 matching lines @@
 
 - (id)handlesExecuteJavascriptScriptCommand:(NSScriptCommand*)command {
   RenderViewHost* view = tabContents_->render_view_host();
   if (!view) {
     NOTREACHED();
     return nil;
   }
 
   string16 script = base::SysNSStringToUTF16(
       [[command evaluatedArguments] objectForKey:@"javascript"]);
-  view->ExecuteJavascriptInWebFrame(string16(), script);
-
-  // TODO(Shreyas): Figure out a way to get the response back.
-  return nil;
+  Value* value = view->ExecuteJavascriptAndGetValue(string16(), script);
+  NSAppleEventDescriptor* descriptor = valueToDescriptor(value);
+  return [[[AnyResultValue alloc] initWithDescriptor:descriptor] autorelease];

[Avi (use Gerrit), 2011/10/17 14:20:38]

I'm a bit lost. We're returning a custom object? How does the scripting
environment know how to get data out?

[keishi, 2011/10/21 05:05:43]

The AppleScript calls selectors on the object based on the type specified in the
sdef file.
In this case command "execute javascript" returns an "any" object so it is going
to call, @selector(scriptingAnyDescriptor).

[Avi (use Gerrit), 2011/10/21 11:50:48]

Gotcha.

 }
 
 @end