[Mac] Website settings: Implement custom tab appearance.

chrome/browser/ui/cocoa/website_settings_bubble_controller.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/website_settings_bubble_controller.h"
 
+#import <AppKit/NSCell.h>

[Robert Sesek, 2012/07/26 02:49:28]

Is this necessary? You import Cocoa.h in the .h, which should bring in AppKit.h.
The convention is to not import individual headers and to use the umbrella
header (AppKit.h) instead.

[Patrick Dubroy, 2012/07/28 02:15:02]

You're right. I could have sworn I added this only after a compile failure, but
I can't remember now.

+#import <QuartzCore/QuartzCore.h>
+
 #include "base/sys_string_conversions.h"
 #import "chrome/browser/ui/cocoa/browser_window_controller.h"
 #import "chrome/browser/ui/cocoa/info_bubble_view.h"
 #import "chrome/browser/ui/cocoa/info_bubble_window.h"
 #import "chrome/browser/ui/cocoa/location_bar/location_bar_view_mac.h"
 #include "chrome/browser/ui/tab_contents/tab_contents.h"
 #include "content/public/browser/cert_store.h"
 #include "grit/generated_resources.h"
+#include "grit/theme_resources.h"
 #include "grit/ui_resources.h"
 #import "third_party/GTM/AppKit/GTMUILocalizerAndLayoutTweaker.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "ui/base/resource/resource_bundle.h"
 
 namespace {
 
 // The width of the window, in view coordinates. The height will be determined
 // by the content.
 const CGFloat kWindowWidth = 380;
@@ skipping 41 matching lines @@
 // A simple container to hold all the contents of the website settings bubble.
 // It uses a flipped coordinate system to make text layout easier.
 @interface WebsiteSettingsContentView : NSView
 @end
 @implementation WebsiteSettingsContentView
 - (BOOL)isFlipped {
   return YES;
 }
 @end
 
+@interface CustomTabbedSegmentedCell : NSSegmentedCell {

[Robert Sesek, 2012/07/26 02:49:28]

naming: call this WebsiteSettingsTabSegmentedCell

[Patrick Dubroy, 2012/07/28 02:15:02]

Done.

+ @private
+  scoped_nsobject<NSImage> tabBackgroundImage_;
+  scoped_nsobject<NSImage> tabCenterImage_;
+  scoped_nsobject<NSImage> tabLeftImage_;
+  scoped_nsobject<NSImage> tabRightImage_;
+}
+@end
+@implementation CustomTabbedSegmentedCell
+- (id)init {
+  ResourceBundle& rb = ResourceBundle::GetSharedInstance();

[Robert Sesek, 2012/07/26 02:49:28]

This should be in an if ((self = [super init])) block

[Patrick Dubroy, 2012/07/28 02:15:02]

Done.

+  tabBackgroundImage_.reset(
+      [rb.GetNativeImageNamed(IDR_WEBSITE_SETTINGS_TAB_BACKGROUND) retain]);
+  tabCenterImage_.reset(
+      [rb.GetNativeImageNamed(IDR_WEBSITE_SETTINGS_TAB_CENTER) retain]);
+  tabLeftImage_.reset(
+      [rb.GetNativeImageNamed(IDR_WEBSITE_SETTINGS_TAB_LEFT) retain]);
+  tabRightImage_.reset(
+      [rb.GetNativeImageNamed(IDR_WEBSITE_SETTINGS_TAB_RIGHT) retain]);
+
+  return [super init];
+}
+
+// Fill the given rect with a tiled pattern using the given image.
+- (void)fillRect:(NSRect)rect
+  withTiledImage:(NSImage*)image
+          inView:(NSView*)view{
+  NSGraphicsContext* context = [NSGraphicsContext currentContext];
+  [context saveGraphicsState];

[Robert Sesek, 2012/07/26 02:49:28]

There's a scoper in ui/gfx for this.

[Patrick Dubroy, 2012/07/28 02:15:02]

Not relevant anymore.

+  NSPoint patternStart = [view convertPoint:rect.origin toView:nil];
+  [context setPatternPhase:patternStart];
+  [[NSColor colorWithPatternImage:image] set];
+  NSRectFill(rect);
+  [context restoreGraphicsState];
+}
+
+- (void)drawWithFrame:(NSRect)cellFrame inView:(NSView *)controlView {
+  // Draw the background for the tab strip.
+  [self fillRect:cellFrame
+  withTiledImage:tabBackgroundImage_.get()

[Robert Sesek, 2012/07/26 02:49:28]

nit: if aligning the colons mean that the next line is <2 spaces indented, the
convention is to treat it like a C++ continuation and to put each param on its
own line and indent each 4 spaces.

[Patrick Dubroy, 2012/07/28 02:15:02]

Not relevant anymore.

+          inView:controlView];
+
+  // Draw the individual tabs.
+  [self drawInteriorWithFrame:cellFrame inView:controlView];
+}
+
+- (void)drawSegment:(NSInteger)segment
+            inFrame:(NSRect)frame
+           withView:(NSView*)controlView {
+  if ([self isSelectedForSegment:segment]) {
+    NSDrawThreePartImage(frame,
+                         tabLeftImage_,
+                         tabCenterImage_,
+                         tabRightImage_,
+                         NO,

[Robert Sesek, 2012/07/26 02:49:28]

For these BOOL params, can you do /*param_name=*/ NO?

[Patrick Dubroy, 2012/07/28 02:15:02]

Done.

+                         NSCompositeSourceOver,
+                         1,
+                         YES);
+  }
+  frame.origin.y += 20;
+  frame.size.height -= 20;
+
+  // Call the superclass to draw the label.
+  [super drawSegment:segment inFrame:frame withView:controlView];
+}
+@end
+
 @implementation WebsiteSettingsBubbleController
 
 - (id)initWithParentWindow:(NSWindow*)parentWindow
    websiteSettingsUIBridge:(WebsiteSettingsUIBridge*)bridge {
   DCHECK(parentWindow);
 
   // Use an arbitrary height; it will be changed in performLayout.
   NSRect contentRect = NSMakeRect(0, 0, kWindowWidth, 1);
   // Create an empty window into which content is placed.
   scoped_nsobject<InfoBubbleWindow> window(
@@ skipping 40 matching lines @@
 
   // Create a text field to identity status (e.g. verified, not verified).
   identityStatusField_ = [self addText:string16()
                               withSize:[NSFont smallSystemFontSize]
                                   bold:NO
                                 toView:contentView_
                                atPoint:controlOrigin];
 
   // Create the tab view and its two tabs.
 
+  NSRect initialFrame = NSMakeRect(0, 0, kWindowWidth, 44);
+  segmentedControl_.reset(
+      [[NSSegmentedControl alloc] initWithFrame:initialFrame]);
+  [segmentedControl_ setCell:[[CustomTabbedSegmentedCell alloc] init]];
+  [segmentedControl_ setSegmentCount:2];
+  [segmentedControl_ setTarget:self];
+  [segmentedControl_ setAction:@selector(tabSelected:)];
+  NSFont* smallSystemFont =
+      [NSFont systemFontOfSize:[NSFont smallSystemFontSize]];
+  NSDictionary* textAttributes =
+      [NSDictionary dictionaryWithObject:smallSystemFont
+                                  forKey:NSFontAttributeName];
+
+  NSString* label = l10n_util::GetNSString(
+      IDS_WEBSITE_SETTINGS_TAB_LABEL_PERMISSIONS);
+  NSSize textSize = [label sizeWithAttributes:textAttributes];
+
+  [segmentedControl_ setLabel:label forSegment:0];
+  [segmentedControl_ setWidth:textSize.width + 2 * 28 forSegment:0];

[Robert Sesek, 2012/07/26 02:49:28]

Where's 28 come from?

[Patrick Dubroy, 2012/07/28 02:15:02]

Fixed.

+
+  label = l10n_util::GetNSString(IDS_WEBSITE_SETTINGS_TAB_LABEL_CONNECTION);
+  textSize = [label sizeWithAttributes:textAttributes];
+  [segmentedControl_ setLabel:label forSegment:1];
+  [segmentedControl_ setWidth:textSize.width + 2 * 28 forSegment:1];
+
+  [segmentedControl_ setFont:smallSystemFont];
+  [contentView_ addSubview:segmentedControl_];
+
   NSRect tabFrame = NSMakeRect(0, 0, kWindowWidth, 300);
   tabView_.reset([[NSTabView alloc] initWithFrame:tabFrame]);
-  [tabView_ setTabViewType:NSTopTabsBezelBorder];
+  [tabView_ setTabViewType:NSNoTabsNoBorder];
+  [tabView_ setDrawsBackground:NO];
   [tabView_ setControlSize:NSSmallControlSize];
-  [tabView_ setFont:[NSFont systemFontOfSize:[NSFont smallSystemFontSize]]];
   [contentView_ addSubview:tabView_.get()];
 
   permissionsContentView_ = [self addPermissionsTabToTabView:tabView_];
   [self addConnectionTabToTabView:tabView_];
 
   // Replace the window's content.
   [[[self window] contentView] setSubviews:
       [NSArray arrayWithObject:contentView_.get()]];
 
   [self performLayout];
 }
 
 // Create the contents of the Permissions tab and add it to the given tab view.
 // Returns a weak reference to the tab view item's view.
 - (NSView*)addPermissionsTabToTabView:(NSTabView*)tabView {
   scoped_nsobject<NSTabViewItem> item([[NSTabViewItem alloc] init]);
-  [item setLabel:
-      l10n_util::GetNSString(IDS_WEBSITE_SETTINGS_TAB_LABEL_PERMISSIONS)];
   [tabView_ addTabViewItem:item.get()];
   scoped_nsobject<NSView> contentView([[WebsiteSettingsContentView alloc]
       initWithFrame:[tabView_ contentRect]]);
   [item setView:contentView.get()];
   return contentView.get();
 }
 
 // Create the contents of the Connection tab and add it to the given tab view.
 // Returns a weak reference to the tab view item's view.
 - (NSView*)addConnectionTabToTabView:(NSTabView*)tabView {
   scoped_nsobject<NSTabViewItem> item([[NSTabViewItem alloc] init]);
-  [item setLabel:
-      l10n_util::GetNSString(IDS_WEBSITE_SETTINGS_TAB_LABEL_CONNECTION)];
-
   scoped_nsobject<NSView> contentView([[WebsiteSettingsContentView alloc]
       initWithFrame:[tabView_ contentRect]]);
 
   // Place all the text at the same position. It will be adjusted in
   // performLayout.
   NSPoint textPosition = NSMakePoint(
       kTabViewContentsPadding + kImageSize + kImageSpacing,
       kTabViewContentsPadding);
 
   identityStatusIcon_ =
@@ skipping 77 matching lines @@
 
   // Lay out the last visit section.
   [self setYPositionOfView:firstVisitIcon_ to:yPos];
   [self sizeTextFieldHeightToFit:firstVisitHeaderField_];
   yPos = [self setYPositionOfView:firstVisitHeaderField_ to:yPos];
   yPos += kHeadlineSpacing;
   [self sizeTextFieldHeightToFit:firstVisitDescriptionField_];
   [self setYPositionOfView:firstVisitDescriptionField_ to:yPos];
 
   // Adjust the tab view size and place it below the identity status.
+
+  NSRect segmentedControlFrame = [segmentedControl_ frame];
+  segmentedControlFrame.origin.y =
+      NSMaxY([identityStatusField_ frame]);
+  [segmentedControl_ setFrame:segmentedControlFrame];
+
   NSRect tabViewFrame = [tabView_ frame];
-  tabViewFrame.origin.y =
-      NSMaxY([identityStatusField_ frame]) + kVerticalSpacing;
+  tabViewFrame.origin.y = NSMaxY(segmentedControlFrame);
 
   CGFloat connectionTabHeight = std::max(
       NSMaxY([firstVisitDescriptionField_ frame]),
       NSMaxY([firstVisitIcon_ frame ]));
   connectionTabHeight += kVerticalSpacing;
 
   CGFloat tabContentHeight = std::max(connectionTabHeight,
                                       permissionsTabHeight_);
   tabViewFrame.size.height = tabContentHeight +
       NSHeight(tabViewFrame) - NSHeight([tabView_ contentRect]);
@@ skipping 179 matching lines @@
 
   [button setAction:@selector(permissionValueChanged:)];
   [button setTarget:self];
 
   [self setTitleOfButton:button];
 
   [view addSubview:button.get()];
   return button.get();
 }
 
+- (void)tabSelected:(id)sender {
+  [tabView_ selectTabViewItemAtIndex: [segmentedControl_ selectedSegment]];

[Robert Sesek, 2012/07/26 02:49:28]

nit: no space after :

[Patrick Dubroy, 2012/07/28 02:15:02]

Done.

+}
+
 // Handler for the permission-changing menus.
 - (void)permissionValueChanged:(id)sender {
   DCHECK([sender isKindOfClass:[NSPopUpButton class]]);
   NSPopUpButton* button = static_cast<NSPopUpButton*>(sender);
   ContentSettingsType type = static_cast<ContentSettingsType>([button tag]);
   ContentSetting newSetting = [self contentSettingForButton:button];
 
   [self setTitleOfButton:button];
   if (presenter_.get())
     presenter_->OnSitePermissionChanged(type, newSetting);
@@ skipping 128 matching lines @@
 }
 
 void WebsiteSettingsUIBridge::SetIdentityInfo(
     const WebsiteSettingsUI::IdentityInfo& identity_info) {
   [bubble_controller_ setIdentityInfo:identity_info];
 }
 
 void WebsiteSettingsUIBridge::SetFirstVisit(const string16& first_visit) {
   [bubble_controller_ setFirstVisit:first_visit];
 }