Convert from using env['PLATFORM'] directly to using the more flexible...

skia/SConscript

 # Copyright (c) 2006-2008 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 Import('env')
 
 env = env.Clone()
 
 env.Prepend(
   CPPPATH = [
     'include',
     'include/corecg',
     'corecg',
     'sgl',
     'picture',
     '$CHROME_SRC_DIR',
   ],
 )
 
 env.Append(
   CPPDEFINES = [
     'SKIA_DISABLE_SUPPORT_FOR_DECODERS',
   ],
 )
 
-if env['PLATFORM'] == 'win32':
+if env.Bit('windows'):
   env.Append(
     CCFLAGS = [
       '/TP',
 
       '/wd4244',
       '/wd4267',
       '/wd4345',
       '/wd4390',
       '/wd4554',
       '/wd4800',
     ],
   )
-elif env['PLATFORM'] in ('posix', 'darwin'):
+elif env.Bit('posix'):
   env.Append(CCFLAGS = ['-Wno-unused'])
 
 input_files = [
   'animator/SkTime.cpp',
   'corecg/Sk64.cpp',
   'corecg/SkBuffer.cpp',
   'corecg/SkChunkAlloc.cpp',
   'corecg/SkCordic.cpp',
   'corecg/SkDebug.cpp',
   'corecg/SkDebug_stdio.cpp',
@@ skipping 102 matching lines @@
   'sgl/SkString.cpp',
   'sgl/SkStroke.cpp',
   'sgl/SkStrokerPriv.cpp',
   'sgl/SkTSearch.cpp',
   'sgl/SkTypeface_fake.cpp',
   'sgl/SkUtils.cpp',
   'sgl/SkWriter32.cpp',
   'sgl/SkXfermode.cpp',
 ]
 
-if env['PLATFORM'] == 'posix':
+if env.Bit('linux'):
   input_files.append('ext/bitmap_platform_device_linux.cc')
   input_files.append('ext/platform_canvas_linux.cc')
   input_files.append('ext/platform_device_linux.cc')
 
   # On Linux we use Skia to render fonts with FreeType and fontconfig
   input_files.remove('sgl/SkTypeface_fake.cpp')
   input_files.remove('ports/SkFontHost_none.cpp')
   input_files.append('sgl/SkTypeface.cpp')
   input_files.append('ports/SkFontHost_FreeType.cpp')
   input_files.append('ports/SkFontHost_TrueType_Tables.cpp')
   input_files.append('ports/SkFontHost_gamma_none.cpp')
   input_files.append('ports/SkFontHost_fontconfig.cpp')
   input_files.append('images/SkMMapStream.cpp')
 
   env.Append(CCFLAGS = ['-Wno-unused-function'])
 
-if env['PLATFORM'] in ('darwin', 'posix'):
+if env.Bit('posix'):
   input_files.append('ports/SkThread_pthread.cpp')
 
-if env['PLATFORM'] == 'darwin':
+if env.Bit('mac'):
   input_files.append('ext/bitmap_platform_device_mac.cc')
   input_files.append('ext/platform_canvas_mac.cc')
   input_files.append('ext/platform_device_mac.cc')
 
-if env['PLATFORM'] == 'win32':
+if env.Bit('windows'):
   input_files.append('ext/bitmap_platform_device_win.cc')
   input_files.append('ext/platform_canvas_win.cc')
   input_files.append('ext/platform_device_win.cc')
   input_files.append('ext/skia_utils_win.cc')
   input_files.append('ext/vector_canvas.cc')
   input_files.append('ext/vector_device.cc')
 
   input_files.append('ports/SkThread_win.cpp')
 
   env_p = env.Clone(
     PCHSTOP = 'SkTypes.h',
     PDB = 'vc80.pdb',
   )
 
   # TODO(rspangler): This step forces -Zi, but doesn't actually use it.  Need to
   # fix so it doesn't override our -Z7.  -Zi also causes vc80.pdb to be created
   # in the skia directory.
   # TODO(bradnelson): This step creates a skia.pch.ib_tag file to be created. 
   # It's a 0-length file so likely harmless.  Is this a side effect of having
   # IncrediBuild installed on the build machine?
   pch, obj = env_p.PCH(['skia.pch', 'precompiled.obj'], 'precompiled.cc')
   env_p['PCH'] = pch
   input_files += [obj]
 
 env.ChromeStaticLibrary('skia', input_files)