[mac] Implement {frame: 'none'} app window on Mac.

chrome/browser/ui/cocoa/extensions/shell_window_cocoa.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/browser/ui/cocoa/extensions/shell_window_cocoa.h"
 
 #include "base/mac/mac_util.h"
 #include "base/sys_string_conversions.h"
 #include "chrome/browser/profiles/profile.h"
 #include "chrome/browser/ui/cocoa/browser_window_utils.h"
@@ skipping 64 matching lines @@
     cornerRadius = [view roundedCornerRadius];
   [[NSBezierPath bezierPathWithRoundedRect:[view bounds]
                                    xRadius:cornerRadius
                                    yRadius:cornerRadius] addClip];
   [[NSColor whiteColor] set];
   NSRectFill(rect);
 }
 
 @end
 
+@interface ControlRegionView : NSView
+@end
+@implementation ControlRegionView
+- (BOOL)mouseDownCanMoveWindow {
+  return NO;
+}
+- (NSView*)hitTest:(NSPoint)aPoint {
+  return nil;
+}
+@end
+
+@interface NSView (WebContentsView)
+- (void)setMouseDownCanMoveWindow:(BOOL)can_move;
+@end
+
 ShellWindowCocoa::ShellWindowCocoa(Profile* profile,
                                    const extensions::Extension* extension,
                                    const GURL& url,
                                    const ShellWindow::CreateParams& params)
     : ShellWindow(profile, extension, url),
+      has_frame_(params.frame == ShellWindow::CreateParams::FRAME_CHROME),
       attention_request_id_(0) {
   // Flip coordinates based on the primary screen.
   NSRect main_screen_rect = [[[NSScreen screens] objectAtIndex:0] frame];
   NSRect cocoa_bounds = NSMakeRect(params.bounds.x(),
       NSHeight(main_screen_rect) - params.bounds.y() - params.bounds.height(),
       params.bounds.width(), params.bounds.height());
   NSUInteger style_mask = NSTitledWindowMask | NSClosableWindowMask |
                           NSMiniaturizableWindowMask | NSResizableWindowMask |
                           NSTexturedBackgroundWindowMask;
   scoped_nsobject<NSWindow> window([[ShellNSWindow alloc]
@@ skipping 10 matching lines @@
   if (max_size.width() || max_size.height()) {
     CGFloat max_width = max_size.width() ? max_size.width() : CGFLOAT_MAX;
     CGFloat max_height = max_size.height() ? max_size.height() : CGFLOAT_MAX;
     [window setContentMaxSize:NSMakeSize(max_width, max_height)];
   }
 
   if (base::mac::IsOSSnowLeopardOrEarlier() &&
       [window respondsToSelector:@selector(setBottomCornerRounded:)])
     [window setBottomCornerRounded:NO];
 
-  NSView* view = web_contents()->GetView()->GetNativeView();
-  [view setFrame:[[window contentView] bounds]];
-  [view setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
-  [[window contentView] addSubview:view];
-
   window_controller_.reset(
       [[ShellWindowController alloc] initWithWindow:window.release()]);
+
+  NSView* view = web_contents()->GetView()->GetNativeView();
+  [view setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
+
+  if (!has_frame_) {
+    // TODO(jeremya): this is a temporary hack to allow moving the window while
+    // we still don't have proper draggable region support.
+    NSView* controlRegion = [[ControlRegionView alloc] init];

[sail, 2012/08/07 17:40:11]

this should be scoped_nsobject

+    [controlRegion setFrame:NSMakeRect(0, 0, NSWidth([view bounds]),
+                                       NSHeight([view bounds]) - 20)];
+    [controlRegion setAutoresizingMask:
+        NSViewWidthSizable | NSViewHeightSizable];
+    [view addSubview:controlRegion];
+    [controlRegion release];
+  }
+
+  InstallView();
+
   [[window_controller_ window] setDelegate:window_controller_];
   [window_controller_ setShellWindow:this];
 }
 
+void ShellWindowCocoa::InstallView() {
+  NSView* view = web_contents()->GetView()->GetNativeView();
+  if (has_frame_) {
+    [view setFrame:[[window() contentView] bounds]];
+    [[window() contentView] addSubview:view];
+  } else {
+    // TODO(jeremya): find a cleaner way to send this information to the
+    // WebContentsViewCocoa view.

[Avi (use Gerrit), 2012/08/03 05:19:49]

Grrr. :(

[jeremya, 2012/08/05 22:52:42]

I know :( :(

I'm thinking that maybe the setMouseDownCanMoveWindow: method belongs on
BaseView, which is visible here. That seems like the cleanest way. I'll prepare
a CL to do that.

+    DCHECK([view
+        respondsToSelector:@selector(setMouseDownCanMoveWindow:)]);
+    [view setMouseDownCanMoveWindow:YES];
+
+    NSView* frameView = [[window() contentView] superview];
+    [view setFrame:[frameView bounds]];
+    [frameView addSubview:view];
+
+    [[window() standardWindowButton:NSWindowZoomButton] setHidden:YES];
+    [[window() standardWindowButton:NSWindowMiniaturizeButton] setHidden:YES];
+    [[window() standardWindowButton:NSWindowCloseButton] setHidden:YES];
+  }
+}
+
+void ShellWindowCocoa::UninstallView() {
+  NSView* view = web_contents()->GetView()->GetNativeView();
+  [view removeFromSuperview];
+}
+
 bool ShellWindowCocoa::IsActive() const {
   return [window() isKeyWindow];
 }
 
 bool ShellWindowCocoa::IsMaximized() const {
   return [window() isZoomed];
 }
 
 bool ShellWindowCocoa::IsMinimized() const {
   return [window() isMiniaturized];
@@ skipping 19 matching lines @@
   const CGDisplayReservationInterval kFadeDurationSeconds = 0.6;
   bool did_fade_out = false;
   CGDisplayFadeReservationToken token;
   if (CGAcquireDisplayFadeReservation(kFadeDurationSeconds, &token) ==
       kCGErrorSuccess) {
     did_fade_out = true;
     CGDisplayFade(token, kFadeDurationSeconds / 2, kCGDisplayBlendNormal,
         kCGDisplayBlendSolidColor, 0.0, 0.0, 0.0, /*synchronous=*/true);
   }
 
+  // Since frameless windows insert the WebContentsView into the NSThemeFrame
+  // ([[window contentView] superview]), and since that NSThemeFrame is
+  // destroyed and recreated when we change the styleMask of the window, we
+  // need to remove the view from the window when we change the style, and
+  // add it back afterwards.
+  UninstallView();
   if (fullscreen) {
     restored_bounds_ = [window() frame];
     [window() setStyleMask:NSBorderlessWindowMask];
     [window() setFrame:[window()
         frameRectForContentRect:[[window() screen] frame]]
                display:YES];
     base::mac::RequestFullScreen(base::mac::kFullScreenModeAutoHideAll);
   } else {
     base::mac::ReleaseFullScreen(base::mac::kFullScreenModeAutoHideAll);
-    [window() setStyleMask:NSTitledWindowMask | NSClosableWindowMask |
-                           NSMiniaturizableWindowMask | NSResizableWindowMask];
+    NSUInteger style_mask = NSTitledWindowMask | NSClosableWindowMask |
+                            NSMiniaturizableWindowMask | NSResizableWindowMask |
+                            NSTexturedBackgroundWindowMask;
+    [window() setStyleMask:style_mask];
     [window() setFrame:restored_bounds_ display:YES];
   }
+  InstallView();
 
   // Fade back in.
   if (did_fade_out) {
     CGDisplayFade(token, kFadeDurationSeconds / 2, kCGDisplayBlendSolidColor,
         kCGDisplayBlendNormal, 0.0, 0.0, 0.0, /*synchronous=*/false);
     CGReleaseDisplayFadeReservation(token);
   }
 }
 
 bool ShellWindowCocoa::IsFullscreenOrPending() const {
@@ skipping 131 matching lines @@
   return [window_controller_ window];
 }
 
 // static
 ShellWindow* ShellWindow::CreateImpl(Profile* profile,
                                      const extensions::Extension* extension,
                                      const GURL& url,
                                      const ShellWindow::CreateParams& params) {
   return new ShellWindowCocoa(profile, extension, url, params);
 }