net-libs/libsoup: backport 2.32.2 from upstream tree.

net-libs/libsoup/libsoup-2.32.2.ebuild

Index: net-libs/libsoup/libsoup-2.32.2.ebuild
diff --git a/net-libs/libsoup/libsoup-2.32.2.ebuild b/net-libs/libsoup/libsoup-2.32.2.ebuild
new file mode 100644
index 0000000000000000000000000000000000000000..903cbb58fb9bcd1c393fd68c1d281f5c778419f9
--- /dev/null
+++ b/net-libs/libsoup/libsoup-2.32.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libsoup/libsoup-2.32.2.ebuild,v 1.9 2011/04/15 16:18:32 darkside Exp $
+
+EAPI="3"
+GCONF_DEBUG="yes"
+
+inherit autotools eutils gnome2
+
+DESCRIPTION="An HTTP library implementation in C"
+HOMEPAGE="http://live.gnome.org/LibSoup"
+
+LICENSE="LGPL-2"
+SLOT="2.4"
+KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sh sparc x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="debug doc +introspection ssl test"
+
+RDEPEND=">=dev-libs/glib-2.21.3
+	>=dev-libs/libxml2-2
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
+	ssl? ( >=net-libs/gnutls-2.1.7 )"
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/gtk-doc-am-1.10
+	doc? ( >=dev-util/gtk-doc-1.10 )"
+#	test? (	www-servers/apache[ssl,apache2_modules_auth_digest,apache2_modules_alias,apache2_modules_auth_basic,
+#		apache2_modules_authn_file,apache2_modules_authz_host,apache2_modules_authz_user,apache2_modules_dir,
+#		apache2_modules_mime,apache2_modules_proxy,apache2_modules_proxy_http,apache2_modules_proxy_connect]
+#		dev-lang/php[apache2]
+#		net-misc/curl )"
+
+pkg_setup() {
+	# Set invalid apache module dir until apache tests are ready, bug #326957
+	DOCS="AUTHORS NEWS README"
+	G2CONF="${G2CONF}
+		--disable-static
+		--without-gnome
+		--with-apache-module-dir="${T}"
+		$(use_enable introspection)
+		$(use_enable ssl)"
+}
+
+src_configure() {
+	# FIXME: we need addpredict to workaround bug #324779 until
+	# root cause (bug #249496) is solved
+	addpredict /usr/share/snmp/mibs/.index
+	gnome2_src_configure
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	if ! use test; then
+		# don't waste time building tests (bug #226271)
+		sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
+			|| die "sed failed"
+	fi
+
+	# Patch *must* be applied conditionally (see patch for details)
+	if use doc; then
+		# Fix bug 268592 (upstream #573685) (build fails without gnome && doc)
+		epatch "${FILESDIR}/${PN}-2.30.1-fix-build-without-gnome-with-doc.patch"
+		eautoreconf
+	fi
+}