Add observers to ContentSettingsDialogController so that the dialog will show...

chrome/browser/cocoa/content_settings_dialog_controller.mm

 // Copyright (c) 2010 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/cocoa/content_settings_dialog_controller.h"
 
 #import <Cocoa/Cocoa.h>
 
 #include "app/l10n_util.h"
 #include "base/mac_util.h"
 #include "chrome/browser/browser.h"
 #include "chrome/browser/browser_window.h"
 #import "chrome/browser/cocoa/content_exceptions_window_controller.h"
 #import "chrome/browser/cocoa/cookies_window_controller.h"
 #import "chrome/browser/cocoa/geolocation_exceptions_window_controller.h"
 #import "chrome/browser/cocoa/l10n_util.h"
 #import "chrome/browser/geolocation/geolocation_content_settings_map.h"
 #import "chrome/browser/host_content_settings_map.h"
 #include "chrome/browser/pref_service.h"
 #include "chrome/browser/profile.h"
 #include "chrome/common/notification_service.h"
 #include "chrome/common/pref_names.h"
 #include "chrome/common/url_constants.h"
 #include "grit/locale_settings.h"
 
 namespace {
 
-// Index of the "enabled" and "disabled" radio group settings in all tabs except
-// for the cookies tab.
-const NSInteger kEnabledIndex = 0;
-const NSInteger kDisabledIndex = 1;
-
-// Indices of the various cookie settings in the cookie radio group.
-const NSInteger kCookieEnabledIndex = 0;
-const NSInteger kCookieAskIndex = 1;
-const NSInteger kCookieDisabledIndex = 2;
-
 // Stores the currently visible content settings dialog, if any.
 ContentSettingsDialogController* g_instance = nil;
 
-// Indices of the various geolocation settings in the geolocation radio group.
-const NSInteger kGeolocationEnabledIndex = 0;
-const NSInteger kGeolocationAskIndex = 1;
-const NSInteger kGeolocationDisabledIndex = 2;
-
 // Walks views in top-down order, wraps each to their current width, and moves
 // the latter ones down to prevent overlaps.
 CGFloat VerticallyReflowGroup(NSArray* views) {
   views = [views sortedArrayUsingFunction:cocoa_l10n_util::CompareFrameY
                                   context:NULL];
   CGFloat localVerticalShift = 0;
   for (NSInteger index = [views count] - 1; index >= 0; --index) {
     NSView* view = [views objectAtIndex:index];
 
     // Since the tab pane is in a horizontal resizer in IB, it's convenient
@@ skipping 14 matching lines @@
 }
 
 }  // namespace
 
 
 @interface ContentSettingsDialogController(Private)
 - (id)initWithProfile:(Profile*)profile;
 - (void)selectTab:(ContentSettingsType)settingsType;
 - (void)showExceptionsForType:(ContentSettingsType)settingsType;
 
-// Properties that the radio groups and checkboxes are bound to.
-@property(assign, nonatomic) NSInteger cookieSettingIndex;
-@property(assign, nonatomic) BOOL blockThirdPartyCookies;
-@property(assign, nonatomic) BOOL clearSiteDataOnExit;
-@property(assign, nonatomic) NSInteger imagesEnabledIndex;
-@property(assign, nonatomic) NSInteger javaScriptEnabledIndex;
-@property(assign, nonatomic) NSInteger popupsEnabledIndex;
-@property(assign, nonatomic) NSInteger pluginsEnabledIndex;
-@property(assign, nonatomic) NSInteger geolocationSettingIndex;
+// Callback when preferences are changed. |prefName| is the name of the
+// pref that has changed.
+- (void)prefChanged:(std::wstring*)prefName;
 
 @end
 
 namespace ContentSettingsDialogControllerInternal {
 
 // A C++ class registered for changes in preferences.
 class PrefObserverBridge : public NotificationObserver {
  public:
   PrefObserverBridge(ContentSettingsDialogController* controller)
       : controller_(controller) {}
 
   virtual ~PrefObserverBridge() {}
 
   virtual void Observe(NotificationType type,
                        const NotificationSource& source,
                        const NotificationDetails& details) {
-    if (type == NotificationType::PREF_CHANGED) {
-      std::wstring* pref_name = Details<std::wstring>(details).ptr();
-      if (*pref_name == prefs::kClearSiteDataOnExit) {
-        // Update UI.
-        [controller_ setClearSiteDataOnExit:[controller_ clearSiteDataOnExit]];
-      }
+    if (!disabled_ && type == NotificationType::PREF_CHANGED) {
+      [controller_ prefChanged:Details<std::wstring>(details).ptr()];
     }
   }
 
+  void SetDisabled(bool disabled) {
+    disabled_ = disabled;
+  }
+
  private:
   ContentSettingsDialogController* controller_;  // weak, owns us
+  bool disabled_;  // true if notifications should be ignored.
+};
+
+// A C++ utility class to disable notifications for PrefsObserverBridge.
+// The intended usage is to create on the stack.
+class PrefObserverDisabler {
+ public:
+  PrefObserverDisabler(PrefObserverBridge *bridge) : bridge_(bridge) {
+    bridge_->SetDisabled(true);
+  }
+
+  ~PrefObserverDisabler() {
+    bridge_->SetDisabled(false);
+  }
+
+ private:
+  PrefObserverBridge *bridge_;
 };
 
 }  // ContentSettingsDialogControllerInternal
 
 @implementation ContentSettingsDialogController
 
-+(id)showContentSettingsForType:(ContentSettingsType)settingsType
-                        profile:(Profile*)profile {
++ (id)showContentSettingsForType:(ContentSettingsType)settingsType
+                         profile:(Profile*)profile {
   profile = profile->GetOriginalProfile();
   if (!g_instance)
     g_instance = [[self alloc] initWithProfile:profile];
 
   // The code doesn't expect multiple profiles. Check that support for that
   // hasn't been added.
   DCHECK(g_instance->profile_ == profile);
 
   // Select desired tab.
   if (settingsType == CONTENT_SETTINGS_TYPE_DEFAULT) {
@@ skipping 16 matching lines @@
   DCHECK(profile);
   NSString* nibpath =
       [mac_util::MainAppBundle() pathForResource:@"ContentSettings"
                                           ofType:@"nib"];
   if ((self = [super initWithWindowNibPath:nibpath owner:self])) {
     profile_ = profile;
 
     observer_.reset(
         new ContentSettingsDialogControllerInternal::PrefObserverBridge(self));
     clearSiteDataOnExit_.Init(prefs::kClearSiteDataOnExit,
-                              profile->GetPrefs(), observer_.get());
+                              profile_->GetPrefs(), observer_.get());
+
+    // Manually observe notifications for preferences that are grouped in
+    // the HostContentSettingsMap or GeolocationContentSettingsMap.
+    PrefService* prefs = profile_->GetPrefs();
+    prefs->AddPrefObserver(prefs::kBlockThirdPartyCookies, observer_.get());
+    prefs->AddPrefObserver(prefs::kDefaultContentSettings, observer_.get());
+    prefs->AddPrefObserver(prefs::kGeolocationDefaultContentSetting,
+                           observer_.get());
 
     // We don't need to observe changes in this value.
     lastSelectedTab_.Init(prefs::kContentSettingsWindowLastTabIndex,
-                          profile->GetPrefs(), NULL);
+                          profile_->GetPrefs(), NULL);
   }
   return self;
 }
 
+- (void)dealloc {
+  if (profile_) {
+    PrefService* prefs = profile_->GetPrefs();
+    prefs->RemovePrefObserver(prefs::kBlockThirdPartyCookies, observer_.get());
+    prefs->RemovePrefObserver(prefs::kDefaultContentSettings, observer_.get());
+    prefs->RemovePrefObserver(prefs::kGeolocationDefaultContentSetting,
+                              observer_.get());
+  }
+
+  [super dealloc];
+}
+
 - (void)closeExceptionsSheet {
   NSWindow* attachedSheet = [[self window] attachedSheet];
   if (attachedSheet) {
     [NSApp endSheet:attachedSheet];
   }
 }
 
 - (void)awakeFromNib {
   DCHECK([self window]);
   DCHECK_EQ(self, [[self window] delegate]);
@@ skipping 42 matching lines @@
 
 - (void)setCookieSettingIndex:(NSInteger)value {
   ContentSetting setting = CONTENT_SETTING_DEFAULT;
   switch (value) {
     case kCookieEnabledIndex:  setting = CONTENT_SETTING_ALLOW; break;
     case kCookieAskIndex:      setting = CONTENT_SETTING_ASK;   break;
     case kCookieDisabledIndex: setting = CONTENT_SETTING_BLOCK; break;
     default:
       NOTREACHED();
   }
+  ContentSettingsDialogControllerInternal::PrefObserverDisabler
+      disabler(observer_.get());
   profile_->GetHostContentSettingsMap()->SetDefaultContentSetting(
       CONTENT_SETTINGS_TYPE_COOKIES,
       setting);
 }
 
 - (NSInteger)cookieSettingIndex {
   switch (profile_->GetHostContentSettingsMap()->GetDefaultContentSetting(
       CONTENT_SETTINGS_TYPE_COOKIES)) {
     case CONTENT_SETTING_ALLOW: return kCookieEnabledIndex;
     case CONTENT_SETTING_ASK:   return kCookieAskIndex;
     case CONTENT_SETTING_BLOCK: return kCookieDisabledIndex;
     default:
       NOTREACHED();
       return kCookieEnabledIndex;
   }
 }
 
 - (BOOL)blockThirdPartyCookies {
   HostContentSettingsMap* settingsMap = profile_->GetHostContentSettingsMap();
   return settingsMap->BlockThirdPartyCookies();
 }
 
 - (void)setBlockThirdPartyCookies:(BOOL)value {
   HostContentSettingsMap* settingsMap = profile_->GetHostContentSettingsMap();
+  ContentSettingsDialogControllerInternal::PrefObserverDisabler
+      disabler(observer_.get());
   settingsMap->SetBlockThirdPartyCookies(value);
 }
 
 - (BOOL)clearSiteDataOnExit {
   return clearSiteDataOnExit_.GetValue();
 }
 
 - (void)setClearSiteDataOnExit:(BOOL)value {
-  return clearSiteDataOnExit_.SetValue(value);
+  ContentSettingsDialogControllerInternal::PrefObserverDisabler
+      disabler(observer_.get());
+  clearSiteDataOnExit_.SetValue(value);
 }
 
 // Shows the cookies controller.
 - (IBAction)showCookies:(id)sender {
   // The cookie controller will autorelease itself when it's closed.
   BrowsingDataDatabaseHelper* databaseHelper =
       new BrowsingDataDatabaseHelper(profile_);
   BrowsingDataLocalStorageHelper* storageHelper =
       new BrowsingDataLocalStorageHelper(profile_);
   BrowsingDataAppCacheHelper* appcacheHelper =
@@ skipping 50 matching lines @@
 }
 
 - (void)showExceptionsForType:(ContentSettingsType)settingsType {
   HostContentSettingsMap* settingsMap = profile_->GetHostContentSettingsMap();
   [[ContentExceptionsWindowController controllerForType:settingsType
                                             settingsMap:settingsMap]
       attachSheetTo:[self window]];
 }
 
 - (void)setImagesEnabledIndex:(NSInteger)value {
-  ContentSetting setting = value == kEnabledIndex ?
+  ContentSetting setting = value == kContentSettingsEnabledIndex ?
       CONTENT_SETTING_ALLOW : CONTENT_SETTING_BLOCK;
+  ContentSettingsDialogControllerInternal::PrefObserverDisabler
+      disabler(observer_.get());
   profile_->GetHostContentSettingsMap()->SetDefaultContentSetting(
       CONTENT_SETTINGS_TYPE_IMAGES, setting);
 }
 
 - (NSInteger)imagesEnabledIndex {
   HostContentSettingsMap* settingsMap = profile_->GetHostContentSettingsMap();
   bool enabled =
       settingsMap->GetDefaultContentSetting(CONTENT_SETTINGS_TYPE_IMAGES) ==
       CONTENT_SETTING_ALLOW;
-  return enabled ? kEnabledIndex : kDisabledIndex;
+  return enabled ? kContentSettingsEnabledIndex : kContentSettingsDisabledIndex;
 }
 
 - (void)setJavaScriptEnabledIndex:(NSInteger)value {
-  ContentSetting setting = value == kEnabledIndex ?
+  ContentSetting setting = value == kContentSettingsEnabledIndex ?
       CONTENT_SETTING_ALLOW : CONTENT_SETTING_BLOCK;
+  ContentSettingsDialogControllerInternal::PrefObserverDisabler
+      disabler(observer_.get());
   profile_->GetHostContentSettingsMap()->SetDefaultContentSetting(
       CONTENT_SETTINGS_TYPE_JAVASCRIPT, setting);
 }
 
 - (NSInteger)javaScriptEnabledIndex {
   HostContentSettingsMap* settingsMap = profile_->GetHostContentSettingsMap();
   bool enabled =
       settingsMap->GetDefaultContentSetting(CONTENT_SETTINGS_TYPE_JAVASCRIPT) ==
       CONTENT_SETTING_ALLOW;
-  return enabled ? kEnabledIndex : kDisabledIndex;
+  return enabled ? kContentSettingsEnabledIndex : kContentSettingsDisabledIndex;
 }
 
 - (void)setPluginsEnabledIndex:(NSInteger)value {
-  ContentSetting setting = value == kEnabledIndex ?
+  ContentSetting setting = value == kContentSettingsEnabledIndex ?
       CONTENT_SETTING_ALLOW : CONTENT_SETTING_BLOCK;
+  ContentSettingsDialogControllerInternal::PrefObserverDisabler
+      disabler(observer_.get());
   profile_->GetHostContentSettingsMap()->SetDefaultContentSetting(
       CONTENT_SETTINGS_TYPE_PLUGINS, setting);
 }
 
 - (NSInteger)pluginsEnabledIndex {
   HostContentSettingsMap* settingsMap = profile_->GetHostContentSettingsMap();
   bool enabled =
       settingsMap->GetDefaultContentSetting(CONTENT_SETTINGS_TYPE_PLUGINS) ==
       CONTENT_SETTING_ALLOW;
-  return enabled ? kEnabledIndex : kDisabledIndex;
+  return enabled ? kContentSettingsEnabledIndex : kContentSettingsDisabledIndex;
 }
 
 - (void)setPopupsEnabledIndex:(NSInteger)value {
-  ContentSetting setting = value == kEnabledIndex ?
+  ContentSetting setting = value == kContentSettingsEnabledIndex ?
       CONTENT_SETTING_ALLOW : CONTENT_SETTING_BLOCK;
+  ContentSettingsDialogControllerInternal::PrefObserverDisabler
+      disabler(observer_.get());
   profile_->GetHostContentSettingsMap()->SetDefaultContentSetting(
       CONTENT_SETTINGS_TYPE_POPUPS, setting);
 }
 
 - (NSInteger)popupsEnabledIndex {
   HostContentSettingsMap* settingsMap = profile_->GetHostContentSettingsMap();
   bool enabled =
       settingsMap->GetDefaultContentSetting(CONTENT_SETTINGS_TYPE_POPUPS) ==
       CONTENT_SETTING_ALLOW;
-  return enabled ? kEnabledIndex : kDisabledIndex;
+  return enabled ? kContentSettingsEnabledIndex : kContentSettingsDisabledIndex;
 }
 
 - (void)setGeolocationSettingIndex:(NSInteger)value {
   ContentSetting setting = CONTENT_SETTING_DEFAULT;
   switch (value) {
     case kGeolocationEnabledIndex:  setting = CONTENT_SETTING_ALLOW; break;
     case kGeolocationAskIndex:      setting = CONTENT_SETTING_ASK;   break;
     case kGeolocationDisabledIndex: setting = CONTENT_SETTING_BLOCK; break;
     default:
       NOTREACHED();
   }
+  ContentSettingsDialogControllerInternal::PrefObserverDisabler
+      disabler(observer_.get());
   profile_->GetGeolocationContentSettingsMap()->SetDefaultContentSetting(
       setting);
 }
 
 - (NSInteger)geolocationSettingIndex {
   ContentSetting setting =
       profile_->GetGeolocationContentSettingsMap()->GetDefaultContentSetting();
   switch (setting) {
     case CONTENT_SETTING_ALLOW: return kGeolocationEnabledIndex;
     case CONTENT_SETTING_ASK:   return kGeolocationAskIndex;
     case CONTENT_SETTING_BLOCK: return kGeolocationDisabledIndex;
     default:
       NOTREACHED();
       return kGeolocationAskIndex;
   }
 }
 
+// Callback when preferences are changed. |prefName| is the name of the
+// pref that has changed and should not be NULL.
+- (void)prefChanged:(std::wstring*)prefName {
+  DCHECK(prefName);
+  if (!prefName) return;
+  if (*prefName == prefs::kClearSiteDataOnExit) {
+    [self willChangeValueForKey:@"clearSiteDataOnExit"];
+    [self didChangeValueForKey:@"clearSiteDataOnExit"];
+  }
+  if (*prefName == prefs::kBlockThirdPartyCookies) {
+    [self willChangeValueForKey:@"blockThirdPartyCookies"];
+    [self didChangeValueForKey:@"blockThirdPartyCookies"];
+  }
+  if (*prefName == prefs::kDefaultContentSettings) {
+    // We don't know exactly which setting has changed, so we'll tickle all
+    // of the properties that apply to kDefaultContentSettings.  This will
+    // keep the UI up-to-date.
+    [self willChangeValueForKey:@"cookieSettingIndex"];
+    [self didChangeValueForKey:@"cookieSettingIndex"];
+    [self willChangeValueForKey:@"imagesEnabledIndex"];
+    [self didChangeValueForKey:@"imagesEnabledIndex"];
+    [self willChangeValueForKey:@"javaScriptEnabledIndex"];
+    [self didChangeValueForKey:@"javaScriptEnabledIndex"];
+    [self willChangeValueForKey:@"pluginsEnabledIndex"];
+    [self didChangeValueForKey:@"pluginsEnabledIndex"];
+    [self willChangeValueForKey:@"popupsEnabledIndex"];
+    [self didChangeValueForKey:@"popupsEnabledIndex"];
+  }
+  if (*prefName == prefs::kGeolocationDefaultContentSetting) {
+    [self willChangeValueForKey:@"geolocationSettingIndex"];
+    [self didChangeValueForKey:@"geolocationSettingIndex"];
+  }
+}
+
 @end