Getting service process on Mac to handle having things moved/changed underneath it.

base/file_util_mac.mm

 // Copyright (c) 2010 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "base/file_util.h"
 
+#include <CoreServices/CoreServices.h>
 #import <Foundation/Foundation.h>
 #include <copyfile.h>
 
 #include "base/basictypes.h"
 #include "base/file_path.h"
+#include "base/logging.h"
+#include "base/mac/mac_util.h"
 #include "base/string_util.h"
 #include "base/threading/thread_restrictions.h"
 
 namespace file_util {
 
 bool GetTempDir(FilePath* path) {
   NSString* tmp = NSTemporaryDirectory();
   if (tmp == nil)
     return false;
   *path = FilePath([tmp fileSystemRepresentation]);
   return true;
 }
 
 bool GetShmemTempDir(FilePath* path) {
   return GetTempDir(path);
 }
 
 bool CopyFile(const FilePath& from_path, const FilePath& to_path) {
   base::ThreadRestrictions::AssertIOAllowed();
   return (copyfile(from_path.value().c_str(),
                    to_path.value().c_str(), NULL, COPYFILE_ALL) == 0);
 }
 
+bool IsInTrash(const FilePath& path) {
+  FSRef ref;
+  if (!base::mac::FSRefFromPath(path.value(), &ref)) {
+    LOG(ERROR) << "Unable to get FSRef for " << path.value();
+    return false;
+  }
+  Boolean result = false;
+  OSStatus err = FSDetermineIfRefIsEnclosedByFolder(
+      kOnAppropriateDisk, kTrashFolderType, &ref, &result);
+  // See http://lists.apple.com/archives/filesystem-dev/2009/Sep/msg00008.html
+  // for why this is required.
+  return err == noErr && result;
+}
+
+bool MoveToTrash(const FilePath& path, FilePath* new_path) {
+  FSRef path_ref;
+  FSRef new_path_ref;
+  if (!base::mac::FSRefFromPath(path.value(), &path_ref)) {
+    LOG(ERROR) << "Unable to get FSREf for " << path.value();
+    return false;
+  }
+  OSStatus status = FSMoveObjectToTrashSync(&path_ref, &new_path_ref,
+                                            kFSFileOperationDefaultOptions);
+  if (status != noErr) {
+    LOG(ERROR) << "MoveToTrash " << status;
+    return false;
+  }
+  if (new_path) {
+    *new_path = FilePath(base::mac::PathFromFSRef(new_path_ref));
+  }
+  return true;
+}
+
 }  // namespace