Update the tcmalloc vendor branch to r111 (perftools version 1.8)

third_party/tcmalloc/vendor/configure.ac

 ## Process this file with autoconf to produce configure.
 ## In general, the safest way to proceed is to run ./autogen.sh
 
 # make sure we're interpreted by some minimal autoconf
 AC_PREREQ(2.57)
 
-AC_INIT(google-perftools, 1.7, opensource@google.com)
+AC_INIT(google-perftools, 1.8, opensource@google.com)
 # Update this value for every release!  (A:B:C will map to foo.so.(A-C).C.B)
 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
-TCMALLOC_SO_VERSION=1:0:1
-PROFILER_SO_VERSION=1:0:1
+TCMALLOC_SO_VERSION=2:0:2
+PROFILER_SO_VERSION=1:1:1
 
 AC_SUBST(TCMALLOC_SO_VERSION)
 AC_SUBST(PROFILER_SO_VERSION)
 
 # The argument here is just something that should be in the current directory
 # (for sanity checking)
 AC_CONFIG_SRCDIR(README)
 AC_CONFIG_MACRO_DIR([m4])
 AC_CANONICAL_HOST
 AM_INIT_AUTOMAKE([dist-zip])
@@ skipping 209 matching lines @@
 CFLAGS="$CFLAGS -S -O2 -o fp.s"
 # This test will always fail because we don't name our output file properly.
 # We do our own determination of success/failure in the grep, below.
 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int f(int x) {return x;}], [return f(0);])],
                   [:], [:])
 AM_CONDITIONAL(X86_64_AND_NO_FP_BY_DEFAULT,
                test "$is_x86_64" = yes && ! grep 'mov.*rsp.*rbp' fp.s >/dev/null 2>&1)
 rm fp.s
 CFLAGS="$OLD_CFLAGS"
 
+# See if the compiler supports -Wno-unused-result.
+# Newer ubuntu's turn on -D_FORTIFY_SOURCE=2, enabling
+# __attribute__((warn_unused_result)) for things like write(),
+# which we don't care about.
+AC_CACHE_CHECK([if the compiler supports -Wno-unused-result],
+               perftools_cv_w_no_unused_result,
+               [OLD_CFLAGS="$CFLAGS"
+                CFLAGS="$CFLAGS -Wno-error -Wno-unused-result"
+                # gcc doesn't warn about unknown flags unless it's
+                # also warning for some other purpose, hence the
+                # divide-by-0.  (We use -Wno-error to make sure the
+                # divide-by-0 doesn't cause this test to fail!)
+                AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, return 1/0)],
+                                  perftools_cv_w_no_unused_result=yes,
+                                  perftools_cv_w_no_unused_result=no)
+                CFLAGS="$OLD_CFLAGS"])
+AM_CONDITIONAL(HAVE_W_NO_UNUSED_RESULT,
+               test "$perftools_cv_w_no_unused_result" = yes)
 
 # Defines PRIuS
 AC_COMPILER_CHARACTERISTICS
 
 # Also make sure we get standard PRI... definitions, even with glibc.
 # We have to use AH_VERBATIM because we need the #ifdef guard (gcc buglet)
 AH_VERBATIM([__STDC_FORMAT_MACROS],
             [/* C99 says: define this to get the PRI... macros from stdint.h */
 #ifndef __STDC_FORMAT_MACROS
 # define __STDC_FORMAT_MACROS 1
@@ skipping 18 matching lines @@
 
 # If we support __thread, that can speed up tcmalloc a bit.
 # Note, however, that our code tickles a bug in gcc < 4.1.2
 # involving TLS and -fPIC (which our libraries will use) on x86:
 #   http://gcc.gnu.org/ml/gcc-bugs/2006-09/msg02275.html
 AC_MSG_CHECKING([for __thread])
 AC_LINK_IFELSE([AC_LANG_PROGRAM([#if defined(__GNUC__) && (defined(__i386__) || defined(__x86_64__)) && ((__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 1) || (__GNUC__ == 4 && __GNUC_MINOR__ == 1 && __GNUC_PATCHLEVEL__ < 2))
 #error gcc has this bug: http://gcc.gnu.org/ml/gcc-bugs/2006-09/msg02275.html
 #endif], [static __thread int p = 0])],
                [AC_DEFINE(HAVE_TLS, 1,
-                      Define to 1 if compiler supports __thread)
+                          Define to 1 if compiler supports __thread)
                 AC_MSG_RESULT([yes])],
                [AC_MSG_RESULT([no])])
 
+# glibc's __malloc_hook/etc were declared volatile starting in glibc 2.14
+AC_MSG_CHECKING([if __malloc_hook is declared volatile])
+AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <malloc.h>
+void* (* volatile __malloc_hook)(size_t, const void*) = 0;],)],
+                  [AC_DEFINE(MALLOC_HOOK_MAYBE_VOLATILE, volatile,
+                             Define to 'volatile' if __malloc_hook is declared volatile)
+                   AC_MSG_RESULT([yes])],
+                  [AC_DEFINE(MALLOC_HOOK_MAYBE_VOLATILE, ),
+                   AC_MSG_RESULT([no])])
+
 # Nanosleep requires extra libraries on some architectures (solaris).
 # This sets NANOSLEEP_LIBS.  nanosleep doesn't exist on mingw, which
 # is fine for us because we don't compile libspinlock, which uses it.
 if test "$need_nanosleep" = yes; then
   ACX_NANOSLEEP
   AC_SUBST(NANOSLEEP_LIBS)
 fi
 
 # Solaris 10 6/06 has a bug where /usr/sfw/lib/libstdc++.la is empty.
 # If so, we replace it with our own version.
@@ skipping 34 matching lines @@
 # and it #includes other .h files.  These all have header guards, so
 # the end result is if config.h is #included twice, its #undefs get
 # evaluated twice, but all the ones in mingw.h/etc only get evaluated
 # once, potentially causing trouble.  c.f.
 #   http://code.google.com/p/google-perftools/issues/detail?id=246
 AH_TOP([
 #ifndef GOOGLE_PERFTOOLS_CONFIG_H_
 #define GOOGLE_PERFTOOLS_CONFIG_H_
 ])
 
+AH_VERBATIM([PTHREADS_CRASHES_IF_RUN_TOO_EARLY],
+            [/* Mark the systems where we know it's bad if pthreads runs too
+   early before main (before threads are initialized, presumably).  */
+#ifdef __FreeBSD__
+#define PTHREADS_CRASHES_IF_RUN_TOO_EARLY 1
+#endif])
+
 # MinGW uses autoconf, but also needs the windows shim routines
 # (since it doesn't have its own support for, say, pthreads).
 # This requires us to #include a special header file, and also to
 # link in some windows versions of .o's instead of the unix versions.
+#
+# Also, manually mark systems where we have to be careful how early
+# we run pthreads.  TODO(csilvers): turn this into an autoconf check.
 AH_BOTTOM([
 #ifdef __MINGW32__
 #include "windows/mingw.h"
 #endif
 
 #endif  /* #ifndef GOOGLE_PERFTOOLS_CONFIG_H_ */
 ])
 AM_CONDITIONAL(MINGW, expr $host : '.*-mingw' >/dev/null 2>&1)
+AM_CONDITIONAL(OSX, expr $host : '.*-apple-darwin.*' >/dev/null 2>&1)
 
 # Redhat 7 (and below?) has sys/ucontext.h, but if you try to #include
 # it directly, the compiler gets upset.  So we pretend we don't have
 # it.
 if cat /etc/redhat-release 2>/dev/null | grep "Red Hat Linux release 7" >/dev/null 2>&1; then
 AC_DEFINE(HAVE_SYS_UCONTEXT_H, 0, [<sys/ucontext.h> is broken on redhat 7])
 fi
 
 # Export the --enable flags we set above.  We do this at the end so
 # other configure rules can enable or disable targets based on what
 # they find.
 AM_CONDITIONAL(WITH_CPU_PROFILER, test "$enable_cpu_profiler" = yes)
 AM_CONDITIONAL(WITH_HEAP_PROFILER, test "$enable_heap_profiler" = yes)
 AM_CONDITIONAL(WITH_HEAP_CHECKER, test "$enable_heap_checker" = yes)
 AM_CONDITIONAL(WITH_DEBUGALLOC, test "$enable_debugalloc" = yes)
 # We make tcmalloc.so if either heap-profiler or heap-checker is asked for.
 AM_CONDITIONAL(WITH_HEAP_PROFILER_OR_CHECKER,
                test "$enable_heap_profiler" = yes -o \
                     "$enable_heap_checker" = yes)
 # If we don't use any profilers, we don't need stack traces (or pprof)
 AM_CONDITIONAL(WITH_STACK_TRACE, test "$enable_cpu_profiler" = yes -o \
                                       "$enable_heap_profiler" = yes -o \
                                       "$enable_heap_checker" = yes)
 
 # Write generated configuration file
 AC_CONFIG_FILES([Makefile src/google/tcmalloc.h src/windows/google/tcmalloc.h])
 AC_OUTPUT