Mac: make favicon and title visible during in/out animation.

chrome/browser/ui/cocoa/tabpose_window.mm

 // Copyright (c) 2010 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/tabpose_window.h"
 
 #import <QuartzCore/QuartzCore.h>
 
 #include "app/resource_bundle.h"
 #include "base/mac_util.h"
@@ skipping 357 matching lines @@
 class Tile {
  public:
   Tile() {}
 
   // Returns the rectangle this thumbnail is at at the beginning of the zoom-in
   // animation. |tile| is the rectangle that's covering the whole tab area when
   // the animation starts.
   NSRect GetStartRectRelativeTo(const Tile& tile) const;
   NSRect thumb_rect() const { return thumb_rect_; }
 
+  NSRect GetFaviconStartRectRelativeTo(const Tile& tile) const;
   NSRect favicon_rect() const { return favicon_rect_; }
   SkBitmap favicon() const;
 
   // This changes |title_rect| and |favicon_rect| such that the favicon is on
   // the font's baseline and that the minimum distance between thumb rect and
   // favicon and title rects doesn't change.
   // The view code
   // 1. queries desired font size by calling |title_font_size()|
   // 2. loads that font
   // 3. calls |set_font_metrics()| which updates the title rect
   // 4. receives the title rect and puts the title on it with the font from 2.
   void set_font_metrics(CGFloat ascender, CGFloat descender);
   CGFloat title_font_size() const { return title_font_size_; }
 
+  NSRect GetTitleStartRectRelativeTo(const Tile& tile) const;
   NSRect title_rect() const { return title_rect_; }
 
   // Returns an unelided title. The view logic is responsible for eliding.
   const string16& title() const { return contents_->GetTitle(); }
 
   TabContents* tab_contents() const { return contents_; }
   void set_tab_contents(TabContents* new_contents) { contents_ = new_contents; }
 
  private:
   friend class TileSet;
@@ skipping 13 matching lines @@
   DISALLOW_COPY_AND_ASSIGN(Tile);
 };
 
 NSRect Tile::GetStartRectRelativeTo(const Tile& tile) const {
   NSRect rect = start_thumb_rect_;
   rect.origin.x -= tile.start_thumb_rect_.origin.x;
   rect.origin.y -= tile.start_thumb_rect_.origin.y;
   return rect;
 }
 
+NSRect Tile::GetFaviconStartRectRelativeTo(const Tile& tile) const {
+  NSRect thumb_start = GetStartRectRelativeTo(tile);
+  NSRect rect = favicon_rect_;
+  rect.origin.x += NSMinX(thumb_start) - NSMinX(thumb_rect_);
+  rect.origin.y += NSMinY(thumb_start) - NSMinY(thumb_rect_);
+  return rect;
+}
+
 SkBitmap Tile::favicon() const {
   if (contents_->is_app()) {
     SkBitmap* icon = contents_->GetExtensionAppIcon();
     if (icon)
       return *icon;
   }
   return contents_->GetFavIcon();
 }
 
+NSRect Tile::GetTitleStartRectRelativeTo(const Tile& tile) const {
+  NSRect thumb_start = GetStartRectRelativeTo(tile);
+  NSRect rect = title_rect_;
+  rect.origin.x += NSMinX(thumb_start) - NSMinX(thumb_rect_);
+  rect.origin.y += NSMinY(thumb_start) - NSMinY(thumb_rect_);
+  return rect;
+}
+
 // Changes |title_rect| and |favicon_rect| such that the favicon is on the
 // font's baseline and that the minimum distance between thumb rect and
 // favicon and title rects doesn't change.
 void Tile::set_font_metrics(CGFloat ascender, CGFloat descender) {
   title_rect_.origin.y -= ascender + descender - NSHeight(title_rect_);
   title_rect_.size.height = ascender + descender;
 
   if (NSHeight(favicon_rect_) < ascender) {
     // Move favicon down.
     favicon_rect_.origin.y = title_rect_.origin.y + descender;
@@ skipping 393 matching lines @@
       [CAMediaTimingFunction functionWithName:kCAMediaTimingFunctionEaseOut];
 
   // Update the layer's position so that the layer doesn't snap back when the
   // animation completes.
   layer.position = NSPointToCGPoint(point);
 
   // Add the animation, overriding the implicit animation.
   [layer addAnimation:animation forKey:@"position"];
 }
 
+void AnimateCALayerOpacityFromTo(
+    CALayer* layer, double from, double to, NSTimeInterval duration) {
+  CABasicAnimation* animation;
+  animation = [CABasicAnimation animationWithKeyPath:@"opacity"];
+  animation.fromValue = [NSNumber numberWithFloat:from];
+  animation.toValue = [NSNumber numberWithFloat:to];
+  animation.duration = duration;
+
+  layer.opacity = to;
+  // Add the animation, overriding the implicit animation.
+  [layer addAnimation:animation forKey:@"opacity"];
+}
+
 @interface TabposeWindow (Private)
 - (id)initForWindow:(NSWindow*)parent
                rect:(NSRect)rect
               slomo:(BOOL)slomo
       tabStripModel:(TabStripModel*)tabStripModel;
 - (void)setUpLayersInSlomo:(BOOL)slomo;
 - (void)fadeAway:(BOOL)slomo;
 - (void)selectTileAtIndex:(int)newIndex;
 @end
 
@@ skipping 53 matching lines @@
 - (void)addLayersForTile:(tabpose::Tile&)tile
                 showZoom:(BOOL)showZoom
                    slomo:(BOOL)slomo
        animationDelegate:(id)animationDelegate {
   scoped_nsobject<CALayer> layer([[ThumbnailLayer alloc]
       initWithTabContents:tile.tab_contents()
                  fullSize:tile.GetStartRectRelativeTo(
                      tileSet_->selected_tile()).size]);
   [layer setNeedsDisplay];
 
+  NSTimeInterval interval =
+      kDefaultAnimationDuration * (slomo ? kSlomoFactor : 1);
+
   // Background color as placeholder for now.
   layer.get().backgroundColor = CGColorGetConstantColor(kCGColorWhite);
   if (showZoom) {

[viettrungluu, 2010/12/09 19:09:30]

Can you make the three cases of |if (showZoom) { ...| share code?

[Nico, 2010/12/09 19:12:03]

I did, I extracted the common code to a function!

Kidding aside: What do you have in mind? Most of the parameters are different,
what would you share?

[viettrungluu, 2010/12/09 20:15:42]

I'd like an "AnimateOrSetFrame()" (or whatever) function. (You could even push
|interval| into this function, with |slomo| as a parameter.)

So, instead of these if-else blocks, you'd just have:
AnimateOrSetFrame(layer, showZoom, slomo, foo.GetStartRect..., foo.end_rect(),
delegate);
(or something like that).

Incidentally, why doesn't the first one get an opacity animation? (I suppose if
that's right, then whether or not the opacity should be animate should also be a
parameter.)

     AnimateCALayerFrameFromTo(
         layer,
         tile.GetStartRectRelativeTo(tileSet_->selected_tile()),
         tile.thumb_rect(),
-        kDefaultAnimationDuration * (slomo ? kSlomoFactor : 1),
+        interval,
         animationDelegate);
   } else {
     layer.get().frame = NSRectToCGRect(tile.thumb_rect());
   }
 
   layer.get().shadowRadius = 10;
   layer.get().shadowOffset = CGSizeMake(0, -10);
   if (state_ == tabpose::kFadedIn)
     layer.get().shadowOpacity = 0.5;
 
@@ skipping 10 matching lines @@
   if (!nsFavicon) {
     NSImage* defaultFavIcon =
         ResourceBundle::GetSharedInstance().GetNativeImageNamed(
             IDR_DEFAULT_FAVICON);
     nsFavicon = defaultFavIcon;
   }
   base::mac::ScopedCFTypeRef<CGImageRef> favicon(
       mac_util::CopyNSImageToCGImage(nsFavicon));
 
   CALayer* faviconLayer = [CALayer layer];
-  faviconLayer.frame = NSRectToCGRect(tile.favicon_rect());
+  if (showZoom) {
+    AnimateCALayerFrameFromTo(
+        faviconLayer,
+        tile.GetFaviconStartRectRelativeTo(tileSet_->selected_tile()),
+        tile.favicon_rect(),
+        interval,
+        nil);
+    AnimateCALayerOpacityFromTo(faviconLayer, 0.0, 1.0, interval);
+  } else {
+    faviconLayer.frame = NSRectToCGRect(tile.favicon_rect());
+  }
   faviconLayer.contents = (id)favicon.get();
   faviconLayer.zPosition = 1;  // On top of the thumb shadow.
-  if (state_ == tabpose::kFadingIn)
-    faviconLayer.hidden = YES;
   [bgLayer_ addSublayer:faviconLayer];
   [allFaviconLayers_ addObject:faviconLayer];
 
   CATextLayer* titleLayer = [CATextLayer layer];
-  titleLayer.frame = NSRectToCGRect(tile.title_rect());
+  if (showZoom) {
+    AnimateCALayerFrameFromTo(
+        titleLayer,
+        tile.GetTitleStartRectRelativeTo(tileSet_->selected_tile()),
+        tile.title_rect(),
+        interval,
+        nil);
+    AnimateCALayerOpacityFromTo(titleLayer, 0.0, 1.0, interval);
+  } else {
+    titleLayer.frame = NSRectToCGRect(tile.title_rect());
+  }
   titleLayer.string = base::SysUTF16ToNSString(tile.title());
   titleLayer.fontSize = [font pointSize];
   titleLayer.truncationMode = kCATruncationEnd;
   titleLayer.font = font;
   titleLayer.zPosition = 1;  // On top of the thumb shadow.
-  if (state_ == tabpose::kFadingIn)
-    titleLayer.hidden = YES;
   [bgLayer_ addSublayer:titleLayer];
   [allTitleLayers_ addObject:titleLayer];
 }
 
 - (void)setUpLayersInSlomo:(BOOL)slomo {
   // Root layer -- covers whole window.
   rootLayer_ = [CALayer layer];
 
   // In a block so that the layers don't fade in.
   {
@@ skipping 209 matching lines @@
     DCHECK_EQ(tileSet_->selected_index(), 0);
   }
 
   {
     ScopedCAActionDisabler disableCAActions;
 
     // Move the selected layer on top of all other layers.
     [self selectedLayer].zPosition = 1;
 
     selectionHighlight_.hidden = YES;
-    for (CALayer* layer in allFaviconLayers_.get())
-      layer.hidden = YES;
-    for (CALayer* layer in allTitleLayers_.get())
-      layer.hidden = YES;
-
     // Running animations with shadows is slow, so turn shadows off before
     // running the exit animation.
     for (CALayer* layer in allThumbnailLayers_.get())
       layer.shadowOpacity = 0.0;
   }
 
   // Animate layers out, all in one transaction.
   CGFloat duration =
       1.3 * kDefaultAnimationDuration * (slomo ? kSlomoFactor : 1);
   ScopedCAActionSetDuration durationSetter(duration);
-  for (NSUInteger i = 0; i < [allThumbnailLayers_ count]; ++i) {
+  for (int i = 0; i < tabStripModel_->count(); ++i) {
+    const tabpose::Tile& tile = tileSet_->tile_at(i);
     CALayer* layer = [allThumbnailLayers_ objectAtIndex:i];
-    // |start_thumb_rect_| was relative to the initial index, now this needs to
-    // be relative to |selectedIndex_| (whose start rect was relative to
-    // the initial index, too).
-    CGRect newFrame = NSRectToCGRect(
-        tileSet_->tile_at(i).GetStartRectRelativeTo(tileSet_->selected_tile()));
-
     // Add a delegate to one of the implicit animations to get a notification
     // once the animations are done.
     if (static_cast<int>(i) == tileSet_->selected_index()) {
       CAAnimation* animation = [CAAnimation animation];
       animation.delegate = self;
       [animation setValue:kAnimationIdFadeOut forKey:kAnimationIdKey];
       [layer addAnimation:animation forKey:@"frame"];
     }
 
-    layer.frame = newFrame;
+    layer.frame = NSRectToCGRect(
+        tile.GetStartRectRelativeTo(tileSet_->selected_tile()));
 
     if (static_cast<int>(i) == tileSet_->selected_index()) {
       // Redraw layer at big resolution, so that zoom-in isn't blocky.
       [layer setNeedsDisplay];
     }
+
+    CALayer* faviconLayer = [allFaviconLayers_ objectAtIndex:i];
+    faviconLayer.frame = NSRectToCGRect(
+        tile.GetFaviconStartRectRelativeTo(tileSet_->selected_tile()));
+    faviconLayer.opacity = 0;
+    CALayer* titleLayer = [allTitleLayers_ objectAtIndex:i];
+    titleLayer.frame = NSRectToCGRect(
+        tile.GetTitleStartRectRelativeTo(tileSet_->selected_tile()));
+    titleLayer.opacity = 0;
   }
 }
 
 - (void)animationDidStop:(CAAnimation*)animation finished:(BOOL)finished {
   NSString* animationId = [animation valueForKey:kAnimationIdKey];
   if ([animationId isEqualToString:kAnimationIdFadeIn]) {
     if (finished && state_ == tabpose::kFadingIn) {
       // If the user clicks while the fade in animation is still running,
       // |state_| is already kFadingOut. In that case, don't do anything.
       state_ = tabpose::kFadedIn;
 
       selectionHighlight_.hidden = NO;
-      for (CALayer* layer in allFaviconLayers_.get())
-        layer.hidden = NO;
-      for (CALayer* layer in allTitleLayers_.get())
-        layer.hidden = NO;
 
       // Running animations with shadows is slow, so turn shadows on only after
       // the animation is done.
       ScopedCAActionDisabler disableCAActions;
       for (CALayer* layer in allThumbnailLayers_.get())
         layer.shadowOpacity = 0.5;
     }
   } else if ([animationId isEqualToString:kAnimationIdFadeOut]) {
     DCHECK_EQ(tabpose::kFadingOut, state_);
     [self close];
@@ skipping 159 matching lines @@
   tile.set_tab_contents(contents->tab_contents());
   ThumbnailLayer* thumbLayer = [allThumbnailLayers_ objectAtIndex:index];
   [thumbLayer setTabContents:contents->tab_contents()];
 }
 
 - (void)tabStripModelDeleted {
   [self close];
 }
 
 @end