Chromium fix for "Copy Image"....

app/clipboard/clipboard_mac.mm

 // Copyright (c) 2006-2008 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "app/clipboard/clipboard.h"
 
 #import <Cocoa/Cocoa.h>
 
 #include "base/file_path.h"
+#include "base/gfx/size.h"
 #include "base/logging.h"
+#include "base/mac_util.h"
+#include "base/scoped_cftyperef.h"
+#include "base/scoped_nsobject.h"
 #include "base/string_util.h"
 #include "base/sys_string_conversions.h"
 
 namespace {
 
 // Would be nice if this were in UTCoreTypes.h, but it isn't
 const NSString* kUTTypeURLName = @"public.url-name";
 
 // Tells us if WebKit was the last to write to the pasteboard. There's no
 // actual data associated with this type.
@@ skipping 91 matching lines @@
       current_filename_offset = i + 1;
       continue;
     }
   }
 
   NSPasteboard* pb = GetPasteboard();
   [pb addTypes:[NSArray arrayWithObject:NSFilenamesPboardType] owner:nil];
   [pb setPropertyList:fileList forType:NSFilenamesPboardType];
 }
 
+void Clipboard::WriteBitmap(const char* pixel_data, const char* size_data) {
+  const gfx::Size* size = reinterpret_cast<const gfx::Size*>(size_data);
+
+  // Safe because the image goes away before the call returns.
+  scoped_cftyperef<CFDataRef> data(
+      CFDataCreateWithBytesNoCopy(kCFAllocatorDefault,
+                                  reinterpret_cast<const UInt8*>(pixel_data),
+                                  size->width()*size->height()*4,
+                                  kCFAllocatorNull));
+
+  scoped_cftyperef<CGDataProviderRef> data_provider(
+      CGDataProviderCreateWithCFData(data));
+
+  scoped_cftyperef<CGImageRef> cgimage(
+      CGImageCreate(size->width(),
+                    size->height(),
+                    8,
+                    32,
+                    size->width()*4,
+                    mac_util::GetSRGBColorSpace(),  // TODO(avi): do better
+                    kCGImageAlphaPremultipliedFirst | kCGBitmapByteOrder32Host,
+                    data_provider,
+                    NULL,
+                    false,
+                    kCGRenderingIntentDefault));
+
+  scoped_nsobject<NSBitmapImageRep> bitmap(
+      [[NSBitmapImageRep alloc] initWithCGImage:cgimage]);
+
+  scoped_nsobject<NSImage> image([[NSImage alloc] init]);
+  [image addRepresentation:bitmap];
+
+  // An API to ask the NSImage to write itself to the clipboard comes in 10.6 :(
+  // For now, spit out the image as a TIFF.
+  NSPasteboard* pb = GetPasteboard();
+  [pb addTypes:[NSArray arrayWithObject:NSTIFFPboardType] owner:nil];
+  [pb setData:[image TIFFRepresentation] forType:NSTIFFPboardType];
+}
+
 // Write an extra flavor that signifies WebKit was the last to modify the
 // pasteboard. This flavor has no data.
 void Clipboard::WriteWebSmartPaste() {
   NSPasteboard* pb = GetPasteboard();
   NSString* format = base::SysUTF8ToNSString(GetWebKitSmartPasteFormatType());
   [pb addTypes:[NSArray arrayWithObject:format] owner:nil];
   [pb setData:nil forType:format];
 }
 
 bool Clipboard::IsFormatAvailable(const Clipboard::FormatType& format,
@@ skipping 143 matching lines @@
   static const std::string type = base::SysNSStringToUTF8(NSHTMLPboardType);
   return type;
 }
 
 // static
 Clipboard::FormatType Clipboard::GetWebKitSmartPasteFormatType() {
   static const std::string type =
       base::SysNSStringToUTF8(kWebSmartPastePboardType);
   return type;
 }