Add the xrender backend to the window manager.

SConstruct

 # Copyright (c) 2010 The Chromium OS Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import fnmatch
 import itertools
 import os
 
 import make_shaders
 
@@ skipping 21 matching lines @@
 # Unless we disable strict aliasing, we get warnings about some of the
 # program's command line flags processing code that look like:
 #   'dereferencing type-punned pointer will break strict-aliasing rules'
 base_env.Append(CCFLAGS=['-fno-strict-aliasing'])
 
 base_env.Append(CPPPATH=['..'])
 
 # We need glib-2.0 ONLY to satisfy libbase.
 # TODO(derat): Weep.
 base_env.Append(LIBS=Split('base gflags pthread rt'))
-base_env.ParseConfig('pkg-config --cflags --libs glib-2.0 x11')
+base_env.ParseConfig('pkg-config --cflags --libs glib-2.0 x11 xrender')

[Daniel Erat, 2011/04/02 14:54:36]

nit: this should be in wm_env below, not base_env (the screenshot program
doesn't need it)

 
 # Fork off a new environment, add Cairo to it, and build the screenshot
 # program.
 screenshot_env = base_env.Clone()
 screenshot_env.ParseConfig('pkg-config --cflags --libs cairo')
 screenshot_env.Program('screenshot', 'screenshot.cc')
 
 # Check for BACKEND on the build line
 backend = ARGUMENTS.get('BACKEND', 'OPENGL').lower()
 
@@ skipping 74 matching lines @@
   srcs.append(Split('''\
     compositor/gles/opengles_visitor.cc
     compositor/gles/real_gles2_interface.cc
     compositor/gles/shader_base.cc
     compositor/gles/shaders.cc
   '''))
   # SCons doesn't figure out this dependency on its own, since
   # opengles_visitor.cc includes "window_manager/compositor/gles/shaders.h", 
   # while the shaders builder just provides "compositor/gles/shaders.h".
   Depends('compositor/gles/opengles_visitor.o', 'compositor/gles/shaders.h')
+elif backend == 'xrender':
+  srcs.append(Split('''\
+    compositor/xrender/xrender_visitor.cc
+  '''))
 
 libwm_core = wm_env.Library('wm_core', srcs)
 
 # Define a library to be used by tests.
 srcs = Split('''\
   compositor/gl/mock_gl_interface.cc
   compositor/mock_compositor.cc
   mock_dbus_interface.cc
   test_lib.cc
   x11/mock_x_connection.cc
 ''')
 libtest = wm_env.Library('test', Split(srcs))
 
 wm_env.Prepend(LIBS=[libwm_core, libwm_ipc])
 
 backend_defines = {'opengl': ['COMPOSITOR_OPENGL'],
-                   'opengles': ['COMPOSITOR_OPENGLES']}
+                   'opengles': ['COMPOSITOR_OPENGLES'],
+                   'xrender': ['COMPOSITOR_XRENDER']}
 wm_env.Append(CPPDEFINES=backend_defines[backend])
 
 test_env = wm_env.Clone()
 
 wm_env.Program('wm', 'main.cc')
 
 test_env.Append(LIBS=['gtest'])
 # libtest needs to be listed first since it depends on wm_core and wm_ipc.
 test_env.Prepend(LIBS=[libtest])
 tests = []
 
 # These are tests that only get built when we use particular backends.
 backend_tests = {'opengl': ['real_compositor_test.cc',
                             'opengl_visitor_test.cc'],
-                 'opengles': []}
+                 'opengles': [],
+                 'xrender': []}
 all_backend_tests = set(itertools.chain(*backend_tests.values()))
 for root, dirnames, filenames in os.walk('.'):
   for filename in fnmatch.filter(filenames, '*_test.cc'):
     if filename in all_backend_tests and filename not in backend_tests[backend]:
       continue
     tests += test_env.Program(os.path.join(root, filename))
 
 # Create a 'tests' target that will build all tests.
 test_env.Alias('tests', tests)
 
 # mock_chrome is just a small program that developers can use to test
 # interaction between the window manager and Chrome.  We only define a
 # target for it if gtkmm is installed so that this SConstruct file can
 # still be parsed in the chroot build environment, which shouldn't contain
 # gtkmm.
 if os.system('pkg-config --exists gtkmm-2.4') == 0:
   mock_chrome_env = wm_env.Clone()
   mock_chrome_env.ParseConfig('pkg-config --cflags --libs gtkmm-2.4')
   mock_chrome_env.Program('mock_chrome', 'mock_chrome.cc')