Adds an iOS implementation of base::SystemMonitor.

base/system_monitor/system_monitor_ios.mm

+// Copyright (c) 2012 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+// Implementation based on sample code from
+// http://developer.apple.com/library/mac/#qa/qa1340/_index.html.

[Mark Mentovai, 2012/07/10 16:06:03]

I don’t see anything like this code at this URL.

[rohitrao (ping after 24h), 2012/07/10 16:26:44]

Removed the comment.

+
+#include "base/system_monitor/system_monitor.h"
+
+#include <UIKit/UIKit.h>

[Mark Mentovai, 2012/07/10 16:06:03]

#import me.

[rohitrao (ping after 24h), 2012/07/10 16:26:44]

Done.

+
+namespace base {
+
+void SystemMonitor::AllocateSystemIOPorts() {
+  // No need to allocate any IO ports on iOS.

[Mark Mentovai, 2012/07/10 16:06:03]

This comment is unnecessary. There’s obviously no need to do so because the
function named “allocate system IO ports” is empty.

But your code’d be slimmer if you took this out of here and inlined an empty
definition of this function for iOS in the header file.

Your call.

[rohitrao (ping after 24h), 2012/07/10 16:26:44]

Removed the comment.  I thought about making the entire method mac-but-not-ios,
but there are a half dozen callers and I think changing them all will be uglier.

[Mark Mentovai, 2012/07/10 17:06:05]

rohitrao wrote:
Right, that’s why the suggestion (in case it wasn’t clear) was to write in the
header:

#if defined(OS_MACOSX)
#if !defined(OS_IOS)
  static void AllocateSystemIOPorts();
#else  // OS_IOS
  static void AllocateSystemIOPorts() {}
#endif  // OS_IOS
#endif  // OS_MACOSX

That way, the no-op will be inlined into the call sites at zero cost, and you
don’t need to decorate the call sites with additional ugly #ifdefs at all.

[rohitrao (ping after 24h), 2012/07/10 17:17:42]

Done.

+}
+
+void SystemMonitor::PlatformInit() {
+  NSNotificationCenter* nc = [NSNotificationCenter defaultCenter];
+  id foreground =
+      [nc addObserverForName:UIApplicationWillEnterForegroundNotification
+                      object:nil
+                       queue:nil
+                  usingBlock:^(NSNotification* notification) {
+                      this->ProcessPowerMessage(RESUME_EVENT);

[Mark Mentovai, 2012/07/10 16:06:03]

Is the “this” really necessary?

[Mark Mentovai, 2012/07/10 16:06:03]

I do love how clean this is.

[rohitrao (ping after 24h), 2012/07/10 16:26:44]

Looks like it's implicit if I leave it out.  From the docs:

"In general you can use C++ objects within a block. Within a member function,
references to member variables and functions are via an implicitly imported this
pointer and thus appear mutable."

Do you see any danger in an implicit this->?  Do I need to do any of the crazy
shenanigans like saving "this" into another variable for use in the block,
similar to the method you would use to break retain cycles when using "self?"

[Mark Mentovai, 2012/07/10 17:06:05]

rohitrao wrote:
In C++ code, we never write this-> because it’s implied. Why would “this” case
be any different?
“this,” whether implicit or explicit, is just a raw pointer as far as the
language is concerned. There’s nothing like reference counting going on when you
use it, whether or not the compiler sees it. It’s just a variable that gets
bound when the block is established. It’s just a number. Simple as that.

[rohitrao (ping after 24h), 2012/07/10 17:17:42]

Ok, makes sense.  paranoia fading.

+                  }];
+  id background =
+      [nc addObserverForName:UIApplicationDidEnterBackgroundNotification
+                      object:nil
+                       queue:nil
+                  usingBlock:^(NSNotification* notification) {
+                      this->ProcessPowerMessage(SUSPEND_EVENT);
+                  }];
+  notification_observers_.push_back(foreground);
+  notification_observers_.push_back(background);
+}
+
+void SystemMonitor::PlatformDestroy() {
+  NSNotificationCenter* nc = [NSNotificationCenter defaultCenter];
+  for (std::vector<id>::iterator it = notification_observers_.begin();
+       it != notification_observers_.end(); ++it) {
+    [nc removeObserver:*it];
+  }
+  notification_observers_.clear();
+}
+
+}  // namespace base