[Mac] Create CrTrackingArea and use it in TabStripController.

chrome/browser/ui/cocoa/tracking_area.mm

+// Copyright (c) 2011 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "chrome/browser/ui/cocoa/tracking_area.h"
+
+#include "base/logging.h"
+
+// NSTrackingArea does not retain its |owner| so CrTrackingArea wraps the real
+// owner in this proxy, which can stop forwarding messages to the owner when
+// it is no longer |alive_|.
+@interface CrTrackingAreaOwnerProxy : NSProxy {

[Scott Hess - ex-Googler, 2011/02/14 19:25:38]

I'm a tiny bit nervous about using NSProxy.  I think you're doing it right, but
it's not common in Chromium code, and the informal protocol we're supporting is
so small that a manual proxy would be pretty easy to implement, and probably no
more code than the NSProxy version.

I think implementing -[CrTrackingAreaOwnerProxy mouseMoved:] is possible with
your design, right?  That's the main case I imagine wanting to override to do
something interesting for debugging.

[Robert Sesek, 2011/02/14 20:46:35]

At this point, with the three dynamic messaging methods overridden, there's no
material difference between using NSObject and NSProxy. Since you're a little
nervous about NSProxy, I've switched it over to be an NSObject subclass.
Yes, this would be possible regardless of the superclass.

+ @private
+  // Whether or not the owner is "alive" and should forward calls to the real
+  // owner object.
+  BOOL alive_;
+
+  // The real object for which this is a proxy. Weak.
+  id owner_;
+
+  // The Class of |owner_|. When the actual object is no longer alive (and could
+  // be zombie), this allows for introspection.
+  Class ownerClass_;
+}
+
+@property(nonatomic, assign) BOOL alive;
+@property(nonatomic, assign) id owner;
+
+- (id)initWithOwner:(id)owner;
+
+@end
+
+@implementation CrTrackingAreaOwnerProxy
+
+@synthesize alive = alive_;
+@synthesize owner = owner_;
+
+- (id)initWithOwner:(id)owner {
+  alive_ = YES;
+  owner_ = owner;
+  ownerClass_ = [owner class];
+  return self;
+}
+
+- (void)forwardInvocation:(NSInvocation*)invocation {
+  if (!alive_)
+    return;
+  [invocation invokeWithTarget:owner_];
+}
+
+- (NSMethodSignature*)methodSignatureForSelector:(SEL)sel {
+  // This can be called if |owner_| is not |alive_|, so use the Class to
+  // generate the signature. |-forwardInvocation:| will block the actual call.
+  return [ownerClass_ instanceMethodSignatureForSelector:sel];
+}
+
+- (BOOL)respondsToSelector:(SEL)aSelector {
+  return YES;

[Scott Hess - ex-Googler, 2011/02/14 19:25:38]

Seems like [ownerClass_ instancesRespondToSelector:aSelector] would be better,
just in case.

[Robert Sesek, 2011/02/14 20:46:35]

Do'h. I was looking for that method but couldn't find it (I thought it was
instanceResponds...). Done.

+}
+
+@end
+
+// Private Interface ///////////////////////////////////////////////////////////
+
+@interface CrTrackingArea (Private)
+- (void)windowWillClose:(NSNotification*)notif;
+@end
+
+////////////////////////////////////////////////////////////////////////////////
+
+@implementation CrTrackingArea
+
+- (id)initWithRect:(NSRect)rect
+           options:(NSTrackingAreaOptions)options
+             owner:(id)owner
+          userInfo:(NSDictionary*)userInfo {
+  ownerProxy_.reset([[CrTrackingAreaOwnerProxy alloc] initWithOwner:owner]);

[Scott Hess - ex-Googler, 2011/02/14 19:25:38]

You can get away with this, but I don't think you should try.  Put a local
scoped_nsobject<> out here, and initialize ownerProxy_ if the super init
succeeds.

[Robert Sesek, 2011/02/14 20:46:35]

Done.

+  if ((self = static_cast<id>([super initWithRect:rect
+                                          options:options
+                                            owner:ownerProxy_.get()
+                                         userInfo:userInfo]))) {
+  }
+  return self;
+}
+
+- (void)dealloc {
+  [[NSNotificationCenter defaultCenter] removeObserver:self];
+  [super dealloc];
+}
+
+- (void)clearOwner {
+  [ownerProxy_ setAlive:NO];
+}
+
+- (void)clearOwnerWhenWindowWillClose:(NSWindow*)window {
+  DCHECK(window);
+  NSNotificationCenter* center = [NSNotificationCenter defaultCenter];
+  [center addObserver:self
+             selector:@selector(windowWillClose:)
+                 name:NSWindowWillCloseNotification
+               object:window];
+}
+
+- (void)windowWillClose:(NSNotification*)notif {
+  [self clearOwner];
+}
+
+@end