Mac: Fix concurrent access on a non-threadsafe data structure.

chrome/browser/renderer_host/render_widget_host_view_mac.mm

 // Copyright (c) 2010 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include <QuartzCore/QuartzCore.h>
 
 #include "chrome/browser/renderer_host/render_widget_host_view_mac.h"
 
 #include "chrome/browser/chrome_thread.h"
 #include "app/surface/io_surface_support_mac.h"
@@ skipping 138 matching lines @@
   scoped_nsobject<NSOpenGLContext> glContext_;
   CGLContextObj cglContext_;  // weak, backed by |glContext_|.
 
   CVDisplayLinkRef displayLink_;  // Owned by us.
 
   RenderWidgetHostViewMac* renderWidgetHostView_;  // weak
   gfx::PluginWindowHandle pluginHandle_;  // weak
 
   // True if the backing IO surface was updated since we last painted.
   BOOL surfaceWasSwapped_;
+
+  // Cocoa methods can only be called on the main thread, so have a copy of the
+  // view's size, since it's required on the displaylink thread.
+  NSSize cachedSize_;
 }
 
 - (id)initWithRenderWidgetHostViewMac:(RenderWidgetHostViewMac*)r
                          pluginHandle:(gfx::PluginWindowHandle)pluginHandle;
 - (void)drawView;
 
 // This _must_ be atomic, since it's accessed from several threads.
 @property BOOL surfaceWasSwapped;
+
+// This _must_ be atomic, since it's accessed from several threads.
+@property NSSize cachedSize;
 @end
 
 @implementation AcceleratedPluginView : NSView
 @synthesize surfaceWasSwapped = surfaceWasSwapped_;
+@synthesize cachedSize = cachedSize_;
 
 - (CVReturn)getFrameForTime:(const CVTimeStamp*)outputTime {
   // There is no autorelease pool when this method is called because it will be
   // called from a background thread.
   base::ScopedNSAutoreleasePool pool;
 
   if (![self surfaceWasSwapped])
     return kCVReturnSuccess;
 
   [self drawView];
@@ skipping 12 matching lines @@
   CVReturn result =
       [(AcceleratedPluginView*)displayLinkContext getFrameForTime:outputTime];
   return result;
 }
 
 - (id)initWithRenderWidgetHostViewMac:(RenderWidgetHostViewMac*)r
                          pluginHandle:(gfx::PluginWindowHandle)pluginHandle {
   if ((self = [super initWithFrame:NSZeroRect])) {
     renderWidgetHostView_ = r;
     pluginHandle_ = pluginHandle;
+    cachedSize_ = NSZeroSize;
 
     [self setAutoresizingMask:NSViewMaxXMargin|NSViewMinYMargin];
 
     NSOpenGLPixelFormatAttribute attributes[] =
         { NSOpenGLPFAAccelerated, NSOpenGLPFADoubleBuffer, 0};
 
     glPixelFormat_.reset([[NSOpenGLPixelFormat alloc]
         initWithAttributes:attributes]);
     glContext_.reset([[NSOpenGLContext alloc] initWithFormat:glPixelFormat_
                                                 shareContext:nil]);
@@ skipping 21 matching lines @@
         displayLink_, cglContext_, cglPixelFormat_);
     CVDisplayLinkStart(displayLink_);
   }
   return self;
 }
 
 - (void)drawView {
   // Called on a background thread. Synchronized via the CGL context lock.
   CGLLockContext(cglContext_);
 
+  // TODO(thakis): Pixel or view coordinates for size?
   renderWidgetHostView_->DrawAcceleratedSurfaceInstance(
-      cglContext_, pluginHandle_);
+      cglContext_, pluginHandle_, [self cachedSize]);
 
   CGLFlushDrawable(cglContext_);
   CGLUnlockContext(cglContext_);
 }
 
 - (void)drawRect:(NSRect)rect {
   if (!CommandLine::ForCurrentProcess()->HasSwitch(
       switches::kDisableHolePunching)) {
     const NSRect* dirtyRects;
     int dirtyRectCount;
@@ skipping 65 matching lines @@
   }
 
   if ([[self window] respondsToSelector:@selector(underlaySurfaceRemoved)]) {
     [static_cast<id>([self window]) underlaySurfaceRemoved];
   }
 
   if ([newWindow respondsToSelector:@selector(underlaySurfaceAdded)]) {
     [static_cast<id>(newWindow) underlaySurfaceAdded];
   }
 }
+
+- (void)setFrame:(NSRect)frameRect {
+  [self setCachedSize:frameRect.size];
+  [super setFrame:frameRect];
+}
+
+- (void)setFrameSize:(NSSize)newSize {
+  [self setCachedSize:newSize];
+  [super setFrameSize:newSize];
+}
 @end
 
 // RenderWidgetHostView --------------------------------------------------------
 
 // static
 RenderWidgetHostView* RenderWidgetHostView::CreateViewForWidget(
     RenderWidgetHost* widget) {
   return new RenderWidgetHostViewMac(widget);
 }
 
@@ skipping 572 matching lines @@
     if (plugin_views_.end() == it) {
       return;
     }
     bool visible =
         plugin_container_manager_.SurfaceShouldBeVisible(root_handle);
     [it->second setHidden:!visible];
   }
 }
 
 void RenderWidgetHostViewMac::DrawAcceleratedSurfaceInstance(
-      CGLContextObj context, gfx::PluginWindowHandle plugin_handle) {
+      CGLContextObj context,
+      gfx::PluginWindowHandle plugin_handle,
+      NSSize size) {
   // Called on the display link thread.
-  PluginViewMap::iterator it = plugin_views_.find(plugin_handle);
-  DCHECK(plugin_views_.end() != it);
-  if (plugin_views_.end() == it) {
-    return;
-  }
   CGLSetCurrentContext(context);
-  // TODO(thakis): Pixel or view coordinates?
-  NSSize size = [it->second frame].size;
 
   glMatrixMode(GL_PROJECTION);
   glLoadIdentity();
   // Note that we place the origin at the upper left corner with +y
   // going down
   glOrtho(0, size.width, size.height, 0, -1, 1);
   glMatrixMode(GL_MODELVIEW);
   glLoadIdentity();
 
   plugin_container_manager_.Draw(context, plugin_handle);
@@ skipping 555 matching lines @@
     gfx::Rect gpuRect;
 
     gfx::PluginWindowHandle root_handle =
        renderWidgetHostView_->plugin_container_manager_.root_container_handle();
     if (root_handle != gfx::kNullPluginWindow) {
       RenderWidgetHostViewMac::PluginViewMap::iterator it =
           renderWidgetHostView_->plugin_views_.find(root_handle);
       DCHECK(it != renderWidgetHostView_->plugin_views_.end());
       if (it != renderWidgetHostView_->plugin_views_.end() &&
           ![it->second isHidden]) {
-        gpuRect = [self flipNSRectToRect:[it->second frame]];
+        NSRect frame = [it->second frame];
+        frame.size = [it->second cachedSize];
+        gpuRect = [self flipNSRectToRect:frame];
       }
     }
 
     [self fillBottomRightRemainderOfRect:gpuRect dirtyRect:damagedRect];
     return;
   }
 
   DCHECK(
       renderWidgetHostView_->render_widget_host_->process()->HasConnection());
   DCHECK(!renderWidgetHostView_->about_to_validate_and_paint_);
@@ skipping 890 matching lines @@
   if (!string) return NO;
 
   // If the user is currently using an IME, confirm the IME input,
   // and then insert the text from the service, the same as TextEdit and Safari.
   [self confirmComposition];
   [self insertText:string];
   return YES;
 }
 
 @end