pkgconfig-0.25-r2 version bump

dev-util/pkgconfig/pkgconfig-0.25-r2.ebuild

+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/pkgconfig/pkgconfig-0.25-r2.ebuild,v 1.5 2010/08/10 16:01:02 jer Exp $
+
+EAPI=2
+inherit eutils flag-o-matic
+
+MY_P=pkg-config-${PV}
+
+DESCRIPTION="Package config system that manages compile/link flags"
+HOMEPAGE="http://pkgconfig.freedesktop.org/wiki/"
+SRC_URI="http://pkgconfig.freedesktop.org/releases/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="elibc_FreeBSD hardened"
+
+DEPEND=">=dev-libs/popt-1.15"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+        epatch "${FILESDIR}"/${P}-dnl.patch
+}
+
+src_configure() {
+        use ppc64 && use hardened && replace-flags -O[2-3] -O1
+
+        # Force using all the requirements when linking, so that needed -pthread
+        # lines are inherited between libraries
+        local myconf
+        use elibc_FreeBSD && myconf="--enable-indirect-deps"
+
+        econf \
+                --docdir=/usr/share/doc/${PF}/html \
+                --with-installed-popt \
+                ${myconf}
+}
+
+src_install() {
+        emake DESTDIR="${D}" install || die
+        dodoc AUTHORS ChangeLog NEWS README
+}