[Mac] Add two-finger gesture support for Lion, which respects the system preference.

chrome/browser/ui/cocoa/browser_window_controller.mm

 // Copyright (c) 2011 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/browser_window_controller.h"
 
 #include <Carbon/Carbon.h>
+#include <numeric>
 
 #include "base/command_line.h"
 #include "base/mac/mac_util.h"
 #import "base/memory/scoped_nsobject.h"
 #include "base/sys_string_conversions.h"
 #include "chrome/app/chrome_command_ids.h"  // IDC_*
 #include "chrome/browser/bookmarks/bookmark_editor.h"
 #include "chrome/browser/google/google_util.h"
 #include "chrome/browser/instant/instant_controller.h"
 #include "chrome/browser/profiles/profile.h"
@@ skipping 116 matching lines @@
 // animated. Basically, the BWC doesn't see the global picture, but it sees
 // grows and shrinks in small increments (as dictated by the animation). Thus
 // window growth/shrinkage (at the top/bottom) have to be tracked incrementally.
 // Allowing shrinking from the zoomed state also requires tracking: We check on
 // any shrink whether we're both zoomed and have previously grown -- if so, we
 // set a flag, and constrain any resize by the allowed amounts. On further
 // shrinks, we check the flag (since the size/position of the window will no
 // longer indicate that the window is shrinking from an apparent zoomed state)
 // and if it's set we continue to constrain the resize.
 
-
 @interface NSWindow (NSPrivateApis)
 // Note: These functions are private, use -[NSObject respondsToSelector:]
 // before calling them.
 
 - (void)setBottomCornerRounded:(BOOL)rounded;
 
 - (NSRect)_growBoxRect;
 
 @end
 
@@ skipping 1543 matching lines @@
     browser_->ExecuteCommandWithDisposition(command,
         event_utils::WindowOpenDispositionFromNSEvent(event));
   }
 }
 
 // Documented in 10.6+, but present starting in 10.5. Called at the beginning
 // of a gesture.
 - (void)beginGestureWithEvent:(NSEvent*)event {
   totalMagnifyGestureAmount_ = 0;
   currentZoomStepDelta_ = 0;
+
+  // On Lion, there's support controlled by a System Preference for two- and
+  // three-finger navigational gestures. If set to allow three-finger gestures,
+  // the system gesture recognizer will automatically call |-swipeWithEvent:|
+  // and that will be handled as it would be on Snow Leopard. The two-finger
+  // gesture does not do this, so it must be manually recogniezd. See the note

[Nico, 2011/07/22 20:21:14]

recognized

mnemonic: "i before e except around z"

[Robert Sesek, 2011/07/22 20:26:23]

I fixed sooo many typos before I uploaded this. I'm surprised this was the only
one :P.

+  // inside |-recognizeTwoFingerGestures| for detailed information on the
+  // interaction of the different preferences.
+  NSSet* touches = [event touchesMatchingPhase:NSTouchPhaseAny
+                                        inView:nil];
+  if ([self recognizeTwoFingerGestures] && [touches count] >= 2) {
+    twoFingerGestureTouches_.reset([[NSMutableDictionary alloc] init]);
+    for (NSTouch* touch in touches) {
+      [twoFingerGestureTouches_ setObject:touch forKey:touch.identity];
+    }
+  }
+}
+
+- (void)endGestureWithEvent:(NSEvent*)event {
+  // This method only needs to process gesture events for two-finger navigation.
+  if (!twoFingerGestureTouches_.get())
+    return;
+
+  // When a multi-touch gesture ends, only one touch will be in the "End" phase.
+  // Other touches will be in "Moved" or "Unknown" phases. So long as one is
+  // ended, which it is by virtue of this method being called, the gesture can
+  // be committed so long as the magnitude is great enough.

[Nico, 2011/07/22 20:21:14]

So two-finger drag followed by lifting one finger goes back? Hm, ok.

[Robert Sesek, 2011/07/22 20:26:23]

Yeah; it's funky but is also what Safari does. I tested a bunch of permutations
and this is as close as possible.

+  NSSet* touches = [event touchesMatchingPhase:NSTouchPhaseAny
+                                        inView:nil];
+
+  // Store the touch data locally and reset the ivar so that new gestures can
+  // begin.
+  scoped_nsobject<NSDictionary> beginTouches(
+      twoFingerGestureTouches_.release());
+
+  // Construct a vector of magnitudes. Since gesture events do not have the
+  // |-deltaX| property set, this creates the X magnitude for each finger.
+  std::vector<CGFloat> magnitudes;
+  for (NSTouch* touch in touches) {
+    NSTouch* beginTouch = [beginTouches objectForKey:touch.identity];
+    if (!beginTouch)
+      continue;

[Nico, 2011/07/22 20:21:14]

Does this ever happen in practice? I'd assume every touch that ends began at
some point?

(If not: Consider replacing magnitudes.size() < 2 with [touches count] < 2 and
just have an accumulator float instead of a vector + accumulate call)

[Robert Sesek, 2011/07/22 20:26:23]

Yes, it can. You can add new fingers mid-gesture. I contemplated in that case
adding the -normalizedPosition.x to the magnitudes, but it didn't work well in
practice.

+
+    // The |normalizedPosition| scaled from (0,1).

[Nico, 2011/07/22 20:21:14]

"is scaled"?

[Robert Sesek, 2011/07/22 20:26:23]

Done.

+    magnitudes.push_back(touch.normalizedPosition.x -
+        beginTouch.normalizedPosition.x);
+  }
+
+  // Need at least two points to gesture.
+  if (magnitudes.size() < 2)
+    return;
+
+  CGFloat sum = std::accumulate(magnitudes.begin(), magnitudes.end(), 0.0f);
+  int command_id = 0;
+  if (sum > 0.3)
+    command_id = IDC_FORWARD;
+  else if (sum < -0.3)
+    command_id = IDC_BACK;
+  else
+    return;
+
+  if (browser_->command_updater()->IsCommandEnabled(command_id)) {
+    browser_->ExecuteCommandWithDisposition(command_id,
+        event_utils::WindowOpenDispositionFromNSEvent(event));
+  }
 }
 
 // Delegate method called when window is resized.
 - (void)windowDidResize:(NSNotification*)notification {
   // Resize (and possibly move) the status bubble. Note that we may get called
   // when the status bubble does not exist.
   if (statusBubble_) {
     statusBubble_->UpdateSizeAndPosition();
   }
 
@@ skipping 471 matching lines @@
 
 - (BOOL)supportsBookmarkBar {
   return [self supportsWindowFeature:Browser::FEATURE_BOOKMARKBAR];
 }
 
 - (BOOL)isTabbedWindow {
   return browser_->is_type_tabbed();
 }
 
 @end  // @implementation BrowserWindowController(WindowType)