[Mac] Add a confirm to quit experiment to about:flags.

chrome/browser/app_controller_mac.mm

 // Copyright (c) 2010 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/app_controller_mac.h"
 
 #include "app/l10n_util.h"
 #include "app/l10n_util_mac.h"
 #include "base/auto_reset.h"
 #include "base/command_line.h"
 #include "base/file_path.h"
 #include "base/mac_util.h"
 #include "base/message_loop.h"
 #include "base/string_number_conversions.h"
 #include "base/sys_string_conversions.h"
 #include "chrome/app/chrome_dll_resource.h"
 #include "chrome/browser/browser.h"
 #include "chrome/browser/browser_init.h"
 #include "chrome/browser/browser_list.h"
 #include "chrome/browser/browser_process.h"
 #include "chrome/browser/browser_shutdown.h"
 #include "chrome/browser/browser_thread.h"
 #include "chrome/browser/browser_window.h"
 #import "chrome/browser/cocoa/about_window_controller.h"
 #import "chrome/browser/cocoa/bookmarks/bookmark_menu_bridge.h"
 #import "chrome/browser/cocoa/browser_window_cocoa.h"
 #import "chrome/browser/cocoa/browser_window_controller.h"
 #import "chrome/browser/cocoa/bug_report_window_controller.h"
 #import "chrome/browser/cocoa/clear_browsing_data_controller.h"
+#import "chrome/browser/cocoa/confirm_quit_panel_controller.h"
 #import "chrome/browser/cocoa/encoding_menu_controller_delegate_mac.h"
 #import "chrome/browser/cocoa/history_menu_bridge.h"
 #import "chrome/browser/cocoa/import_settings_dialog.h"
 #import "chrome/browser/cocoa/preferences_window_controller.h"
 #import "chrome/browser/cocoa/tab_strip_controller.h"
 #import "chrome/browser/cocoa/tab_window_controller.h"
 #include "chrome/browser/cocoa/task_manager_mac.h"
 #include "chrome/browser/command_updater.h"
 #include "chrome/browser/download/download_manager.h"
 #include "chrome/browser/metrics/user_metrics.h"
@@ skipping 195 matching lines @@
   // shutting down, else the user might be prompted multiple times if the
   // download isn't stopped before terminate is called again.
   if (!browser_shutdown::IsTryingToQuit() &&
       ![self shouldQuitWithInProgressDownloads])
     return NO;
 
   // TODO(viettrungluu): Remove Apple Event handlers here? (It's safe to leave
   // them in, but I'm not sure about UX; we'd also want to disable other things
   // though.) http://crbug.com/40861
 
+  // Check if the user really wants to quit by employing the confirm-to-quit
+  // mechanism.
+  if (!browser_shutdown::IsTryingToQuit() &&
+      [self applicationShouldTerminate:app] != NSTerminateNow)
+    return NO;
+
   size_t num_browsers = BrowserList::size();
 
   // Give any print jobs in progress time to finish.
   if (!browser_shutdown::IsTryingToQuit())
     g_browser_process->print_job_manager()->StopJobs(true);
 
   // Initiate a shutdown (via BrowserList::CloseAllBrowsers()) if we aren't
   // already shutting down.
   if (!browser_shutdown::IsTryingToQuit())
     BrowserList::CloseAllBrowsers();
 
   return num_browsers == 0 ? YES : NO;
 }
 
 - (void)stopTryingToTerminateApplication:(NSApplication*)app {
   if (browser_shutdown::IsTryingToQuit()) {
     // Reset the "trying to quit" state, so that closing all browser windows
     // will no longer lead to termination.
     browser_shutdown::SetTryingToQuit(false);
 
     // TODO(viettrungluu): Were we to remove Apple Event handlers above, we
     // would have to reinstall them here. http://crbug.com/40861
   }
 }
 
+- (NSApplicationTerminateReply)applicationShouldTerminate:(NSApplication*)app {
+  // Check if the experiment is enabled.

[viettrungluu, 2010/11/02 17:28:13]

Probably you should say which experiment.

+  const CommandLine* commandLine(CommandLine::ForCurrentProcess());
+  if (!commandLine->HasSwitch(switches::kEnableConfirmToQuit))
+    return NSTerminateNow;
+
+  // If the application is going to terminate as the result of a Cmd+Q
+  // invocation, use the special sauce to prevent accidental quitting.
+  // http://dev.chromium.org/developers/design-documents/confirm-to-quit-experiment
+  NSEvent* currentEvent = [app currentEvent];
+  if ([currentEvent type] == NSKeyDown) {
+    ConfirmQuitPanelController* quitPanel =
+        [[ConfirmQuitPanelController alloc] init];  // Releases self.
+    // Show the info panel that explains what the user must to do confirm quit.
+    [quitPanel showWindow:self];
+
+    // How long the user must hold down Cmd+Q to confirm the quit.
+    const NSTimeInterval kTimeToConfirmQuit = 1.5;
+    // Leeway between the |targetDate| and the current time that will confirm a
+    // quit.
+    const NSTimeInterval kTimeDeltaFuzzFactor = 1.0;
+    // Duration of the window fade out animation.
+    const NSTimeInterval kWindowFadeAnimationDuration = 0.2;
+
+    // Spin a nested run loop until the |targetDate| is reached or a KeyUp event
+    // is sent.
+    NSDate* targetDate =
+        [NSDate dateWithTimeIntervalSinceNow:kTimeToConfirmQuit];
+    BOOL willQuit = NO;
+    NSEvent* nextEvent = nil;
+    do {

[viettrungluu, 2010/11/02 17:28:13]

Generically, I'm kind of scared of this, though I think it should be okay
(nested loops in event tracking mode are all over the place). To reassure me,
could you check that nothing bad happens if, e.g., Javascript opens a new
window, or pops up a modal alert, or an extension closes a window? (Can any of
those things happen?)

[Robert Sesek, 2010/11/02 20:05:58]

Open new window: OK
Extension close window: OK
JS modal alert: bad

I'll need to dig more how to make JS modal alerts not bork it, but considering
this is behind a flag, I'm OK with shipping this and figuring out that edge case
later. We may never even ship this, too. But if we do, all platforms will face
this issue and we should figure out a good way to handle it across all of them.

+      // Dequeue events until a key up is received.
+      nextEvent = [app nextEventMatchingMask:NSKeyUpMask
+                                   untilDate:nil
+                                      inMode:NSEventTrackingRunLoopMode
+                                     dequeue:YES];
+
+      // Wait for the time expiry to happen. Once past the hold threshold,
+      // commit to quitting and hide all the open windows.
+      if (!willQuit) {
+        NSDate* now = [NSDate date];
+        NSTimeInterval difference = [targetDate timeIntervalSinceDate:now];
+        if (difference < kTimeDeltaFuzzFactor) {
+          willQuit = YES;
+
+          // At this point, the quit has been confirmed and windows should all
+          // fade out to convince the user to release the key combo to finalize
+          // the quit.
+          [NSAnimationContext beginGrouping];
+          [[NSAnimationContext currentContext] setDuration:
+              kWindowFadeAnimationDuration];
+          for (NSWindow* aWindow in [app windows]) {
+            // Windows that are set to animate and have a delegate do not
+            // expect to be animated by other things and could result in an
+            // invalid state. If a window is set up like so, just force the
+            // alpha value to 0. Otherwise, animate all pretty and stuff.
+            if (![[aWindow animationForKey:@"alphaValue"] delegate]) {
+              [[aWindow animator] setAlphaValue:0.0];
+            } else {
+              [aWindow setAlphaValue:0.0];
+            }
+          }
+          [NSAnimationContext endGrouping];
+        }
+      }
+    } while (!nextEvent);
+
+    // The user has released the key combo. Discard any events (i.e. the
+    // repeated KeyDown Cmd+Q).
+    [app discardEventsMatchingMask:NSAnyEventMask beforeEvent:nextEvent];
+    if (willQuit) {
+      // The user held down the combination long enough that quitting should
+      // happen.
+      return NSTerminateNow;
+    } else {
+      // Slowly fade the confirm window out in case the user doesn't
+      // understand what they have to do to quit.
+      [quitPanel dismissPanel];
+      return NSTerminateCancel;
+    }
+  }  // if event type is KeyDown
+
+  // Default case: terminate.
+  return NSTerminateNow;
+}
+
 // Called when the app is shutting down. Clean-up as appropriate.
 - (void)applicationWillTerminate:(NSNotification*)aNotification {
   NSAppleEventManager* em = [NSAppleEventManager sharedAppleEventManager];
   [em removeEventHandlerForEventClass:kInternetEventClass
                            andEventID:kAEGetURL];
   [em removeEventHandlerForEventClass:'WWW!'
                            andEventID:'OURL'];
 
   // There better be no browser windows left at this point.
   CHECK_EQ(BrowserList::size(), 0u);
@@ skipping 822 matching lines @@
   [appController showPreferencesWindow:nil page:page profile:profile];
 }
 
 namespace app_controller_mac {
 
 bool IsOpeningNewWindow() {
   return g_is_opening_new_window;
 }
 
 }  // namespace app_controller_mac