[MIPS] Untrusted versions of setjmp and longjmp.

pnacl/support/setjmp_mips32.S

+/*

[Mark Seaborn, 2012/10/03 00:46:33]

Surely this file should be "setjmp_mips.S"?  The other MIPS files don't have
"mips32" in their names.

[petarj, 2012/10/03 16:50:01]

Well, the other mips files are not compiled with "setjmp_${arch/-/_}".
See pnacl/build.sh

[Mark Seaborn, 2012/10/03 20:02:54]

Hmm.  Given that build.sh is already munging '-' to '_', there is a case for
further munging "mips32" to "mips".  But I guess it's OK as is.

+ * Copyright (c) 2012 The Native Client Authors. All rights reserved.
+ * Use of this source code is governed by a BSD-style license that can be
+ * found in the LICENSE file.
+ */
+
+#include "nacl_mips_defs.h"
+
+  .text
+  .p2align 4
+  .align NACL_BLOCK_SHIFT
+  .globl setjmp
+  .ent setjmp

[Mark Seaborn, 2012/10/03 00:46:33]

BTW, you didn't use .ent in tls_get_addr.S

+  .frame  $sp, 0, $31
+  .set noreorder
+
+/* int setjmp(jmp_buf env) */
+setjmp:
+
+  /* NACL_CALLEE_SAVE_LIST BEGIN */
+  and  $a0, $a0, STORE_MASK
+  sw   $s0, 0($a0)
+  and  $a0, $a0, STORE_MASK
+  sw   $s1, 4($a0)
+

[Mark Seaborn, 2012/10/03 00:46:33]

It's a little odd that the empty lines group this by pairs of registers.

I'd suggest either putting an empty line between each reg:

and  $a0, $a0, STORE_MASK
sw   $s0, 0($a0)

and  $a0, $a0, STORE_MASK
sw   $s1, 0($a0)

and  $a0, $a0, STORE_MASK
sw   $s2, 0($a0)

or group by type of register, e.g.

/* Save s0-s7 */
and  $a0, $a0, STORE_MASK
sw   $s0, 0($a0)
and  $a0, $a0, STORE_MASK
sw   $s1, 0($a0)
and  $a0, $a0, STORE_MASK
sw   $s2, 0($a0)

/* Save sp */
...

[petarj, 2012/10/03 16:50:01]

Normally, we would group it by type of registers (GPR and FPR), like it is done
in newlib. But the idea was to show the bundle alignment, so it is more readable
for anyone looking for pattern breakage. This way, for instance, an extra 'nop'
can be explained without words.
It was not grouped by pairs of registers.

[Mark Seaborn, 2012/10/03 20:02:54]

Ah, I see.  Maybe add a comment like
/* The code here is grouped by instruction bundle */

[petarj, 2012/10/05 17:26:44]

Done.

+  and  $a0, $a0, STORE_MASK
+  sw   $s2, 8($a0)
+  and  $a0, $a0, STORE_MASK
+  sw   $s3, 12($a0)
+
+  and  $a0, $a0, STORE_MASK
+  sw   $s4, 16($a0)
+  and  $a0, $a0, STORE_MASK
+  sw   $s5, 20($a0)
+
+  and  $a0, $a0, STORE_MASK
+  sw   $s6, 24($a0)
+  and  $a0, $a0, STORE_MASK
+  sw   $s7, 28($a0)
+
+  and  $a0, $a0, STORE_MASK
+  sw   $sp, 32($a0)
+  and  $a0, $a0, STORE_MASK
+  sw   $fp, 36($a0)
+
+  and  $a0, $a0, STORE_MASK
+  sw   $ra, 40($a0)
+  and  $a0, $a0, STORE_MASK
+  swc1 $f20, 44($a0)
+
+  and  $a0,  $a0, STORE_MASK
+  swc1 $f21, 48($a0)
+  and  $a0,  $a0, STORE_MASK
+  swc1 $f22, 52($a0)
+
+  and  $a0,  $a0, STORE_MASK
+  swc1 $f23, 56($a0)
+  and  $a0,  $a0, STORE_MASK
+  swc1 $f24, 60($a0)
+
+  and  $a0,  $a0, STORE_MASK
+  swc1 $f25, 64($a0)
+  and  $a0,  $a0, STORE_MASK
+  swc1 $f26, 68($a0)
+
+  and  $a0,  $a0, STORE_MASK
+  swc1 $f27, 72($a0)
+  and  $a0,  $a0, STORE_MASK
+  swc1 $f28, 76($a0)
+
+  and  $a0,  $a0, STORE_MASK
+  swc1 $f29, 80($a0)
+  and  $a0,  $a0, STORE_MASK
+  swc1 $f30, 84($a0)
+
+  and  $a0,  $a0, STORE_MASK
+  swc1 $f31, 88($a0)
+  /* NACL_CALLEE_SAVE_LIST END */
+  move $v0, $zero
+  nop
+
+  and  $ra, $ra, JUMP_MASK
+  j    $ra
+  nop
+  nop
+
+  .end setjmp
+
+  .text
+  .p2align 4
+  .align NACL_BLOCK_SHIFT
+  .globl longjmp
+  .ent longjmp
+  .set noreorder
+
+/* void longjmp(jmp_buf env, int val) */
+longjmp:
+
+  /* NACL_CALLEE_LOAD_LIST BEGIN */
+  and  $a0, $a0, STORE_MASK
+  lw   $s0, 0($a0)
+  and  $a0, $a0, STORE_MASK
+  lw   $s1, 4($a0)
+
+  and  $a0, $a0, STORE_MASK
+  lw   $s2, 8($a0)
+  and  $a0, $a0, STORE_MASK
+  lw   $s3, 12($a0)
+
+  and  $a0, $a0, STORE_MASK
+  lw   $s4, 16($a0)
+  and  $a0, $a0, STORE_MASK
+  lw   $s5, 20($a0)
+
+  and  $a0, $a0, STORE_MASK
+  lw   $s6, 24($a0)
+  and  $a0, $a0, STORE_MASK
+  lw   $s7, 28($a0)
+
+  and  $a0, $a0, STORE_MASK
+  lw   $sp, 32($a0)
+  and  $sp, $sp, STORE_MASK
+  nop
+
+  and  $a0, $a0, STORE_MASK
+  lw   $fp, 36($a0)
+  and  $a0, $a0, STORE_MASK
+  lw   $ra, 40($a0)
+
+  and  $a0,  $a0, STORE_MASK
+  lwc1 $f20, 44($a0)
+  and  $a0,  $a0, STORE_MASK
+  lwc1 $f21, 48($a0)
+
+  and  $a0,  $a0, STORE_MASK
+  lwc1 $f22, 52($a0)
+  and  $a0,  $a0, STORE_MASK
+  lwc1 $f23, 56($a0)
+
+  and  $a0,  $a0, STORE_MASK
+  lwc1 $f24, 60($a0)
+  and  $a0,  $a0, STORE_MASK
+  lwc1 $f25, 64($a0)
+
+  and  $a0,  $a0, STORE_MASK
+  lwc1 $f26, 68($a0)
+  and  $a0,  $a0, STORE_MASK
+  lwc1 $f27, 72($a0)
+
+  and  $a0,  $a0, STORE_MASK
+  lwc1 $f28, 76($a0)
+  and  $a0,  $a0, STORE_MASK
+  lwc1 $f29, 80($a0)
+
+  and  $a0,  $a0, STORE_MASK
+  lwc1 $f30, 84($a0)
+  and  $a0,  $a0, STORE_MASK
+  lwc1 $f31, 88($a0)
+  /* NACL_CALLEE_LOAD_LIST END */
+
+  bne  $a1, $zero, 1f
+  nop
+  ori  $a1, $zero, 1
+1:
+  move $v0, $a1
+
+  and  $ra, $ra, JUMP_MASK
+  j    $ra
+  nop
+  nop
+
+  .end longjmp
+