dev-libs/libpcre: import 8.12 version from main tree.

dev-libs/libpcre/libpcre-8.12.ebuild

+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpcre/libpcre-8.12.ebuild,v 1.6 2011/04/05 05:16:42 maekke Exp $
+
+EAPI=2
+
+inherit libtool eutils toolchain-funcs
+
+DESCRIPTION="Perl-compatible regular expression library"
+HOMEPAGE="http://www.pcre.org/"
+if [[ ${PV} == ${PV/_rc} ]]
+then
+        MY_P="pcre-${PV}"
+        # Only the final releases are available here.
+        SRC_URI="mirror://sourceforge/pcre/${MY_P}.tar.bz2
+                ftp://ftp.csx.cam.ac.uk/pub/software/programming/pcre/${MY_P}.tar.bz2"
+else
+        MY_P="pcre-${PV/_rc/-RC}"
+        SRC_URI="ftp://ftp.csx.cam.ac.uk/pub/software/programming/pcre/Testing/${MY_P}.tar.bz2"
+fi
+LICENSE="BSD"
+SLOT="3"
+KEYWORDS="~alpha amd64 arm hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh ~sparc x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="bzip2 +cxx unicode zlib static-libs +recursion-limit"
+
+RDEPEND="bzip2? ( app-arch/bzip2 )
+        zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+        dev-util/pkgconfig
+        userland_GNU? ( >=sys-apps/findutils-4.4.0 )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+        sed -i -e "s:-lpcre ::" libpcrecpp.pc.in || die "Fixing libpcrecpp pkgconfig files failed"
+        elibtoolize
+}
+
+src_configure() {
+        econf --with-match-limit-recursion=$(use recursion-limit && echo 8192 || echo MATCH_LIMIT) \
+                $(use_enable unicode utf8) $(use_enable unicode unicode-properties) \
+                $(use_enable cxx cpp) \
+                $(use_enable zlib pcregrep-libz) \
+                $(use_enable bzip2 pcregrep-libbz2) \
+                $(use_enable static-libs static) \
+                --enable-shared \
+                --htmldir=/usr/share/doc/${PF}/html \
+                --docdir=/usr/share/doc/${PF} \
+                || die "econf failed"
+}
+
+src_install() {
+        emake DESTDIR="${D}" install || die "make install failed"
+        gen_usr_ldscript -a pcre
+        find "${D}" -type f -name '*.la' -exec rm -rf '{}' '+' || die "la removal failed"
+}