Send keypress() events for ctrl-key and cmd-key in addition to keydown()

chrome/browser/renderer_host/render_widget_host_view_mac.mm

 // Copyright (c) 2006-2008 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/browser/renderer_host/render_widget_host_view_mac.h"
 
 #include "base/histogram.h"
 #import "base/scoped_nsobject.h"
 #include "base/string_util.h"
 #include "base/sys_string_conversions.h"
 #include "chrome/browser/browser_trial.h"
 #import "chrome/browser/cocoa/rwhvm_editcommand_helper.h"
 #include "chrome/browser/renderer_host/backing_store.h"
 #include "chrome/browser/renderer_host/render_process_host.h"
 #include "chrome/browser/renderer_host/render_widget_host.h"
 #include "chrome/browser/spellchecker_platform_engine.h"
 #include "chrome/common/native_web_keyboard_event.h"
 #include "chrome/common/edit_command.h"
 #include "chrome/common/render_messages.h"
 #include "skia/ext/platform_canvas.h"
 #include "webkit/api/public/mac/WebInputEventFactory.h"
 #include "webkit/api/public/WebInputEvent.h"
 #include "webkit/glue/webmenurunner_mac.h"
 
+using WebKit::WebInputEvent;
 using WebKit::WebInputEventFactory;
 using WebKit::WebMouseEvent;
 using WebKit::WebMouseWheelEvent;
 
+static inline int ToWebKitModifiers(NSUInteger flags) {

[pink (ping after 24hrs), 2009/11/11 15:46:16]

if this is a bitfield, should it be an unsigned int?

[Nico, 2009/11/12 00:11:16]

Technically yes, but the NativeWebKeyboardEvent constructor takes int, not
unsigned, so I feel the small gain of matching the constructor signature
outweighs the loss of this having potential problems in the future if someone
decides to add a bit flag for bit 32 _and_ right-shifts a number with this bit
set.

If you feel strongly, I'll change it.

+  int modifiers = 0;
+  if (flags & NSControlKeyMask) modifiers |= WebInputEvent::ControlKey;
+  if (flags & NSShiftKeyMask) modifiers |= WebInputEvent::ShiftKey;
+  if (flags & NSAlternateKeyMask) modifiers |= WebInputEvent::AltKey;
+  if (flags & NSCommandKeyMask) modifiers |= WebInputEvent::MetaKey;
+  return modifiers;
+}
+
 @interface RenderWidgetHostViewCocoa (Private)
 + (BOOL)shouldAutohideCursorForEvent:(NSEvent*)event;
 - (id)initWithRenderWidgetHostViewMac:(RenderWidgetHostViewMac*)r;
 - (void)keyEvent:(NSEvent *)theEvent wasKeyEquivalent:(BOOL)equiv;
 - (void)cancelChildPopups;
 @end
 
 namespace {
 
 // Maximum number of characters we allow in a tooltip.
@@ skipping 606 matching lines @@
   // To send an onkeydown() event before an onkeypress() event, we should
   // dispatch this NSKeyDown event AFTER sending it to the renderer.
   // (See <https://bugs.webkit.org/show_bug.cgi?id=25119>).
   //
   // If this object's retainCount is 1, the only reference is the one held by
   // keepSelfAlive.  All other references may have been destroyed in the
   // RenderWidgetHost::ForwardKeyboardEvent call above if it resulted in tab
   // closure.  Were it not for that single reference, this object would
   // already be deallocated.  In that case, there's no point in calling
   // -interpretKeyEvents:.
-  if ([self retainCount] > 1 && [theEvent type] == NSKeyDown)
+  if ([self retainCount] > 1 && [theEvent type] == NSKeyDown) {
     [self interpretKeyEvents:[NSArray arrayWithObject:theEvent]];
 
+    // We don't get insertText: calls if ctrl is down, so synthesize a keypress
+    // event for that case. Note that this makes our behavior deviate from the
+    // windows and linux versions of chrome (however, see http://crbug.com/13891
+    // ), but it makes us similar to how Safari behaves.

[pink (ping after 24hrs), 2009/11/11 15:46:16]

should you be specific about Mac Safari? Does Win Safari behave the same way?

[Nico, 2009/11/12 00:11:16]

Safari/win seems to be similar. At least for keys not used by browser shortcuts
or cocoa text shortcuts (weird that they are active on windows...), ctrl+key
sends both keydown and keypress.

+    if ([theEvent modifierFlags] & (NSControlKeyMask | NSCommandKeyMask) &&

[pink (ping after 24hrs), 2009/11/11 15:46:16]

the comment only mentions control, but this fires for command as well. Is that
intentional?

[Nico, 2009/11/12 00:11:16]

Updated the comment.

+        lastKeyPressedEvent_.get() != theEvent) {
+      NativeWebKeyboardEvent event([[theEvent characters] characterAtIndex:0],
+                                   ToWebKitModifiers([theEvent modifierFlags]),
+                                   base::Time::Now().ToDoubleT());
+      renderWidgetHostView_->render_widget_host_->ForwardKeyboardEvent(event);
+    }
+  }
+
   // Possibly autohide the cursor.
   if ([RenderWidgetHostViewCocoa shouldAutohideCursorForEvent:theEvent])
     [NSCursor setHiddenUntilMouseMoves:YES];
 }
 
 - (void)scrollWheel:(NSEvent *)theEvent {
   [self cancelChildPopups];
 
   const WebMouseWheelEvent& event =
       WebInputEventFactory::mouseWheelEvent(theEvent, self);
@@ skipping 609 matching lines @@
 
 - (void)doCommandBySelector:(SEL)selector {
   // An input method calls this function to dispatch an editing command to be
   // handled by this view.
   // Even though most editing commands has been already handled by the
   // RWHVMEditCommandHelper object, we need to handle an insertNewline: command
   // and send a '\r' character to WebKit so that WebKit dispatches this
   // character to onkeypress() event handlers.
   // TODO(hbono): need to handle more commands?
   if (selector == @selector(insertNewline:)) {
+    lastKeyPressedEvent_.reset([[NSApp currentEvent] retain]);
     NativeWebKeyboardEvent event('\r', renderWidgetHostView_->im_modifiers_,
                                  base::Time::Now().ToDoubleT());
     renderWidgetHostView_->render_widget_host_->ForwardKeyboardEvent(event);
   }
 }
 
 - (void)insertText:(id)string {
   // An input method has characters to be inserted.
   // Same as Linux, Mac calls this method not only:
   // * when an input method finishs composing text, but also;
   // * when we type an ASCII character (without using input methods).
   // When we aren't using input methods, we should send the given character as
   // a Char event so it is dispatched to an onkeypress() event handler of
   // JavaScript.
   // On the other hand, when we are using input methods, we should send the
   // given characters as an IME event and prevent the characters from being
   // dispatched to onkeypress() event handlers.
   BOOL isAttributedString = [string isKindOfClass:[NSAttributedString class]];
   NSString* im_text = isAttributedString ? [string string] : string;
   if (!renderWidgetHostView_->im_composing_ && [im_text length] == 1) {
+    lastKeyPressedEvent_.reset([[NSApp currentEvent] retain]);
     NativeWebKeyboardEvent event([im_text characterAtIndex:0],
                                  renderWidgetHostView_->im_modifiers_,
                                  base::Time::Now().ToDoubleT());
     renderWidgetHostView_->render_widget_host_->ForwardKeyboardEvent(event);
   } else {
     renderWidgetHostView_->render_widget_host_->ImeConfirmComposition(
         UTF8ToUTF16([im_text UTF8String]));
   }
   renderWidgetHostView_->im_composing_ = false;
 }
 
 @end