Add the tooltips for the toolbar buttons....

chrome/browser/cocoa/toolbar_controller.mm

 // Copyright (c) 2009 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/cocoa/toolbar_controller.h"
 
+#include "app/l10n_util_mac.h"
 #include "base/mac_util.h"
 #include "base/sys_string_conversions.h"
 #include "base/gfx/rect.h"
 #include "chrome/app/chrome_dll_resource.h"
+#include "chrome/browser/autocomplete/autocomplete_edit_view.h"
 #include "chrome/browser/autocomplete/autocomplete_popup_view.h"
 #import "chrome/browser/cocoa/autocomplete_text_field.h"
 #import "chrome/browser/cocoa/autocomplete_text_field_editor.h"
 #import "chrome/browser/cocoa/back_forward_menu_controller.h"
 #import "chrome/browser/cocoa/gradient_button_cell.h"
 #import "chrome/browser/cocoa/location_bar_view_mac.h"
 #import "chrome/browser/cocoa/menu_button.h"
 #include "chrome/browser/cocoa/nsimage_cache.h"
 #include "chrome/browser/profile.h"
+#include "chrome/browser/search_engines/template_url_model.h"
 #include "chrome/browser/toolbar_model.h"
 #include "chrome/common/notification_details.h"
 #include "chrome/common/notification_observer.h"
 #include "chrome/common/notification_type.h"
 #include "chrome/common/pref_names.h"
 #include "chrome/common/pref_service.h"
+#include "grit/generated_resources.h"
 
 // Name of image in the bundle for the yellow of the star icon.
 static NSString* const kStarredImageName = @"starred.pdf";
 
 // Height of the toolbar in pixels when the bookmark bar is closed.
 static const float kBaseToolbarHeight = 36.0;
 
 // Overlap (in pixels) between the toolbar and the bookmark bar.
 static const float kBookmarkBarOverlap = 7.0;
 
@@ skipping 144 matching lines @@
   locationBarRetainer_.reset([locationBar_ retain]);
   trackingArea_.reset(
       [[NSTrackingArea alloc] initWithRect:NSZeroRect // Ignored
                                    options:NSTrackingMouseMoved |
                                            NSTrackingInVisibleRect |
                                            NSTrackingMouseEnteredAndExited |
                                            NSTrackingActiveAlways
                                      owner:self
                                   userInfo:nil]);
   [[self view] addTrackingArea:trackingArea_.get()];
+
+  // We want a dynamic tooltip on the go button, so tell the go button to ask
+  // use for the tooltip
+  [goButton_ addToolTipRect:[goButton_ bounds] owner:self userData:nil];
 }
 - (void)removeFromSuperview {
   NSLog(@"remove");
 }
 - (void)mouseExited:(NSEvent*)theEvent {
   [[hoveredButton_ cell] setMouseInside:NO animate:YES];
   [hoveredButton_ release];
   hoveredButton_ = nil;
 }
 
@@ skipping 82 matching lines @@
   [starButton_ setEnabled:commands->IsCommandEnabled(IDC_STAR) ? YES : NO];
 }
 
 - (void)updateToolbarWithContents:(TabContents*)tab
                shouldRestoreState:(BOOL)shouldRestore {
   locationBarView_->Update(tab, shouldRestore ? true : false);
 }
 
 - (void)setStarredState:(BOOL)isStarred {
   NSImage* starImage = nil;
-  if (isStarred)
+  NSString* toolTip;
+  if (isStarred) {
     starImage = nsimage_cache::ImageNamed(kStarredImageName);
+    // Cache the string since we'll need it a lot
+    static NSString* starredToolTip =
+        [l10n_util::GetNSStringWithFixup(IDS_TOOLTIP_STARRED) retain];
+    toolTip = starredToolTip;
+  } else {
+    // Cache the string since we'll need it a lot
+    static NSString* starToolTip =
+        [l10n_util::GetNSStringWithFixup(IDS_TOOLTIP_STAR) retain];
+    toolTip = starToolTip;
+  }
 
   [(GradientButtonCell*)[starButton_ cell] setUnderlayImage:starImage];
+  [starButton_ setToolTip:toolTip];
 }
 
 - (void)setIsLoading:(BOOL)isLoading {
   NSString* imageName = @"go_Template.pdf";
   NSInteger tag = IDC_GO;
   if (isLoading) {
     imageName = @"stop_Template.pdf";
     tag = IDC_STOP;
   }
   NSImage* stopStartImage = nsimage_cache::ImageNamed(imageName);
@@ skipping 131 matching lines @@
   } else if (*prefName == prefs::kShowPageOptionsButtons) {
     [self showOptionalPageWrenchButtons];
   }
 }
 
 - (NSRect)starButtonInWindowCoordinates {
   return [[[starButton_ window] contentView] convertRect:[starButton_ bounds]
                                                 fromView:starButton_];
 }
 
+- (NSString *)view:(NSView *)view
+  stringForToolTip:(NSToolTipTag)tag
+             point:(NSPoint)point
+          userData:(void *)userData {
+  DCHECK(view == goButton_);
+
+  // Following chrome/browser/views/go_button.cc: GoButton::GetTooltipText()
+
+  // Is it currently 'stop'?
+  if ([goButton_ tag] == IDC_STOP) {
+    return l10n_util::GetNSStringWithFixup(IDS_TOOLTIP_STOP);
+  }
+
+  // It is 'go', so see what it would do...
+
+  // Fetch the EditView and EditModel
+  LocationBar* locationBar = [self locationBar];
+  DCHECK(locationBar);
+  AutocompleteEditView* editView = locationBar->location_entry();
+  DCHECK(editView);
+  AutocompleteEditModel* editModel = editView->model();
+  DCHECK(editModel);
+
+  std::wstring currentText(editView->GetText());
+  if (currentText.empty()) {
+    return nil;
+  }
+  string16 currentText16(WideToUTF16Hack(currentText));
+
+  // It is simply an url it is gonna go to, build the tip with the info.
+  if (editModel->CurrentTextIsURL()) {
+    return l10n_util::GetNSStringF(IDS_TOOLTIP_GO_SITE, currentText16);
+  }
+
+  // Build the tip based on what provide/template it will get.
+  std::wstring keyword(editModel->keyword());
+  TemplateURLModel* template_url_model =
+      editModel->profile()->GetTemplateURLModel();
+  const TemplateURL* provider =
+      (keyword.empty() || editModel->is_keyword_hint()) ?
+      template_url_model->GetDefaultSearchProvider() :
+      template_url_model->GetTemplateURLForKeyword(keyword);
+  if (!provider)
+    return nil;
+  std::wstring shortName(provider->AdjustedShortNameForLocaleDirection());
+  return l10n_util::GetNSStringF(IDS_TOOLTIP_GO_SEARCH,
+                                 WideToUTF16(shortName), currentText16);
+
+}
+
 - (gfx::Rect)autocompletePopupPosition {
   // The popup should span from the left edge of the star button to the right
   // edge of the go button.  The returned height is ignored.
   NSRect locationFrame = [locationBar_ frame];
   // TODO(shess): The buttons have an extra 2 pixels between the edge
   // of the visual button and the edge of the logical button.  This
   // seems wrong.
   int minX = NSMinX([starButton_ frame]) + 2.0;
   int maxX = NSMaxX([goButton_ frame]) - 2.0;
   DCHECK(minX < NSMinX(locationFrame));
   DCHECK(maxX > NSMaxX(locationFrame));
 
   NSRect r = NSMakeRect(minX, NSMinY(locationFrame), maxX - minX, 0);
   return gfx::Rect(NSRectToCGRect([[self view] convertRect:r toView:nil]));
 }
 @end