Mac Web Intents Part 11: Progress view

chrome/browser/ui/cocoa/intents/web_intent_picker_view_controller.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/intents/web_intent_picker_view_controller.h"
 
 #include "base/sys_string_conversions.h"
 #import "chrome/browser/ui/cocoa/event_utils.h"
 #import "chrome/browser/ui/cocoa/flipped_view.h"
 #import "chrome/browser/ui/cocoa/hover_close_button.h"
 #import "chrome/browser/ui/cocoa/intents/web_intent_picker_cocoa2.h"
 #import "chrome/browser/ui/cocoa/intents/web_intent_view_controller_message.h"
+#import "chrome/browser/ui/cocoa/intents/web_intent_view_controller_progress.h"
 #import "chrome/browser/ui/cocoa/key_equivalent_constants.h"
 #include "chrome/browser/ui/constrained_window.h"
 #include "chrome/browser/ui/intents/web_intent_picker_delegate.h"
 #include "chrome/browser/ui/intents/web_intent_inline_disposition_delegate.h"
 
 #include "grit/generated_resources.h"
 #include "ui/base/cocoa/window_size_constants.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 
 namespace {
 
 WebIntentPickerState GetPickerState(const WebIntentPickerModel& model) {
+  if (!model.pending_install_extension_id().empty())
+    return PICKER_STATE_INSTALLING_EXTENSION;
+  if (model.IsWaitingForSuggestions())
+    return PICKER_STATE_WAITING;
   return PICKER_STATE_NO_SERVICE;
 }
 
 }
 
 @interface WebIntentPickerViewController ()
 
 - (void)performLayout;
 // Gets the inner frame with a minimum window width and height.
 - (NSRect)minInnerFrame;
 // Gets the view controller currently being displayed.
 - (WebIntentViewController*)currentViewController;
 
 // Update the varous views.
+- (void)updateWaiting;
 - (void)updateNoService;
+- (void)updateInstallingExtension;
 
 - (void)onCloseButton:(id)sender;
 - (void)cancelOperation:(id)sender;
 
 @end
 
 @implementation WebIntentPickerViewController
 
 - (id)initWithPicker:(WebIntentPickerCocoa2*)picker {
   if ((self = [super init])) {
     picker_ = picker;
 
     scoped_nsobject<NSView> view(
         [[FlippedView alloc] initWithFrame:ui::kWindowSizeDeterminedLater]);
     [self setView:view];
 
     closeButton_.reset([[HoverCloseButton alloc] initWithFrame:NSZeroRect]);
     [closeButton_ setTarget:self];
     [closeButton_ setAction:@selector(onCloseButton:)];
     [[closeButton_ cell] setKeyEquivalent:kKeyEquivalentEscape];
     [[self view] addSubview:closeButton_];
 
     messageViewController_.reset(
         [[WebIntentViewControllerMessage alloc] init]);
+    progressViewController_.reset(
+        [[WebIntentViewControllerProgress alloc] init]);
   }
   return self;
 }
 
 - (WebIntentPickerState)state {
   return state_;
 }
 
 - (WebIntentViewControllerMessage*)messageViewController {
   return messageViewController_;
 }
 
+- (WebIntentViewControllerProgress*)progressViewController {
+  return progressViewController_;
+}
+
 - (void)update {
   WebIntentPickerState newState = GetPickerState(*picker_->model());
   if (state_ != newState || ![[[self currentViewController] view] superview]) {
     [[[self currentViewController] view] removeFromSuperview];
     state_ = newState;
     [[self view] addSubview:[[self currentViewController] view]];
 
     // Ensure that the close button is top most.
     [closeButton_ removeFromSuperview];
     [[self view] addSubview:closeButton_];
   }
 
   switch (state_) {
+    case PICKER_STATE_WAITING:
+      [self updateWaiting];
+      break;
     case PICKER_STATE_NO_SERVICE:
       [self updateNoService];
       break;
+    case PICKER_STATE_INSTALLING_EXTENSION:
+      [self updateInstallingExtension];
+      break;
   }
 
   [self performLayout];
 }
 
 - (void)performLayout {
   NSRect innerFrame = [self minInnerFrame];
   WebIntentViewController* viewController = [self currentViewController];
   NSSize minSize =
       [viewController minimumSizeForInnerWidth:NSWidth(innerFrame)];
@@ skipping 22 matching lines @@
 - (NSRect)minInnerFrame {
   NSRect bounds = NSMakeRect(0, 0, WebIntentPicker::kWindowMinWidth,
                              WebIntentPicker::kWindowMinHeight);
   return NSInsetRect(bounds,
                      ConstrainedWindow::kHorizontalPadding,
                      ConstrainedWindow::kVerticalPadding);
 }
 
 - (WebIntentViewController*)currentViewController {
   switch (state_) {
+    case PICKER_STATE_WAITING:
+      return progressViewController_;
     case PICKER_STATE_NO_SERVICE:
       return messageViewController_;
+    case PICKER_STATE_INSTALLING_EXTENSION:
+      return progressViewController_;
   }
   NOTREACHED();
   return nil;
 }
 
+- (void)updateWaiting {
+  NSString* message = l10n_util::GetNSStringWithFixup(
+      IDS_INTENT_PICKER_WAIT_FOR_CWS);
+  [progressViewController_ setMessage:message];
+  [progressViewController_ setPercentDone:-1];
+}
+
 - (void)updateNoService {
   [messageViewController_ setTitle:l10n_util::GetNSStringWithFixup(
       IDS_INTENT_PICKER_NO_SERVICES_TITLE)];
   [messageViewController_ setMessage:l10n_util::GetNSStringWithFixup(
       IDS_INTENT_PICKER_NO_SERVICES)];
 }
 
+- (void)updateInstallingExtension {
+  WebIntentPickerModel* model = picker_->model();
+  const WebIntentPickerModel::SuggestedExtension* extension =
+      model->GetSuggestedExtensionWithId(
+          model->pending_install_extension_id());
+  if (!extension)
+    return;
+  [progressViewController_ setTitle:
+      base::SysUTF16ToNSString(extension->title)];
+  [progressViewController_ setMessage:
+      base::SysUTF16ToNSString(model->pending_install_status_string())];
+  [progressViewController_ setPercentDone:
+      model->pending_install_download_percent()];
+}
+
 - (void)onCloseButton:(id)sender {
   picker_->delegate()->OnUserCancelledPickerDialog();
 }
 
 // Handle default OSX dialog cancel mechanisms. (Cmd-.)
 - (void)cancelOperation:(id)sender {
   [self onCloseButton:sender];
 }
 
 @end