Move scoped_cftyperef from base to base/mac, use the new namespace, and name ...

base/mac_util.mm

 // Copyright (c) 2010 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "base/mac_util.h"
 
 #import <Cocoa/Cocoa.h>
 
 #include "base/file_path.h"
 #include "base/logging.h"
+#include "base/mac/scoped_cftyperef.h"
 #include "base/message_loop.h"
-#include "base/scoped_cftyperef.h"
 #include "base/scoped_nsobject.h"
 #include "base/sys_string_conversions.h"
 
+using base::mac::ScopedCFTypeRef;
+
 namespace {
 
 // a count of currently outstanding requests for full screen mode from browser
 // windows, plugins, etc.
 int g_full_screen_requests[mac_util::kNumFullScreenModes] = { 0, 0, 0};
 
 // Sets the appropriate SystemUIMode based on the current full screen requests.
 // Since only one SystemUIMode can be active at a given time, full screen
 // requests are ordered by priority.  If there are no outstanding full screen
 // requests, reverts to normal mode.  If the correct SystemUIMode is already
@@ skipping 45 matching lines @@
   BOOL result =
       [[parent_info objectForKey:@"FileCreator"] isEqualToString:@"lgnw"];
 
   return result == YES;
 }
 
 // Looks into Shared File Lists corresponding to Login Items for the item
 // representing the current application. If such an item is found, returns
 // retained reference to it. Caller is responsible for releasing the reference.
 LSSharedFileListItemRef GetLoginItemForApp() {
-  scoped_cftyperef<LSSharedFileListRef> login_items(LSSharedFileListCreate(
+  ScopedCFTypeRef<LSSharedFileListRef> login_items(LSSharedFileListCreate(
       NULL, kLSSharedFileListSessionLoginItems, NULL));
 
   if (!login_items.get()) {
     LOG(ERROR) << "Couldn't get a Login Items list.";
     return NULL;
   }
 
   scoped_nsobject<const NSArray> login_items_array(
       reinterpret_cast<const NSArray*>(
         LSSharedFileListCopySnapshot(login_items, NULL)));
 
   NSURL* url = [NSURL fileURLWithPath:[[NSBundle mainBundle] bundlePath]];
 
   for(NSUInteger i = 0; i < [login_items_array count]; ++i) {
     LSSharedFileListItemRef item = reinterpret_cast<LSSharedFileListItemRef>(
         [login_items_array objectAtIndex:i]);
     CFURLRef item_url_ref = NULL;
 
     if (LSSharedFileListItemResolve(item, 0, &item_url_ref, NULL) == noErr) {
-      scoped_cftyperef<CFURLRef> item_url(item_url_ref);
+      ScopedCFTypeRef<CFURLRef> item_url(item_url_ref);
       if (CFEqual(item_url, url)) {
         CFRetain(item);
         return item;
       }
     }
   }
 
   return NULL;
 }
 
 #if !defined(MAC_OS_X_VERSION_10_6) || \
     MAC_OS_X_VERSION_MAX_ALLOWED < MAC_OS_X_VERSION_10_6
 // kLSSharedFileListLoginItemHidden is supported on
 // 10.5, but missing from the 10.5 headers.
 // http://openradar.appspot.com/6482251
 static NSString* kLSSharedFileListLoginItemHidden =
     @"com.apple.loginitem.HideOnLaunch";
 #endif
 
 bool IsHiddenLoginItem(LSSharedFileListItemRef item) {
-  scoped_cftyperef<CFBooleanRef> hidden(reinterpret_cast<CFBooleanRef>(
+  ScopedCFTypeRef<CFBooleanRef> hidden(reinterpret_cast<CFBooleanRef>(
       LSSharedFileListItemCopyProperty(item,
           reinterpret_cast<CFStringRef>(kLSSharedFileListLoginItemHidden))));
 
   return hidden && hidden == kCFBooleanTrue;
 }
 
 }  // end namespace
 
 namespace mac_util {
 
 std::string PathFromFSRef(const FSRef& ref) {
-  scoped_cftyperef<CFURLRef> url(
+  ScopedCFTypeRef<CFURLRef> url(
       CFURLCreateFromFSRef(kCFAllocatorDefault, &ref));
   NSString *path_string = [(NSURL *)url.get() path];
   return [path_string fileSystemRepresentation];
 }
 
 bool FSRefFromPath(const std::string& path, FSRef* ref) {
   OSStatus status = FSPathMakeRef((const UInt8*)path.c_str(),
                                   ref, nil);
   return status == noErr;
 }
@@ skipping 303 matching lines @@
 }
 
 CFTypeRef GetValueFromDictionary(CFDictionaryRef dict,
                                  CFStringRef key,
                                  CFTypeID expected_type) {
   CFTypeRef value = CFDictionaryGetValue(dict, key);
   if (!value)
     return value;
 
   if (CFGetTypeID(value) != expected_type) {
-    scoped_cftyperef<CFStringRef> expected_type_ref(
+    ScopedCFTypeRef<CFStringRef> expected_type_ref(
         CFCopyTypeIDDescription(expected_type));
-    scoped_cftyperef<CFStringRef> actual_type_ref(
+    ScopedCFTypeRef<CFStringRef> actual_type_ref(
         CFCopyTypeIDDescription(CFGetTypeID(value)));
     LOG(WARNING) << "Expected value for key "
                  << base::SysCFStringRefToUTF8(key)
                  << " to be "
                  << base::SysCFStringRefToUTF8(expected_type_ref)
                  << " but it was "
                  << base::SysCFStringRefToUTF8(actual_type_ref)
                  << " instead";
     return NULL;
   }
@@ skipping 91 matching lines @@
 }
 
 // Converts a NSImage to a CGImageRef.  Normally, the system frameworks can do
 // this fine, especially on 10.6.  On 10.5, however, CGImage cannot handle
 // converting a PDF-backed NSImage into a CGImageRef.  This function will
 // rasterize the PDF into a bitmap CGImage.  The caller is responsible for
 // releasing the return value.
 CGImageRef CopyNSImageToCGImage(NSImage* image) {
   // This is based loosely on http://www.cocoadev.com/index.pl?CGImageRef .
   NSSize size = [image size];
-  scoped_cftyperef<CGContextRef> context(
+  ScopedCFTypeRef<CGContextRef> context(
       CGBitmapContextCreate(NULL,  // Allow CG to allocate memory.
                             size.width,
                             size.height,
                             8,  // bitsPerComponent
                             0,  // bytesPerRow - CG will calculate by default.
                             [[NSColorSpace genericRGBColorSpace] CGColorSpace],
                             kCGBitmapByteOrder32Host |
                                 kCGImageAlphaPremultipliedFirst));
   if (!context.get())
     return NULL;
 
   [NSGraphicsContext saveGraphicsState];
   [NSGraphicsContext setCurrentContext:
       [NSGraphicsContext graphicsContextWithGraphicsPort:context.get()
                                                  flipped:NO]];
   [image drawInRect:NSMakeRect(0,0, size.width, size.height)
            fromRect:NSZeroRect
           operation:NSCompositeCopy
            fraction:1.0];
   [NSGraphicsContext restoreGraphicsState];
 
   return CGBitmapContextCreateImage(context);
 }
 
 bool CheckLoginItemStatus(bool* is_hidden) {
-  scoped_cftyperef<LSSharedFileListItemRef> item(GetLoginItemForApp());
+  ScopedCFTypeRef<LSSharedFileListItemRef> item(GetLoginItemForApp());
   if (!item.get())
     return false;
 
   if (is_hidden)
     *is_hidden = IsHiddenLoginItem(item);
 
   return true;
 }
 
 void AddToLoginItems(bool hide_on_startup) {
-  scoped_cftyperef<LSSharedFileListItemRef> item(GetLoginItemForApp());
+  ScopedCFTypeRef<LSSharedFileListItemRef> item(GetLoginItemForApp());
   if (item.get() && (IsHiddenLoginItem(item) == hide_on_startup)) {
     return;  // Already is a login item with required hide flag.
   }
 
-  scoped_cftyperef<LSSharedFileListRef> login_items(LSSharedFileListCreate(
+  ScopedCFTypeRef<LSSharedFileListRef> login_items(LSSharedFileListCreate(
       NULL, kLSSharedFileListSessionLoginItems, NULL));
 
   if (!login_items.get()) {
     LOG(ERROR) << "Couldn't get a Login Items list.";
     return;
   }
 
   // Remove the old item, it has wrong hide flag, we'll create a new one.
   if (item.get()) {
     LSSharedFileListItemRemove(login_items, item);
   }
 
   NSURL* url = [NSURL fileURLWithPath:[[NSBundle mainBundle] bundlePath]];
 
   BOOL hide = hide_on_startup ? YES : NO;
   NSDictionary* properties =
       [NSDictionary
         dictionaryWithObject:[NSNumber numberWithBool:hide]
                       forKey:(NSString*)kLSSharedFileListLoginItemHidden];
 
-  scoped_cftyperef<LSSharedFileListItemRef> new_item;
+  ScopedCFTypeRef<LSSharedFileListItemRef> new_item;
   new_item.reset(LSSharedFileListInsertItemURL(
       login_items, kLSSharedFileListItemLast, NULL, NULL,
       reinterpret_cast<CFURLRef>(url),
       reinterpret_cast<CFDictionaryRef>(properties), NULL));
 
   if (!new_item.get()) {
     LOG(ERROR) << "Couldn't insert current app into Login Items list.";
   }
 }
 
 void RemoveFromLoginItems() {
-  scoped_cftyperef<LSSharedFileListItemRef> item(GetLoginItemForApp());
+  ScopedCFTypeRef<LSSharedFileListItemRef> item(GetLoginItemForApp());
   if (!item.get())
     return;
 
-  scoped_cftyperef<LSSharedFileListRef> login_items(LSSharedFileListCreate(
+  ScopedCFTypeRef<LSSharedFileListRef> login_items(LSSharedFileListCreate(
       NULL, kLSSharedFileListSessionLoginItems, NULL));
 
   if (!login_items.get()) {
     LOG(ERROR) << "Couldn't get a Login Items list.";
     return;
   }
 
   LSSharedFileListItemRemove(login_items, item);
 }
 
 bool WasLaunchedAsHiddenLoginItem() {
   if (!WasLaunchedAsLoginItem())
     return false;
 
-  scoped_cftyperef<LSSharedFileListItemRef> item(GetLoginItemForApp());
+  ScopedCFTypeRef<LSSharedFileListItemRef> item(GetLoginItemForApp());
   if (!item.get()) {
     LOG(ERROR) << "Process launched at Login but can't access Login Item List.";
     return false;
   }
   return IsHiddenLoginItem(item);
 }
 
 void NSObjectRetain(void* obj) {
   id<NSObject> nsobj = static_cast<id<NSObject> >(obj);
   [nsobj retain];
 }
 
 void NSObjectRelease(void* obj) {
   id<NSObject> nsobj = static_cast<id<NSObject> >(obj);
   [nsobj release];
 }
 
 }  // namespace mac_util