[Mac] Add field trial tuples to breakpad crash reports.

chrome/common/child_process_logging_mac.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/common/child_process_logging.h"
 
 #import <Foundation/Foundation.h>
 
 #include "base/command_line.h"
 #include "base/string_number_conversions.h"
 #include "base/string_split.h"
 #include "base/string_util.h"
 #include "base/stringprintf.h"
 #include "base/sys_string_conversions.h"
 #include "base/utf_string_conversions.h"
+#include "chrome/common/metrics/experiments_helper.h"
 #include "chrome/installer/util/google_update_settings.h"
 #include "content/public/common/gpu_info.h"
 #include "googleurl/src/gurl.h"
 
 namespace child_process_logging {
 
 using base::mac::SetCrashKeyValueFuncPtr;
 using base::mac::ClearCrashKeyValueFuncPtr;
 using base::mac::SetCrashKeyValue;
 using base::mac::ClearCrashKey;
@@ skipping 187 matching lines @@
     key_i++;
   }
 
   // Clear out any stale keys.
   for (; key_i < kMaxSwitches; ++key_i) {
     NSString* key = [NSString stringWithFormat:kSwitchKeyFormat, (key_i + 1)];
     ClearCrashKey(key);
   }
 }
 
-void SetExperimentList(const std::vector<string16>& state) {
-  // TODO(mad): Implement this.
+void SetExperimentList(const std::vector<string16>& experiments) {
+  // These should match the corresponding strings in breakpad_win.cc.
+  NSString* const kNumExperimentsKey = @"num-experiments";
+  NSString* const kExperimentChunkFormat = @"experiment-chunk-%zu";  // 1-based.
+
+  std::vector<string16> chunks;
+  experiments_helper::GenerateExperimentChunks(experiments, &chunks);
+
+  // Store up to |kMaxReportedExperimentChunks| chunks.
+  for (size_t i = 0; i < kMaxReportedExperimentChunks; ++i) {
+    NSString* key = [NSString stringWithFormat:kExperimentChunkFormat, i + 1];
+    if (i < chunks.size()) {

[MAD, 2012/06/28 13:03:38]

Why not run until the min of kMaxReportedExperimentChunks and chunks.size()?

[Alexei Svitkine (slow), 2012/06/28 14:56:09]

I originally had it like that, but then I noticed how SetCommandLine(). Since
the state we're setting is persistent, the idea is to clear any entries between
chunks.size() and kMaxReportedExperimentChunks in case they have any data left
over from the last time SetExperimentList() was called. (For example, if a trial
gets disabled between calls of SetExperimentList().)

[Scott Hess - ex-Googler, 2012/06/29 00:37:07]

Yes, this is the correct approach to take.

+      NSString* value = base::SysUTF16ToNSString(chunks[i]);
+      SetCrashKeyValue(key, value);
+    } else {
+      ClearCrashKey(key);

[MAD, 2012/06/28 13:03:38]

If you keep this, break?

[Alexei Svitkine (slow), 2012/06/28 14:56:09]

See above. (Break does not achieve the result we want - the idea is to clear all
the slots at the end.)

+    }
+  }
+
+  // Make note of the total number of experiments, which may be greater than
+  // what was able to fit in |kMaxReportedExperimentChunks|. This is useful
+  // when correlating stability with the number of experiments running
+  // simultaneously.
+  SetCrashKeyValue(kNumExperimentsKey,
+                   [NSString stringWithFormat:@"%zu", experiments.size()]);
 }
 
 void SetChannel(const std::string& channel) {
   // This should match the corresponding string in breakpad_win.cc.
   NSString* const kChannelKey = @"channel";
 
   SetCrashKeyValue(kChannelKey, base::SysUTF8ToNSString(channel));
 }
 
 }  // namespace child_process_logging